XSLTPROC=xsltproc

CURL=curl

draft-ietf.html: draft-ietf.xml rfc2629.xslt

	$(XSLTPROC) --novalid --output $@ rfc2629.xslt $<

draft-ietf.xml: draft.html ietf.xsl

	$(XSLTPROC) --novalid --output $@ ietf.xsl $<

#see http://greenbytes.de/tech/webdav/

rfc2629.xslt:

	$(CURL) -O http://greenbytes.de/tech/webdav/rfc2629.xslt

<xsl:transform

    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

    xmlns:h="http://www.w3.org/1999/xhtml"

    version="1.0"

    >

<xsl:output

    method="xml"

    indent="yes"

    doctype-system='rfcXXXX.dtd'

    />

<xsl:template match="h:html">

  <xsl:apply-templates />

</xsl:template>

<xsl:template match="h:head">

  <!-- munch munch -->

</xsl:template>

<xsl:template match="h:body">

  <rfc>

    <xsl:apply-templates />

  </rfc>

</xsl:template>

<xsl:template match="h:div[@class='head']">

  <front>

    <xsl:apply-templates />

    <!-- hmm... abstract@@ -->

  </front>

</xsl:template>

<xsl:template match="h:h1">

  <title>

    <xsl:apply-templates />

  </title>

</xsl:template>

<xsl:template match="h:dt[ancestor::h:div/@class='head']" >

  <!-- drop Editors: label-->

</xsl:template>

<xsl:template match="h:dd[ancestor::h:div/@class='head']" >

  <author>

    <xsl:text>@@fix/prune author</xsl:text>

    <xsl:apply-templates />

  </author>

</xsl:template>

<xsl:template match="h:h2[ancestor::h:div/@class='head']" >

  <date>

    <xsl:text>@@fix/prune date</xsl:text>

    <xsl:apply-templates />

  </date>

</xsl:template>

<xsl:template match="h:p[@class='copyright']">

  <!-- "Note that text relating to the memo's status, copyright

       notice, or table of contents is not included in the document's

       markup — this is automatically inserted by an XML application

       when it produces either a text or HTML version of the

       document. " - 2.2.7.  Status, Copyright Notice, Table of

       Contents -->

</xsl:template>

<xsl:template match="h:div[h:h2/h:a/@id='status']" >

  <!-- elide -->

</xsl:template>

<xsl:template match="h:div[@class='toc']" >

  <!-- elide -->

</xsl:template>

<xsl:template match="h:h2" >

  <!-- elide -->

</xsl:template>

<xsl:template match="h:div[@class='body']">

  <middle>

    <xsl:apply-templates />

  </middle>

</xsl:template>

<xsl:template match="h:span[@class='secno']">

  <!-- elide -->

</xsl:template>

<xsl:template match="h:div[@class='div1']">

  <xsl:variable name="label" select="h:h2" /> <!-- remove secno -->

  <xsl:variable name="anchor" select="h:h2/@id" />

  <section title="{$label}" anchor="{$anchor}">

    <xsl:apply-templates />

  </section>

</xsl:template>

<xsl:template match="h:p">

  <t>

    <xsl:apply-templates />

  </t>

</xsl:template>

<xsl:template match="h:p">

  <t>

    <xsl:apply-templates />

  </t>

</xsl:template>

<xsl:template match="h:ol">

  <list style="numbers">

    <xsl:apply-templates />

  </list>

</xsl:template>

<xsl:template match="h:ul">

  <list style="symbols">

    <xsl:apply-templates />

  </list>

</xsl:template>

<xsl:template match="h:li">

  <xsl:choose>

    <xsl:when test="h:p">

      <xsl:apply-templates />

    </xsl:when>

    <xsl:otherwise>

      <t>

	<xsl:apply-templates />

      </t>

    </xsl:otherwise>

  </xsl:choose>

</xsl:template>

<xsl:template match="h:var">

  <spanx style="emph">

	<xsl:apply-templates />

  </spanx>

</xsl:template>

<xsl:template match="h:code">

  <spanx style="verb">

	<xsl:apply-templates />

  </spanx>

</xsl:template>

<!-- hypertext references -->

<xsl:template match="h:a[@href]">

  <xsl:variable name="target" select="substring(@href, 2)" />

  <xref target="{$target}" />

</xsl:template>

<xsl:template match="*">

  <xsl:message>warning: <xsl:value-of select="local-name()" />#<xsl:value-of select="@id" />[<xsl:value-of select="@class" />] in <xsl:value-of select="local-name(..)" />#<xsl:value-of select="../@id" />[<xsl:value-of select="../@class" />] not recognized.

  </xsl:message>

  <xsl:apply-templates />

</xsl:template>

</xsl:transform>