Source

pyside_aur / python-pyside / PKGBUILD

Full commit
# Maintainer: arlx_ignacy <ziphims@gmail.com>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>


# modify these two to whatever Python 3 interpreter you're targetting; on my
# system I use the vanilla python3
_pyver=3
_pyexec=/usr/bin/python$_pyver

pkgname=python-pyside
pkgver=1.1.0
pkgrel=1
pkgdesc='A set of Python 3.x bindings licensed under LGPL for the Qt toolkit'
arch=('i686' 'x86_64')
license=('LGPL')
url='http://www.pyside.org'
depends=('python-libshiboken>=1.1.0' 'python' 'qt>=4.7' 'phonon' 'mesa')
makedepends=('cmake' 'automoc4' 'python-shibokengenerator>=1.1.0')
replaces=('pyside-py3')
source=("http://www.pyside.org/files/pyside-qt4.7+$pkgver.tar.bz2")
md5sums=('233f0c6d2b3daf58cf88877d7f74557b')


build() {
    cd "$srcdir"

    if [ -d build ] ; then
        msg "Removing last build ..."
        rm -rf build
    fi

    mkdir build
    cd build

    cmake ../pyside-qt4.7+$pkgver -DCMAKE_INSTALL_PREFIX=/usr \
                                  -DCMAKE_BUILD_TYPE=Release  \
                                  -DBUILD_TESTS=FALSE         \
                                  -DUSE_PYTHON3=TRUE
    make
}

package() {
    cd "$srcdir/build"
    make DESTDIR=$pkgdir install
}