Source

spotxtras / xcurl.ml

Full commit
open Spotlib.Spot

let ok200 = function
  | 200, v -> `Ok v
  | n, mes -> `Error (`Http (n, `Message mes))

let wrap f =
  try f () with
  | Curl.CurlException (_, n, mes) -> `Error (`Curl (n, mes))

let get_string f = 
  let h = new Curl.handle in
  f h;
  let buf = Buffer.create 100 in
  h#set_writefunction (fun s -> Buffer.add_string buf s; String.length s);
  wrap & fun () -> 
    h#perform;
    let code = h#get_httpcode in
    h#cleanup; (* Need to flush out cookies *)
    ok200 (code, Buffer.contents buf)

let download dst f =
  let h = new Curl.handle in
  f h;
  let tmp = dst ^ ".tmp" in
  if Sys.file_exists tmp then Unix.unlink tmp;
  let oc = open_out_bin tmp in
  h#set_writefunction (fun s -> 
    output_string oc s; String.length s);
  wrap & fun () -> 
    protect' (fun () -> h#perform) ~finally:(fun () -> close_out oc);
    let code = h#get_httpcode in
    h#cleanup; (* Need to flush out cookies *)
    match code with
    | 200 | 226 (* IM used: access to a ftp server may return this *) -> 
        Unix.rename tmp dst; `Ok dst
    | e -> `Error (`Http (e, `Downloaded tmp))

module Error = struct
  open Format

  type t = [ `Http of int * [ `Message of string | `Downloaded of string ]
           | `Curl of int * string ]

  let format ppf = function
    | `Http (n, _err) -> fprintf ppf "HTTP Error %d@." n
    | `Curl (n, err) -> fprintf ppf "Curl Error %d: %s@." n err

end