Source

frawor / plugin / frawor / decorators / altervars.vim

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
"▶1 Header
scriptencoding utf-8
execute frawor#Setup('0.1', {'@/decorators': '0.0',
            \                    '@/checks': '0.0',
            \      '@/decorators/altervars': '0.0'})
"▶1 Define messages
if v:lang=~?'ru'
    let s:_messages={
                \    'idnotstr': 'Ошибка создания сохраняющей и '.
                \                'восстанавливающей функций для '.
                \                'дополнения %s: их название '.
                \                'не является строкой',
                \       'invid': 'Ошибка создания сохраняющей и '.
                \                'восстанавливающей функций для '.
                \                'дополнения %s: строка «%s» '.
                \                'не может являться названием',
            \}
    call extend(s:_messages, map({
                \     'altnlst': 'ключ «altervars» не является списком',
                \   'altelnlst': 'элемент %u значения ключа «altervars» '.
                \                'описания функции не является списком',
                \ 'altelinvlen': 'элемент %u значения ключа «altervars» '.
                \                'описания функции имеет неверную длину %u '.
                \                '(список должен содержать один или '.
                \                 'два элемента)',
                \   'altelnstr': 'первый элемент элемента %u значения ключа '.
                \                '«altervars» описания функции '.
                \                'не является строкой',
                \    'invvnlen': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: длина строки '.
                \                'не может быть меньше двух символов',
                \    'invvname': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: строка «%s» '.
                \                'не может являться именем переменной',
                \    'noocpref': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: в имени '.
                \                'настройки «%s» отсутстувет префикс '.
                \                '(g: или l:)',
                \    'invoname': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: строка «%s» '.
                \                'не может являться именем настройки',
                \     'invoval': 'неверен второй элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'тип элемента не совпадает с типом настройки',
                \     'noclose': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'отсутствует закрывающая скобка',
                \     'spnoarg': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'сохраняющая функция %s не принимает '.
                \                'дополнительных аргументов',
                \'acheckfailed': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'аргумент сохраняющей функции %s не прошёл '.
                \                'проверку',
                \      'usaver': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'неизвестна сохраняющая функция %s',
                \    'spmisarg': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'сохраняющая функция %s требует наличия '.
                \                'дополнительного аргумента',
                \      'notdep': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'дополнение %s, определившее сохраняющую '.
                \                'функцию %s, не указано в списке зависимостей',
                \        'ualt': 'неверен первый элемент элемента %u '.
                \                'значения ключа «altervars»: '.
                \                'способ обработки «%s» неизвестен',
            \}, '"Ошибка создания функции %s для дополнения %s: ".v:val'))
    call extend(s:_messages, map({
                \     'ssiddef': 'функции уже определены дополнением %s',
                \  'savnotfunc': 'второй аргумент не является '.
                \                'ссылкой на функцию',
                \  'setnotfunc': 'третий аргумент не является '.
                \                'ссылкой на функцию',
                \  'ssmanyargs': 'слишком большое количество аргументов',
                \  'ssoptsndct': 'дополнительный аргумент не является словарём',
                \   'sssavuref': 'сохраняющая функция является ссылкой '.
                \                'на неизвестную функцию',
                \   'ssseturef': 'восстанавливающая функция является ссылкой '.
                \                'на неизвестную функцию',
            \},
            \'"Ошибка создания сохраняющей и восстанавливающей функций '.
            \ '%s для дополнения %s: ".v:val'))
else
    let s:_messages={
                \    'idnotstr': 'Error while creating saver and setter '.
                \                'functions for plugin %s: id is not a String',
                \       'invid': 'Error while creating saver and setter '.
                \                'functions for plugin %s: string `%s'' '.
                \                'is not a valid identifier',
            \}
    call extend(s:_messages, map({
                \     'altnlst': 'key `altervars'' is not a list',
                \   'altelnlst': 'element %u of `altervars'' value '.
                \                'of the function description is not a list',
                \ 'altelinvlen': 'element %u of `altervars'' value '.
                \                'of the function description has invalid '.
                \                'length %u while expected 1 or 2',
                \   'altelnstr': 'first element of element %u of `altervars'' '.
                \                'value of the function description is '.
                \                'not a string',
                \    'invvnlen': 'first element of element %u of `altervars'' '.
                \                'value is not valid: string must be at least '.
                \                'two characters long',
                \    'invvname': 'first element of element %u of `altervars'' '.
                \                'value is not valid: string `%s'' '.
                \                'is not a variable name',
                \    'noocpref': 'first element of element %u of `altervars'' '.
                \                'value is not valid: there should be '.
                \                'g: or l: prefix before option name in '.
                \                'the string `%s''',
                \    'invoname': 'first element of element %u of `altervars'' '.
                \                'value is not valid: string `%s'' '.
                \                'is not an option name',
                \     'invoval': 'second element of element %u '.
                \                'of `altervars'' value is not valid: '.
                \                'type of the element does not match type of '.
                \                'the option',
                \     'noclose': 'first element of element %u of `altervars'' '.
                \                'value is not valid: closing bracket '.
                \                'not found',
                \     'spnoarg': 'first element of element %u of `altervars'' '.
                \                'value is not valid: saver %s does '.
                \                'not accept additional arguments',
                \'acheckfailed': 'first element of element %u of `altervars'' '.
                \                'value is not valid: argument of saver %s '.
                \                'failed to pass check',
                \      'usaver': 'first element of element %u of `altervars'' '.
                \                'value is not valid: saver %s is not known',
                \    'spmisarg': 'first element of element %u of `altervars'' '.
                \                'value is not valid: saver %s requires '.
                \                'additional argument',
                \      'notdep': 'first element of element %u of `altervars'' '.
                \                'value is not valid: plugin %s that defined '.
                \                'saver %s is not in dependencies list',
                \        'ualt': 'first element of element %u of `altervars'' '.
                \                'value is not valid: unable to determine '.
                \                'how to process %s',
            \}, '"Error while creating function %s for plugin %s: ".v:val'))
    call extend(s:_messages, map({
                \     'ssiddef': 'they were already defined by plugin %s',
                \  'savnotfunc': 'saver is not a function reference',
                \  'setnotfunc': 'setter is not a function reference',
                \  'ssmanyargs': 'too many arguments',
                \  'ssoptsndct': 'options argument is not a Dictionary',
                \   'sssavuref': 'saver is a reference to unknown function',
                \   'ssseturef': 'setter is a reference to unknown function',
            \},
            \'"Error while creating saver and setter functions with id %s '.
            \ 'for plugin %s: ".v:val'))
endif
"▶1 rewritefname    :: sid, Funcref → funcname
function s:F.rewritefname(sid, Fref)
    let fstr=string(a:Fref)[10:-3]
    if fstr[:1] is# 's:'
        let fstr='<SNR>'.a:sid.'_'.fstr[2:]
    endif
    return fstr
endfunction
"▶1 refunction      :: sid, Funcref, throwargs → Funcref
function s:F.refunction(sid, Fref, ...)
    let fstr=s:F.rewritefname(a:sid, a:Fref)
    if string(+fstr) is# fstr
        return a:Fref
    else
        if !exists('*'.fstr)
            call call(s:_f.throw, a:000, {})
        endif
        return function(fstr)
    endif
endfunction
"▶1 Decorator
let s:altervars={'lastid': 0}
let s:ss={}
let s:altdict={'altervars': s:altervars,
            \         'ss': s:ss}
function s:F.altervars(plugdict, fname, arg)
    "▶2 Check a:arg
    if type(a:arg)!=type([])
        call s:_f.throw('altnlst', a:fname, a:plugdict.id)
    endif
    "▶2 Define variables
    let preret=['let @$@={}',
                \     'try',]
    let postret=['finally']
    let laltvars=len(a:arg)
    let plid=a:plugdict.id
    let i=0
    let id=printf('%x', s:altervars.lastid)
    let fpref='@%@.altervars.'.id
    let altcopy=map(copy(a:arg), 'copy(v:val)')
    let s:altervars[id]=altcopy
    let s:altervars.lastid+=1
    "▲2
    while i<laltvars
        "▶2 Check current element
        if type(a:arg[i])!=type([])
            call s:_f.throw('altelnlst', a:fname, plid, i)
        elseif empty(a:arg[i]) || len(a:arg[i])>2
            call s:_f.throw('altelinvlen', a:fname, plid, i, len(a:arg[i]))
        elseif type(a:arg[i][0])!=type('')
            call s:_f.throw('altelnstr', a:fname, plid, i)
        endif
        "▲2
        let element=altcopy[i]
        let varname=element[0]
        let vnlen=len(varname)
        let hasvar=(len(element)>1)
        let warnargs="'".varname."', '".a:fname."', ".
                    \substitute(string(plid), "\n",
                    \           '''."\\n".''', 'g').', v:exception'
        "▶2 Check varname length
        if vnlen<2
            call s:_f.throw('invvnlen', a:fname, plid, i)
        "▶2 Process variables
        elseif varname[1] is# ':' && index(['g','b','t','w'], varname[0])!=-1
            "▶3 Check variable name
            if varname[2:]!~#'^\h\w*$'
                call s:_f.throw('invvname', a:fname, plid, i, varname[2:])
            endif
            "▲3
            let preret+=['if exists("'.varname.'")',
                        \          'let @$@.'.i.'='.varname]
            if hasvar
                " Unlet variable to be sure that it won't cause E706 
                " (variable type mismatch) error
                let preret+=['unlet '.varname,
                            \   'endif',
                            \   'let '.varname.'=']
                if type(element[1])==type(0) ||
                            \(has('float') && type(element[1])==type(0.0) &&
                            \ string(element[1])!~'\w')
                    let preret[-1].=string(element[1])
                else
                    let preret[-1].=fpref.'['.i.'][1]'
                endif
            else
                call add(preret, 'endif')
            endif
            " Restore the previous status: variable will be left undefined if it 
            " was not defined before function was run
            let postret+=['if exists("'.varname.'")',
                        \         'unlet '.varname,
                        \     'endif',
                        \     'if has_key(@$@, '.i.')',
                        \         'let '.varname.'=@$@.'.i,
                        \     'endif',]
        "▶2 Process options
        elseif varname[0] is# '&' && vnlen>3
            "▶3 Check option name
            if varname[2] isnot# ':' || !(varname[1] is# 'g' || varname[1] is# 'l')
                call s:_f.throw('noocpref', a:fname, plid, i, varname)
            elseif varname[3:]!~#'^\l\+$'
                call s:_f.throw('invoname', a:fname, plid, i, varname[3:])
            endif
            "▲3
            if exists('+'.varname[1:])
                let ovarname='@$@'.varname[1].'_'.varname[3:]
                call add(preret, 'let '.ovarname.'='.varname)
                if hasvar
                    "▶3 Check value type
                    if type(element[1])!=type(eval(varname))
                        call s:_f.throw('invoval', a:fname, plid, i)
                    endif
                    "▲3
                    call add(preret, 'let '.varname.'='.
                                \substitute(string(element[1]), '\n',
                                \                  '''."\\n".''', 'g'))
                endif
                let postret+=['let '.varname.'='.ovarname]
            endif
        "▶2 Process special
        elseif varname[0] is# '+'
            "▶3 *args, varname
            let saveargs=''
            let setargs=fpref.'['.i.'][1]'
            let set2args='@$@.'.i
            let varname=varname[1:]
            "▲3
            let bidx=stridx(varname, '(')
            "▶3 If argument is supplied
            if bidx!=-1
                "▶4 Altering varname, element and *args variables
                let noclose=(varname[-1:] isnot# ')')
                if !hasvar
                    call add(element, 0)
                endif
                call add(element, varname[(bidx+1):-2])
                let varname=varname[:(bidx-1)]
                let element[0]='+'.varname
                let saveargs=fpref.'['.i.'][2]'
                let setargs.=', '.saveargs
                let set2args.=', '.saveargs
                "▶4 Check existance of special
                if !has_key(s:ss, varname)
                    call s:_f.throw('usaver', a:fname, plid, i, varname)
                endif
                let ssdef=s:ss[varname]
                "▶4 Checking () expr
                if noclose
                    call s:_f.throw('noclose', a:fname, plid, i)
                elseif !ssdef.hasarg
                    call s:_f.throw('spnoarg', a:fname, plid, i, varname)
                elseif has_key(ssdef, 'checker') && !ssdef.checker([element[2]])
                    call s:_f.throw('acheckfailed', a:fname, plid, i, varname)
                endif
            "▶3 Else just check existance of special
            else
                if !has_key(s:ss, varname)
                    call s:_f.throw('usaver', a:fname, plid, i, varname)
                endif
            endif
            "▲3
            let ssdef=s:ss[varname]
            "▶3 Check special name and existance of all arguments
            if ssdef.hasarg==2 && bidx==-1
                call s:_f.throw('spmisarg', a:fname, plid, i, varname)
            elseif !has_key(a:plugdict.dependencies, ssdef.plid)
                call s:_f.throw('notdep', a:fname, plid, i, ssdef.plid, varname)
            endif
            "▲3
            let preret+=['try',
                        \          'let @$@.'.i.'=@%@.ss.'.varname.'.saver'.
                        \                                      '('.saveargs.')',
                        \      'catch',
                        \          'call s:_f.warn("savexcept", '.warnargs.')',
                        \      'endtry',]
            if hasvar
                let preret+=['try',
                            \          'call @%@.ss.'.varname.'.setter'.
                            \                                   '('.setargs.')',
                            \      'catch',
                            \          'call s:_f.warn("setexcept", '.
                            \                                 warnargs.')',
                            \      'endtry',]
            endif
            let postret+=['try',
                        \         'call @%@.ss.'.varname.'.setter'.
                        \                                      '('.set2args.')',
                        \     'catch',
                        \         'call s:_f.warn("set2except", '.warnargs.')',
                        \     'endtry',]
        "▶2 Process unknown
        else
            call s:_f.throw('ualt', a:fname, plid, i, varname)
        endif
        "▶2 Finish cycle (increment+unlet)
        let i+=1
        unlet element
        "▲2
    endwhile
    call add(postret, 'endtry')
    return [192, '@@@', s:altdict, preret, postret, 0]
endfunction
call s:_f.adddecorator('altervars', s:F.altervars)
"▶1 addaltspecial feature
"▶2 delaltspecials  :: {f} → s:ss, fdict
function s:F.delaltspecials(plugdict, fdict)
    for ssdef in values(a:fdict)
        unlet s:ss[ssdef.id]
        unlet a:fdict[ssdef.id]
    endfor
endfunction
"▶2 addaltspecial   :: {f}, ssid, Saver::Funcref, Setter::Funcref[, ssopts] → +…
function s:F.addaltspecial(plugdict, fdict, ssid, Saver, Setter, ...)
    "▶3 Check arguments
    if type(a:ssid)!=type('')
        call s:_f.throw('idnotstr', a:plugdict.id)
    elseif a:ssid!~#'^\h\w*$'
        call s:_f.throw('invid', a:plugdict.id, a:ssid)
    elseif has_key(s:ss, a:ssid)
        call s:_f.throw('ssiddef', a:ssid, a:plugdict.id,
                    \              s:ss[a:ssid].plid)
    elseif type(a:Saver)!=2
        call s:_f.throw('savnotfunc', a:ssid, a:plugdict.id)
    elseif type(a:Setter)!=2
        call s:_f.throw('setnotfunc', a:ssid, a:plugdict.id)
    elseif a:0>1
        call s:_f.throw('ssmanyargs', a:ssid, a:plugdict.id)
    elseif a:0
        if type(a:1)!=type({})
            call s:_f.throw('ssoptsndct', a:ssid, a:plugdict.id)
        endif
    endif
    "▲3
    let ssdef={
                \    'id': a:ssid,
                \  'plid': a:plugdict.id,
                \ 'saver': s:F.refunction(a:plugdict.sid, a:Saver,
                \                         'sssavuref', a:ssid, a:plugdict.id),
                \'setter': s:F.refunction(a:plugdict.sid, a:Setter,
                \                         'ssseturef', a:ssid, a:plugdict.id),
                \'hasarg': 0,
            \}
    if a:0
        if has_key(a:1, 'requiresarg')
            let ssdef.hasarg=2
        elseif has_key(a:1, 'acceptsarg')
            let ssdef.hasarg=1
        endif
        if has_key(a:1, 'checker')
            let ssdef.checker=s:_f.conschecker(a:1.checker)
        endif
    endif
    let s:ss[ssdef.id]=ssdef
    let a:fdict[ssdef.id]=ssdef
endfunction
"▶2 Register feature
call s:_f.newfeature('addaltspecial', {'cons': s:F.addaltspecial,
            \                        'unload': s:F.delaltspecials,})
"▶1 Savers/setters
"▶2 Define dictionaries
let s:F.saver={}
let s:F.setter={}
let s:F.sschk={}
"▶2 window
function s:F.saver.window()
    return [tabpagenr(), winnr()]
endfunction
function s:F.setter.window(twnr)
    if type(a:twnr)==type([]) && len(a:twnr)==2
                \&& type(a:twnr[0])==type(0) && a:twnr[0]<=tabpagenr('$')
                \&& type(a:twnr[1])==type(0) && a:twnr[1]<=winnr('$')
        try
            if tabpagenr()!=a:twnr[0]
                execute 'tabnext' a:twnr[0]
            endif
            if winnr()!=a:twnr[1]
                execute a:twnr[1].'wincmd w'
            endif
        catch
            echohl ErrorMsg
            echomsg v:exception
            echohl None
        endtry
    endif
endfunction
call s:_f.addaltspecial('window', s:F.saver.window, s:F.setter.window)
"▶2 winview
call s:_f.addaltspecial('winview', function('winsaveview'),
            \                      function('winrestview'))
"▶2 folds
function s:F.saver.folds()
    let r=[]
    for line in range(1, line('$'))
        if foldclosed(line)!=-1
            execute line.'foldopen'
            call insert(r, line)
        endif
    endfor
    return r
endfunction
function s:F.setter.folds(flist)
    if type(a:flist)==type([]) &&
                \empty(filter(copy(a:flist), 'type(v:val)!='.type(0)))
        try
            normal! zR
            for line in a:flist
                execute line.'foldclose'
            endfor
        catch
            echohl ErrorMsg
            echomsg v:exception
            echohl None
        endtry
    endif
endfunction
call s:_f.addaltspecial('folds', s:F.saver.folds, s:F.setter.folds)
"▶2 buffer
function s:F.saver.buffer()
    return bufnr('%')
endfunction
function s:F.setter.buffer(bufnr)
    if type(a:bufnr)==type(0) && a:bufnr!=bufnr('%') && bufexists(a:bufnr)
        try
            execute 'buffer' a:bufnr
        catch
            " Setter must not throw anything: it may break things
            echohl ErrorMsg
            echomsg v:exception
            echohl None
        endtry
    endif
endfunction
call s:_f.addaltspecial('buffer', s:F.saver.buffer, s:F.setter.buffer)
"▶2 variables
"▶3 check
function s:F.sschk.variables(arg)
    if a:arg[0]!~#'^[gtbw]$'
        call s:_f.throw('invvcvar', a:arg[0])
    endif
    return 1
endfunction
"▶3 save
function s:F.saver.variables(...)
    let dname=get(a:000, 0, 'g').':'
    return copy(eval(dname))
endfunction
"▶3 set
function s:F.setter.variables(oldv, ...)
    if type(a:oldv)!=type({})
        return
    endif
    let dname=get(a:000, 0, 'g').':'
    let v=eval(dname)
    for name in filter(keys(v), '!has_key(a:oldv, v:val)')
        unlet v[name]
    endfor
    call extend(v, filter(a:oldv, 'v:key=~#"^\\h\\w*$"'), 'force')
endfunction
"▲3
call s:_f.addaltspecial('variables', s:F.saver.variables, s:F.setter.variables,
            \                               {'checker': s:F.sschk.variables,
            \                             'acceptsarg': 1,})
"▶2 matches
call s:_f.addaltspecial('matches',function('getmatches'),function('setmatches'))
"▶2 qflist
function s:F.setqflist(list)
    return setqflist(a:list, 'r')
endfunction
call s:_f.addaltspecial('qflist', function('getqflist'), s:F.setqflist)
"▲2
unlet s:F.saver s:F.setter s:F.sschk
"▶1
call frawor#Lockvar(s:, 'altervars,ss,altdict')
lockvar 1 s:altdict
" vim: fmr=▶,▲ sw=4 ts=4 sts=4 et tw=80
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.