Source

pyside_aur / python-libshiboken / PKGBUILD

Full commit
# Maintainer: arlx_ignacy <ziphims@gmail.com>
# Contributor: Matthias Maennich <arch@maennich.net>

# modify these two to whatever Python 3 interpreter you're targetting; on my
# system I use the vanilla python3
_pyver=3
_pyexec=/usr/bin/python$_pyver

pkgname=python-libshiboken
pkgver=1.1.0
pkgrel=1
pkgdesc='Support library for Python 3 bindings to Qt toolkit'
arch=('i686' 'x86_64')
license=('LGPL')
url='http://www.pyside.org'
depends=('python' 'qt>=4.7' 'openssl')
makedepends=('cmake' 'automoc4' 'generatorrunner>=0.6.16')
replaces=('libshiboken-py3')
source=("http://www.pyside.org/files/shiboken-$pkgver.tar.bz2")
md5sums=('9c9d696c8c426fb5abf28a6bd3759558')


build() {
    cd "$srcdir"

    if [ -d build ] ; then
        msg "Removing last build ..."
        rm -rf build
    fi

    mkdir build
    cd build

    cmake ../shiboken-$pkgver -DCMAKE_INSTALL_PREFIX=/usr  \
                              -DCMAKE_BUILD_TYPE=Release   \
                              -DBUILD_TESTS=FALSE          \
                              -DPYTHON_EXECUTABLE=$_pyexec \
                              -DUSE_PYTHON3=TRUE
    make libshiboken
}


package() {
    cd "$srcdir/build/libshiboken"
    make DESTDIR=$pkgdir install
}