Source

wikiup / src / wikiup.pl.in

   1
   2
   3
   4
   5
   6
   7
   8
   9
  10
  11
  12
  13
  14
  15
  16
  17
  18
  19
  20
  21
  22
  23
  24
  25
  26
  27
  28
  29
  30
  31
  32
  33
  34
  35
  36
  37
  38
  39
  40
  41
  42
  43
  44
  45
  46
  47
  48
  49
  50
  51
  52
  53
  54
  55
  56
  57
  58
  59
  60
  61
  62
  63
  64
  65
  66
  67
  68
  69
  70
  71
  72
  73
  74
  75
  76
  77
  78
  79
  80
  81
  82
  83
  84
  85
  86
  87
  88
  89
  90
  91
  92
  93
  94
  95
  96
  97
  98
  99
 100
 101
 102
 103
 104
 105
 106
 107
 108
 109
 110
 111
 112
 113
 114
 115
 116
 117
 118
 119
 120
 121
 122
 123
 124
 125
 126
 127
 128
 129
 130
 131
 132
 133
 134
 135
 136
 137
 138
 139
 140
 141
 142
 143
 144
 145
 146
 147
 148
 149
 150
 151
 152
 153
 154
 155
 156
 157
 158
 159
 160
 161
 162
 163
 164
 165
 166
 167
 168
 169
 170
 171
 172
 173
 174
 175
 176
 177
 178
 179
 180
 181
 182
 183
 184
 185
 186
 187
 188
 189
 190
 191
 192
 193
 194
 195
 196
 197
 198
 199
 200
 201
 202
 203
 204
 205
 206
 207
 208
 209
 210
 211
 212
 213
 214
 215
 216
 217
 218
 219
 220
 221
 222
 223
 224
 225
 226
 227
 228
 229
 230
 231
 232
 233
 234
 235
 236
 237
 238
 239
 240
 241
 242
 243
 244
 245
 246
 247
 248
 249
 250
 251
 252
 253
 254
 255
 256
 257
 258
 259
 260
 261
 262
 263
 264
 265
 266
 267
 268
 269
 270
 271
 272
 273
 274
 275
 276
 277
 278
 279
 280
 281
 282
 283
 284
 285
 286
 287
 288
 289
 290
 291
 292
 293
 294
 295
 296
 297
 298
 299
 300
 301
 302
 303
 304
 305
 306
 307
 308
 309
 310
 311
 312
 313
 314
 315
 316
 317
 318
 319
 320
 321
 322
 323
 324
 325
 326
 327
 328
 329
 330
 331
 332
 333
 334
 335
 336
 337
 338
 339
 340
 341
 342
 343
 344
 345
 346
 347
 348
 349
 350
 351
 352
 353
 354
 355
 356
 357
 358
 359
 360
 361
 362
 363
 364
 365
 366
 367
 368
 369
 370
 371
 372
 373
 374
 375
 376
 377
 378
 379
 380
 381
 382
 383
 384
 385
 386
 387
 388
 389
 390
 391
 392
 393
 394
 395
 396
 397
 398
 399
 400
 401
 402
 403
 404
 405
 406
 407
 408
 409
 410
 411
 412
 413
 414
 415
 416
 417
 418
 419
 420
 421
 422
 423
 424
 425
 426
 427
 428
 429
 430
 431
 432
 433
 434
 435
 436
 437
 438
 439
 440
 441
 442
 443
 444
 445
 446
 447
 448
 449
 450
 451
 452
 453
 454
 455
 456
 457
 458
 459
 460
 461
 462
 463
 464
 465
 466
 467
 468
 469
 470
 471
 472
 473
 474
 475
 476
 477
 478
 479
 480
 481
 482
 483
 484
 485
 486
 487
 488
 489
 490
 491
 492
 493
 494
 495
 496
 497
 498
 499
 500
 501
 502
 503
 504
 505
 506
 507
 508
 509
 510
 511
 512
 513
 514
 515
 516
 517
 518
 519
 520
 521
 522
 523
 524
 525
 526
 527
 528
 529
 530
 531
 532
 533
 534
 535
 536
 537
 538
 539
 540
 541
 542
 543
 544
 545
 546
 547
 548
 549
 550
 551
 552
 553
 554
 555
 556
 557
 558
 559
 560
 561
 562
 563
 564
 565
 566
 567
 568
 569
 570
 571
 572
 573
 574
 575
 576
 577
 578
 579
 580
 581
 582
 583
 584
 585
 586
 587
 588
 589
 590
 591
 592
 593
 594
 595
 596
 597
 598
 599
 600
 601
 602
 603
 604
 605
 606
 607
 608
 609
 610
 611
 612
 613
 614
 615
 616
 617
 618
 619
 620
 621
 622
 623
 624
 625
 626
 627
 628
 629
 630
 631
 632
 633
 634
 635
 636
 637
 638
 639
 640
 641
 642
 643
 644
 645
 646
 647
 648
 649
 650
 651
 652
 653
 654
 655
 656
 657
 658
 659
 660
 661
 662
 663
 664
 665
 666
 667
 668
 669
 670
 671
 672
 673
 674
 675
 676
 677
 678
 679
 680
 681
 682
 683
 684
 685
 686
 687
 688
 689
 690
 691
 692
 693
 694
 695
 696
 697
 698
 699
 700
 701
 702
 703
 704
 705
 706
 707
 708
 709
 710
 711
 712
 713
 714
 715
 716
 717
 718
 719
 720
 721
 722
 723
 724
 725
 726
 727
 728
 729
 730
 731
 732
 733
 734
 735
 736
 737
 738
 739
 740
 741
 742
 743
 744
 745
 746
 747
 748
 749
 750
 751
 752
 753
 754
 755
 756
 757
 758
 759
 760
 761
 762
 763
 764
 765
 766
 767
 768
 769
 770
 771
 772
 773
 774
 775
 776
 777
 778
 779
 780
 781
 782
 783
 784
 785
 786
 787
 788
 789
 790
 791
 792
 793
 794
 795
 796
 797
 798
 799
 800
 801
 802
 803
 804
 805
 806
 807
 808
 809
 810
 811
 812
 813
 814
 815
 816
 817
 818
 819
 820
 821
 822
 823
 824
 825
 826
 827
 828
 829
 830
 831
 832
 833
 834
 835
 836
 837
 838
 839
 840
 841
 842
 843
 844
 845
 846
 847
 848
 849
 850
 851
 852
 853
 854
 855
 856
 857
 858
 859
 860
 861
 862
 863
 864
 865
 866
 867
 868
 869
 870
 871
 872
 873
 874
 875
 876
 877
 878
 879
 880
 881
 882
 883
 884
 885
 886
 887
 888
 889
 890
 891
 892
 893
 894
 895
 896
 897
 898
 899
 900
 901
 902
 903
 904
 905
 906
 907
 908
 909
 910
 911
 912
 913
 914
 915
 916
 917
 918
 919
 920
 921
 922
 923
 924
 925
 926
 927
 928
 929
 930
 931
 932
 933
 934
 935
 936
 937
 938
 939
 940
 941
 942
 943
 944
 945
 946
 947
 948
 949
 950
 951
 952
 953
 954
 955
 956
 957
 958
 959
 960
 961
 962
 963
 964
 965
 966
 967
 968
 969
 970
 971
 972
 973
 974
 975
 976
 977
 978
 979
 980
 981
 982
 983
 984
 985
 986
 987
 988
 989
 990
 991
 992
 993
 994
 995
 996
 997
 998
 999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
#! @PERL@

# --8<--8<--8<--8<--
#
# Copyright (C) 2008-2012 Smithsonian Astrophysical Observatory
#
# This file is part of wikiup
#
# wikiup is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or (at
# your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.
#
# -->8-->8-->8-->8--


use vars qw( $Config::Tiny::errstr );

use strict;
use warnings;

use autouse 'File::Basename' => 'basename';
use autouse 'Pod::Usage' => 'pod2usage';

use constant FOSWIKISTRIKEONE => 'FOSWIKISTRIKEONE';

use Getopt::Long;

our $VERSION = '@VERSION@';

our %ARGV;

#--------------------------------------------------------------------

eval { main() };
if ( $@ )
{
    print STDERR "# wikiup: $_\n" foreach split /\n/, $@;
    exit 1;
}

exit(0);

#--------------------------------------------------------------------

sub msg(@)   { my $f = $ARGV{verbose} > 0; @_ && $f ? print @_  : $f }
sub info(@)  { my $f = $ARGV{verbose} > 1; @_ && $f ? print @_  : $f }
sub debug(@) { my $f = $ARGV{verbose} > 2; @_ && $f ? print STDERR @_ : $f }
sub debug_dump(@) { return unless debug();
		    require Data::Dumper;
		    debug( Data::Dumper->Dump( @_ ) );
		}

#--------------------------------------------------------------------

sub main
{
    parse_cmdline();

    usage(2) if $ARGV{man};
    usage(1) if $ARGV{help};
    usage(0) if $ARGV{usage};

    do { print "wikiup $VERSION\n"; return }
      if $ARGV{version};

    my ( $config, $topic_path ) = config();

    my $files = transform_files( $config, $ARGV{files} );

    check_files( $files );

    upload_files( $config, $topic_path, $files );

    return;
}

#--------------------------------------------------------------------
# make sure files to be uploaded exist and are readable

sub check_files {

    my ( $files ) = @_;

    die( "no files were specified\n" )
      unless @$files;

    my @badfiles = grep { ! -r $_ || -d _ } map { $_->{disk} } @$files;
    die(  join( "\n   ", "non-existent or unreadable files: ", @badfiles ),
	  "\n" ) if @badfiles;

    return;
}

#--------------------------------------------------------------------
# read configuration file, override with command line args and 
# do initial topic path parsing.

sub config {

  my $config = WikiUp::Config->new( $ARGV{config}, '.wikiuprc'  );

  $config->set_profile( $ARGV{profile} ) if defined $ARGV{profile};

  my ( $uri, $bin_path, $topic_path ) = create_bin_uri( $config );

  # if the topic_path hasn't been determined or a profile hasn't been
  # specified, try to match the command line destination to the
  # profiles
  if ( ! defined $topic_path || $config->is_default_profile )
  {
      # this will set the current profile to that matched
      my ( $match, $rpath ) = $config->match_uri( $uri );

      # matched! use the newly parsed topic path if necessary
      if ( $match )
      {
	  info "Matched profile: ", $config->profile, "\n";
	  $topic_path = $rpath unless defined $topic_path;
      }

      # no matching profile, but have a topic path; that's sufficient
      elsif ( defined $topic_path )
      {
	  $config->set( uri => $uri );
      }

      # failure; no match and no topic path
      else
      {
	  die( "unable to determine base url from $uri\n" )
      }
  }

  # update profile with command line options
  $bin_path =
                 defined $ARGV{bin_path}              ? $ARGV{bin_path}
	       : defined $config->get( 'bin_path' )   ?  $config->get( 'bin_path' )
	       : defined $bin_path && $bin_path ne '' ? $bin_path
	       :                                        'bin';

  $config->set( bin_path => $bin_path );

  my $sleep =
              defined $ARGV{sleep}          ? $ARGV{sleep}
	    : defined $config->get('sleep') ? $config->get('sleep') 
	    :                                 5;
  $config->set( sleep => $sleep );

  $config->set( transform => $ARGV{transform} )
    if defined $ARGV{transform} && ! defined $config->get( 'transform' );

  # copy over ordinary variables
  $config->set( $_ => $ARGV{$_} )
    foreach grep { defined $ARGV{$_} } qw[ user insecure segment ];

  # set attributes
  $config->set_attr( $_ ) foreach split( ',', $ARGV{attrs} );

  return ( $config, $topic_path );
}

#--------------------------------------------------------------------

sub transform_files {

    my ( $config, $argv ) = @_;

    my @files;

    if ( $ARGV{rename} && defined $config->get( 'transform' ) )
    {
	warn( "command line --rename overrides configuration file transform\n" );
    }

    if ( $ARGV{rename} )
    {
	die( "odd number of filenames: --rename requires an even number\n" )
	  if @$argv %2;

	while( my ( $disk, $upload ) = splice( @$argv, 0, 2 ) )
	{

	    push @files, { disk => $disk,
			   upload => basename($upload)
			 };
	}

    }

    elsif ( $config->get( 'transform' ) )
    {
	local $_;
	for my $disk ( @$argv )
	{
	    $_ = $disk;
	    eval $config->get( 'transform' );
	    die( "error transforming $disk: $@\n" ) if $@;
	    push @files, { disk => $disk,
			   upload => basename($_)
			 };
	}
    }

    else
    {
	@files = map { { disk => $_ } } @$argv;
    }

    return \@files;

}

#--------------------------------------------------------------------

sub create_bin_uri {

    my ( $config ) = @_;

    my ( $bin_path, $topic_path);

    my $uri = $config->get( 'uri' );

    # does the current profile have a uri? if so the command line
    # destination is the topic path
    if ( defined $uri )
    {
	$topic_path = defined $config->get( 'web' )
	            ? $config->get( 'web' ) . '/' . $ARGV{dest}
		    : $ARGV{dest};
    }

    # no; try to derive the base url and topic path from the command
    # line destination
    else
    {
	require URI;
	$uri = URI->new( $ARGV{dest} )->canonical;

	die( "destination isn't a recognizeable URL: $ARGV{dest}\n" )
	  unless defined $uri->scheme;

	my @segments = $uri->path_segments;
	my $web;

	# user has not specified the path segment at which to
	# truncate, so search for evidence of a bin directory and use
	# that to set the truncate segment
	if ( !defined $ARGV{segment} )
	{
	    ( $ARGV{segment} ) =
	      grep { $segments[$_] =~ /bin|cgi-bin/ } 0..@segments-1;

	    # FIXME: ugly return in the middle of the routine.
	    return ( $uri, $bin_path, $topic_path )
	      if ! defined $ARGV{segment};

	    $ARGV{segment}--;
	    $web = $ARGV{segment} + 3;
	}

	else
	{
	    $web = $ARGV{segment} + 1;
	}

	$uri->path_segments( @segments[0..$ARGV{segment}] );
	$uri = $uri->canonical;

	$topic_path = join( '/', @segments[$web..@segments-1] );
    }

    return ( $uri, $bin_path, $topic_path );
}

#--------------------------------------------------------------------

sub upload_files {

  my ( $config, $topic_path, $files ) = @_;

  my $uri = $config->get( 'uri' )->clone;

  $uri->path_segments
    ( grep { $_ ne '' } $uri->path_segments,
      split( '/', $config->get( 'bin_path' ) ),
      'attach',
      split( '/', $topic_path  )
    );


  info "Base URI: " . $config->get( 'uri' ) . "\n",
       "Topic path: $topic_path\n",
       "URI: $uri\n"
	 ;

  my $ua = WikiUp::UserAgent->new( config => $config, quiet => 1 );

  push @{ $ua->requests_redirectable }, 'POST';

  require IO::Handle;
  STDOUT->autoflush(1);

  while ( @$files )
  {
      my $file = shift @$files;

      print " $file->{disk}",
	        $file->{upload} ? " as $file->{upload}" : ()
	if msg() || $ARGV{interactive};

      print "\n" if msg() && ! $ARGV{interactive};

      next if $ARGV{dryrun};

      if ( $ARGV{interactive} )
      {
	  print "? ";
	  my $response;
	  while ( 1 )
	  {
	      chomp( $response = <STDIN> );
	      last if $response =~ /(y|yes|n|no)/i;
	      print "Please enter y/yes or n/no: ";
	  }
	  next if $response =~ /n/i;
      }

      # Foswiki requires a modified validation key to be uploaded with
      # the file (if the validation method is strikeone).  It seems
      # the only means of getting the original key is from a Foswiki
      # generated attachment form.  So we end up web-scraping the form
      # for the key, modifying it, and then submitting the form.
      # Otherwise, we could just use bin/upload

      # TWiki (<= 5.?) doesn't perform the same sort of validation, so
      # technically one could use bin/upload directly.  For the sake
      # of keeping the code simple, I've decided to use the
      # screen-scraping method for both.

      $ua->get( $uri );
      die( "error accessing Topic ($topic_path) via $uri: ",
	   $ua->response->message, "\n")
	unless $ua->success;

      # we may have been directed to a login form; if so log in
      if ( defined $ua->form_name( 'loginform' ) )
      {
	  info "Found login form\n";
	  my ($user, $password) = $ua->get_basic_credentials;
	  $ua->set_fields( username => $user,
			   password => $password );
	  $ua->click();
      }

      # select the attachment form by the fields present.  could just
      # use the form name "main", but that seems so generic I'm
      # guessing it'll get changed one day
      unless ( $ua->form_with_fields( qw( filepath createlink hidefile ) ) ) {

	  debug( $ua->response->message );
	  die( "error accessing Topic: $topic_path\n" );
      }

      # form fields not related to validation
      my %fields = ( createlink => $config->get_attr( 'link' ),
		     filecomment => $ARGV{comment},
		     filepath => $file->{disk},
		     hidefile => $config->get_attr( 'hide' )
		   );


      # see if we're connected to Foswiki and need to handle validation. Look for
      # Foswiki specific cookies
      my %cookie;
      my $host = $ua->uri->host;

      debug "Host: $host\n";
      debug "Cookies: \n", $ua->cookie_jar->as_string, "\n";

      $ua->cookie_jar->scan( sub { my ( $version, $key, $val, $path, $domain ) = @_;
				   return unless $key =~ /^foswiki/i;

				   die( "Found Foswiki cookie ($key), but host ($host) doesn't match domain ($domain)\n" )
				     if $host !~ /${domain}$/;

				   die( "Found Foswiki cookie ($key), but path ($path) doesn't match URL (",$ua->uri,")\n" )
				     if $ua->uri->path !~ /^$path/;

				   $cookie{$key} = $val;
			       } );

      # got some Foswiki cookies; let's play
      if ( keys %cookie )
      {
	  debug_dump [ \%cookie], [ 'Foswiki Cookies' ];

	  $fields{noredirect} = 1;

	  # handle strikeone validation method
	  if ( defined $cookie{FOSWIKISTRIKEONE()} )
	  {
	      my $validation_key = $ua->value( 'validation_key' );

	      die( "unable to find validation key in attach form\n" )
		unless $validation_key ne '';

	      if ( $validation_key =~ /^\?(.*)/ )
	      {
		  require Digest::MD5;
		  $fields{validation_key} =
			      Digest::MD5::md5_hex( $1, $cookie{FOSWIKISTRIKEONE()});
	      }
	  }
      }

      debug_dump [\%fields], ['Output Fields'];

      $ua->set_fields( %fields );

      # if the user requested that the file be renamed upon upload,
      # perform a little bit of form magic here.
      if ( defined $file->{upload} && $file->{upload} ne '' )
      {
	  my $form = $ua->current_form;
	  my $filepath = $form->find_input( 'filepath' );
	  $filepath->file( $file->{disk});
	  $filepath->filename( $file->{upload} );
      }

      $ua->click();

      eval { $ua->check_upload( $file, $topic_path ) };
      if ( $@ )
      {
	  die $@ unless $ARGV{keepgoing};
	  warn $@;
      }

      if ( $config->get( 'sleep' ) && @$files )
      {
	  msg " Sleeping . . .";
	  sleep( $config->get( 'sleep' ) );
	  msg "\n";
      }
  }

  return;
}


#--------------------------------------------------------------------

sub parse_cmdline {

    %ARGV = (
	     attrs => '',
	     rename => 0,
	     verbose => 0,
	     interactive => 0,
	    );

    eval {
	local $SIG{__WARN__} = sub { die $_[0] };

	GetOptions( \%ARGV,
		    qw/
			  attrs|a=s
			  comment|c=s
			  config|f=s
			  dryrun|n
			  help
			  insecure
			  interactive|i
			  keepgoing|k
			  man
			  profile=s
			  rename|r
			  segment|w=i
			  sleep|s=f
			  transform|t=s
			  bin_path=s
			  usage
			  user|u=s
			  verbose|v:+
			  version
		      /);
    };

    die $@ if $@;

    return if grep { $ARGV{$_} } qw( help man usage version );

    $ARGV{dest} = shift @ARGV
      or die( "destination was not specified\n" );

    die( "specify only one of --rename or --transform\n" )
      if defined $ARGV{transform} && $ARGV{rename};

    $ARGV{files} = \@ARGV;

    $ARGV{verbose}++ if $ARGV{dryrun} && ! $ARGV{verbose};

    $ARGV{sleep} = 0 if $ARGV{interactive};

    return;
}

#--------------------------------------------------------------------

sub usage {

    my ( $verbose ) = @_;

    pod2usage( { -exitval => 0,
			     -verbose => $verbose,
			     });

    return;
}


#====================================================================

{
    package WikiUp::UserAgent;

    use base 'WWW::Mechanize';
    use autouse 'Term::ReadKey' => 'ReadMode';

    my @lattr;
    BEGIN { @lattr = qw( config ) }

    sub new {

	my ( $class, %cnf ) = @_;

	my %lcnf;
	@lcnf{@lattr} = map { delete $cnf{$_} } @lattr;

	if ( $lcnf{config}->get('insecure') ) {

	    $cnf{ssl_opts} = { verify_hostname => 0 };
	    eval { require IO::Socket::SSL;

		   $cnf{ssl_opts}{SSL_verify_mode}
		       = IO::Socket::SSL::SSL_VERIFY_NONE();
	       };
	}

	my $self = $class->SUPER::new ( %cnf );

	# very very ugly. store my object data in the hash.  could one
	# day cause problems.  WWW::Mechanize uses this technique, so
	# maybe it's ok.
	$self->{wikiup} = {};
	$self->{wikiup}{$_} = $lcnf{$_} for keys %lcnf;

	# set up temporary cookie jar
	$self->cookie_jar( {} );

	return $self;
    }

    sub check_upload {

	my ( $self, $file, $topic_path  ) = @_;

	::info $self->content, "\n";

	my $errpfx = "Error uploading $file->{disk}: ";

	die( $errpfx, $self->response->message, ' (', $self->status, ")\n" )
	  unless $self->success;

	# horrible kludge to deal with TWiki
	if ( $self->content =~ /class='\w+Alert'/ )
	{
	    if ( my ( $bad, $what )
		 = $self->content =~ /"([^"]+)"\s+(topic|web) does not exist/ )
	    {
		$bad  =~ s{[.]}{/}g;
		die( $errpfx, "\u$what $bad does not exist\n" );
	    }
	    else
	    {
		require File::Temp;
		my $tmp = File::Temp->new( TEMPLATE => 'wikiupXXXX',
					   TMPDIR => 1,
					   SUFFIX => '.html',
					   UNLINK => 0 );
		$tmp->print( $self->content );
		$tmp->close;
		die( $errpfx, "unknown error; see $tmp for more information\n" );
	    }
	}

	return;
    }


    sub get_basic_credentials {

	my ( $self ) = @_;

	my $config = $self->{wikiup}{config};

	my $user = $config->get( 'user' );
	$user = $config->set( 'user', get_user() )
	  if ! defined $user;

	my $password = $config->get( 'password' );
	$password = $config->set( 'password', get_password() )
	  if ! defined $password;

	return ( $user, $password );
    }

    sub get_user
    {
	print "User: ";
	my $user = <STDIN>;
	chomp $user;
	return $user;
    }

    sub get_password
    {
	print "Password: ";

	ReadMode('noecho');
	my $password = <STDIN>;
	ReadMode('restore');
	print "\n";

	chomp $password;
	return $password;
    }

}

#====================================================================

{
    package WikiUp::Config;

    use autouse 'File::Spec::Functions' => qw( catfile );
    use autouse 'Fcntl' => qw( S_IMODE S_IRWXU );

    # legal attributes;
    my %ATTRSMAP;
    BEGIN {

	%ATTRSMAP = ( hide => [ hide => 1 ],
		      show => [ hide => 0 ],
		      link => [ link => 1 ],
		      'no-link' => [ link => 0 ],
		    );
    };

    sub new {

	my ( $class, $file, $default ) = @_;

	my $self;

	# first check local file
	if ( ! defined $file )
	{
	    # first check local dir
	    $self = _read_config( $default, 0 );
	}

	# if config is specified, it's an error if it doesn't exist
	else
	{
	    $self = _read_config( $file, 1 );
	}

	# if nothing has been read or read_root_config requested, read root 
	if ( ! $self || $self->{_}{read_root_config} )
	{
	    require File::HomeDir;
	    my $root = _read_config( catfile( File::HomeDir->my_home, $default ), 0 );

	    if ( $self )
	    {
		while ( my ( $profile, $data ) = each %$self )
		{
		    my $rp = $root->{$profile} || {};
		    $root->{$profile} = { %$rp, %$data };
		}
	    }

	    $self = $root;
	}


	bless $self, $class;

	# set up default profile
	if ( $self->{_}{profile} )
	{
	    $self->set_profile( $self->{_}{profile} );
	}
	else
	{
	    $self->reset_profile;
	}

	return $self;
    }



    sub match_uri {

	my ( $self, $uri ) = @_;

	my ( $match, $rpath );

	my @segs = $uri->path_segments;

	# determine the segment length of matches; choose
	# the match with the most segments.
	my @matches;
	while( my ( $name, $profile ) = each %{$self} )
	{
	    next unless defined $profile->{uri};

	    my $puri = $profile->{uri};

	    # need to ensure that the URI scheme and authority match
	    next unless
	           $uri->scheme    eq $puri->scheme
		&& $uri->authority eq $puri->authority;

	    # now check path segments and record the maximum number of
	    # leading segments which matched.

	    # path_segments returns an extra empty segment if there
	    # are no segments.
	    my @psegs = $puri->path_segments;
	    pop @psegs
	      if @psegs == 2 && $psegs[0] eq '' && $psegs[1] eq '';

	    my $nsegs = @segs > @psegs ? @psegs : @segs;

	    my $nmatch = 0;
	    $nmatch++
	      while $nmatch < $nsegs && $psegs[$nmatch] eq $segs[$nmatch];

	    # reject unless the entire profile URI is matched
	    next unless $nmatch == @psegs;

	    push @matches, [ $nmatch, $name, $profile ]
	}

	if ( @matches )
	{
	    # choose the profile with the most matching segments
	    ( $match ) = sort { $b->[0] <=> $a->[0] } @matches;
	    ( $self->{profile}, $self->{default} ) = @{$match}[1,2];

	    # create a path from the residual non-matched path segments
	    $rpath = join('/', @segs[$match->[0]..@segs-1]);
	}


	return ( defined $match, $rpath );
    }

    sub profile { $_[0]->{profile} }

    sub set_profile {

	my ( $self, $profile ) = @_;

	die( "unknown profile: $profile\n" )
	  unless defined $self->{$profile} ;

	$self->{default} = $self->{$profile};

	return;
    }

    sub is_default_profile {
	return $_[0]->{default} == $_[0]->{'_'};
    }

    sub reset_profile { $_[0]->set_profile( '_' ) }

    sub set { $_[0]->{default}{$_[1]} = $_[2] }
    sub get { $_[0]->{default}{$_[1]} }


    # currently attrs are all boolean and %ATTRSMAP is used to
    # map their values.
    sub set_attr {
	my ( $self, $attr ) = @_;

	die( "illegal attribute: $attr" ) 
	  unless defined $ATTRSMAP{$attr};

	$self->set( @{$ATTRSMAP{$attr}} );
    }

    sub get_attr { goto &get };

    sub _read_config {

	my ( $file, $must_exist ) = @_;

	my $config = { '_' => {} };

	unless ( -f $file ) {

	    die( "configuration file ($file) does not exist\n" )
	      if $must_exist;

	    return $config;
	}

	::info "Reading configuration file $file\n";

	die( "$file: insecure permissions. ",
	     " only the owner should have read or write permissions\n" )
	  if S_IMODE((stat($file))[2]) & ~S_IRWXU();

	require Config::Tiny;

	$config = Config::Tiny->read( $file )
	  or die( "$file: ", $Config::Tiny::errstr, "\n" );

	# set up default root section.
	$config->{_} ||= {};

	require URI;

	# propagate default values to profiles
	my $default = $config->{_};

	while( my ( $name, $profile ) = each %$config )
	{
	    # ignore default section
	    next if $name eq '_';

	    $profile->{$_} = $default->{$_}
	      foreach grep { ! defined $profile->{$_} } keys %$default;

	    # delete variables expressly set to an empty string
	    delete $profile->{$_}
	      for grep { $profile->{$_} eq '' } keys %$profile;

	    $profile->{uri} = URI->new( $profile->{url} )->canonical
	      if defined $profile->{url};
	}

	return $config;
    }


}

#====================================================================


__END__


=head1 NAME

wikiup - upload content to a topic on a Foswiki or TWiki site.

=head1 SYNOPSIS

wikiup [options] destination files...

=head1 DESCRIPTION

B<wikiup> attaches one or more files to a topic on a site running
Foswiki or TWiki.  The user must specify the destination topic, the
files to upload, and, if required, credentials to access the site.  It
automatically recognizes the following authentication mechanisms:

=over

=item *

HTTP browser based Basic authentication (e.g. C<Foswiki::LoginManager::ApacheLogin> )

=item *

C<Foswiki::LoginManager::TemplateLogin>

=back


Customized values for parameters may be specified in a configuration
file, which contain multiple profiles (either for different wiki
sites, or for different ways of uploading to the same site).

=head2 Options And Arguments

=head3 Arguments

The required arguments (which typically follow any options on the
command line) are:

=over

=item I<destination>

Either the topic view URL or the topic path (see L</Specifying the
destination topic>).

=item I<files>

One or more files to upload.

=back

=head3 Options

Options may be abbreviated. Options which take values may be separated
from the values by whitespace or the "=" character.

=over

=item -w I<integer> | --segment=I<integer>

The number of components preceding the web name in a "shortened" URL.

=item -c I<comment> | --comment=I<comment>

The comment to be associated with the uploaded files.

=item -f I<filename> | --config=I<filename>

Use an alternative configuration file.

=item --insecure

Do I<not> verify host certificates when connecting to hosts using SSL.
This should only be necessary when connecting to hosts with self-signed
certificates.

=item -k

Ignore upload errors and plow on ahead.

=item -p I<profile> | --profile=I<profile>

Use the specified profile.

=item -u I<username> | --user=I<username>

The wiki username.  If not specified the user will be prompted.

=item --bin_path I<upload path>

The upload path relative to the Wiki's base url.  B<wikiup> usually
figures this out on its own, but may get it wrong if the wiki is using
"shortened" URLs.  It falls back to C</bin/upload>.

=item -a I<attrs> | --attr=I<attrs>

Specify a comma separated list of attributes.  For example,

  --attr=show,link

See L</Upload Attributes> for more information.

=item -r | --rename

Treat the list of files to be uploaded as a list of I<pairs> of files.
The first element in the pair is the filename as it exists on disk,
the second is the filename as it should be reported to the wiki.
See L<Renaming uploaded files> for more information.

=item -t I<perlexpr> | --transform I<perlexpr>

The filenames reported to the wiki will be transformed using the
supplied Perl expression, which should modify the C<$_> Perl variable.
See L<Renaming uploaded files> for more information.

=item -i | --interactive

Prompt before uploading each file.

=item -s I<seconds> | --sleep I<seconds>

Sleep the specified number of seconds between uploads to reduce load
and avoid blacklisting.  Defaults to 5 seconds.

=item -n | --dryrun

List which files will be uploaded, but don't actually upload anything.

=item -v | --verbose

Be verbose about what's happening.  Repeating the option increases the
verbosity.

=item --usage 

Output very short usage information and exit.


=item -h | --help

Output short usage information and exit.

=item --man

Output full usage information and exit.

=back

=head2 Specifying the destination topic

How you specify the destination topic path (e.g. C<Web/Topic>) depends
in part on how your wiki server is configured.  The URL used to view a
topic will typically have one of the following forms:

=over

=item * a "standard" URL

  http://server.name/wiki/<bin>/<view>/<topic path>

Note that I<< <bin> >> may be C<bin> or C<cgi-bin>, and I<< <view> >>
may be C<view> or C<view.cgi>.

=item * a "shortened" URL

  http://server.name/wiki/<topic path>

=back

You can specify the destination in one of the following ways:

=over

=item 1

Specify the URL in a profile in the configuration file:

Create a profile in your F<$HOME/.wikiuprc> configuration file with the base
url:

  [ mywiki ]
  url = http://server.name/wiki

When you use the C<-p> option and the profile has a URL, B<wikiup>
will treat the destination provided on the command line as a topic path.

  wikiup -p mywiki Web/Topic ...

If you forget to put the URL in the configuration file, B<wikiup> will
treat the command line destination as a full URL, which won't work.

=item 2

Use a "standard" view URL:

If the wiki site uses the "standard" form of the view URL, you can cut
and paste the view URL from your browser:

  wikiup http://server.name/wiki/bin/view/Web/Topic ...

B<wikiup> can usually figure out the topic path.  If it can't it'll
stop and output an error.  Please report this as a bug.  You can work
around this bug using approach 1 above.

=item 3

Use a "shortened" view URL:

If the wiki site uses the "standard" form of the view URL, you can cut
and paste the view URL from your browser.

Unfortunately in this case B<wikiup> can't reliably figure out where
the topic path begins.  There are two ways to tell it:

=over

=item 1

You can use the B<-w> option to tell it the number of segments (after
the server name) which precede the topic path in the URL.  For
example,

  wikiup -w 1 http://server.name/wiki/Web/Topic ...

=item 2

Create a profile in the configuration file with the base URL:

  [ mywiki ]
  url = http://server.name/wiki

and specify the shortened URL

  wikiup http://server.name/wiki/Web/Topic ...

This works because B<wikiup> will try to match against the URL's in
profiles if it can't figure out the topic path from the view URL.

=back

=back


=head2 Authentication

If the Wiki requires authentication, the user must specify a username
and password.  If they are not provided via the command line or the
configuration file, the user will be prompted.  For security reasons,
it is not possible to specify the password on the command line.

=head2 Profile Matching

If a profile is not specified via the B<-p> option, B<wikiup> will try
to select one in the user's configuration file by matching on the
base wiki URL.

=head2 Upload Attributes

Upload attributes indicate additional actions that can be performed
during the upload.  They may be specified via the B<--attrs> option
or in the configuration file.

=over

=item I<show> | I<hide>

These attributes indicate whether the uploaded files should be shown
in the attachment table.

=item I<link> | I<no-link>

These attributes indicates whether a link to the attachment should be added
in the topic text.

=back

=head1 CONFIGURATION FILE

B<wikup>'s behavior can be customized using a configuration file.  The
configuration file must be readable only by the user (because it may
contain passwords); if not, B<wikiup> will exit with an error message.

A configuration file may contain multiple profiles (either for
different wiki sites, or for different ways of uploading to the same
site).

=head2 Configuration file format

Lines which begin with C<#> are ignored.  Lines which have the form

  variable = value

define configuration variables, and lines which have the form

  [ profile_name ]

define a new profile.  Variable definitions which follow a profile
definition are part of that profile until a new profile is defined.

Variable definitions which I<precede> profile definitions are used as
defaults.

To unset a variable in a profile (e.g. to discard the default value),
set it to an empty value.

=head2 Variables

The following variables are recognized:

=over

=item C<url>

The base URL for the wiki site.

=item C<user>

The wiki user name used to authenticate with the wiki server

=item C<password>

The password used to authenticate with the wiki server

=item C<profile>

Specify the default profile.  Only useful in the default section of
the configuration file.

=item C<read_root_config>

If present in the default section of a configuration file, it causes
the root configuration file (F<$HOME/.wikiuprc>) to be
read. (This has no effect if it's in the root configuration file.)

=item C<web>

The web to which to upload the files.  This has meaning only if the
C<url> variable is also specified.  If this is specified, the
command line destination should be the topic name, without a web.

=item C<sleep>

The number of seconds to sleep between uploads.

=item C<insecure>

See the C<--insecure> option.

=item C<transform>

See the C<--transform> option.

=item C<segment>

See the C<--segment> option.

=item C<bin_path>

The path (relative to the base URL) of the upload command.  By default
it is C</bin/upload>.

=back

=head2 Specifying Upload Attributes

Upload attributes are specified in the same manner as variables.
Set them to C<1> to enable them, C<0> to disable them.

=head2 Configuration file location

By default B<wikiup> will first look in the current directory for
F<.wikiuprc>.  If that is not present, or if the C<read_root_config>
variable is set it will look for F<$HOME/.wikiuprc>.  B<wikiup> can be
persuaded to look elsewhere with the C<-f> option.


=head2 Configuration File Examples

  # Mickey Mouse has the same username and password on most sites
  user = MickeyMouse
  password = SqueakSqueak

  # Hide attachments and don't create links to them
  hide = 1
  link = 0

  # these are "shortened" URL sites; specify the URL so automatic
  # profile recognition works

  [ site1 ]
  url = http://site1/wiki

  [ site2 ]
  url = http://site2/wiki

  # reset the password so as to force password prompting for this site
  [ site3 ]
  url = http://site3/wiki
  password =

=head1 EXAMPLES

=head2 Renaming uploaded files

Foswiki and TWiki currently only allow a topic to include an attached
file (via C<%INCLUDE{ "%ATTACHURL%/filename" }%>) if it ends in
C<.txt> or C<.html>.  B<wikiup> supports two means of changing the
name that is reported to the wiki server, so that the user doesn't have
to rename the file prior to uploading it.

=over

=item * Use the B<--rename> option:

C<--rename> instructs B<wikiup> to treat the list of files to be uploaded
as a list of I<pairs> of files.  The first element in the pair is the
filename as it exists on disk, the second is the filename as it should
be reported to wiki.  For example,

  wikiup -p mysite -r Web/Topic file1.fit file1.fit.txt file2.x file2.txt

will upload F<file1.fit> as F<file1.fit.txt> and F<file2.x> as F<file2.txt>.

=item * Use the B<--transform> option:

This is a more advanced technique which uses a Perl expression to
transform the file name.  It is most useful when uploading a number of files
using a shell glob pattern, as in

  wikiup -p mysite Web/Topic foo.*

The Perl expression should modify the C<$_> Perl variable.  Here are a couple
of examples:

=over

=item Rename all files ending in C<.fit>, changing it to C<.txt>, using
Perl regular expressions:

  -t 's/.fit$/.txt/'

=item Append C<.txt> to all files ending in C<.fit>.

  -t '/.fit$/ and $_ .= ".txt"'
  -t 's/(.*.fit)$/$1.txt'

=back


=back

=head1 ERRORS

The following error messages may be output:

=head2 Command line errors

=over

=item C<no files were specified>

No files were specified on the command line.

=item C<destination isn't a recognizeable URL: $destination>

The URL specified on the command line isn't recognizable as a valid
URL.

=item C<unable to determine base url from $uri>

B<wikiup> was unable to determine which parts of the URL were the path
to the wiki web and topic

=item C<odd number of filenames: --rename requires an even number>

If the C<--rename> option is specified B<wikiup> expects that the
filenames on the command line come in pairs.  This message indicates
that an unpaired filename was specified.

=back

=head2 Upload errors

=over

=item C<non-existent or unreadable files: %s>

The listed files were either not found or were not readable.

=item C<error transforming $file: %s>

An error ocurred when performing a filename transformation.  Check the
Perl expression that was specified with the C<--transform> option for
syntax.

=item C<error accessing Topic: $topic via $url>

The wiki server indicated that the requested topic was not valid.

=item C<Found Foswiki cookie ($cookie), but host ($host) doesn't match domain ($domain)>

There is something wrong on the wiki server. the Foswiki generated cookie is not valid
on the wiki server.

=item C<Found Foswiki cookie ($key), but path ($path) doesn't match URL $uri>

There is something wrong on the wiki server. the Foswiki generated cookie is not valid
for the URL of the topic.

=item C<unable to find validation key in attach form>

There is something wrong on the wiki server. Foswiki generated a
C<STRIKEONE> cookie, but the C<STRIKEONE> validation key was not in the
attachment form on the wiki attach page for the requested topic.

=back

=head2 Configuration file errors

=over

=item C<$file: configuration file does not exist>

=item C<unknown profile: $profile>

The profile specified via the C<--profile> option does not exist in
the configuration file(s).

=item C<illegal attribute: $attr>

An attribute was specified which is not valid.

=item C<$file: insecure permissions>

The configuration flie must be readable only by the owner of the file.

=back

=head1 BUGS

None reported.

=head1 FILES

=over

=item F<$HOME/.wikiuprc>

The user's configuration file.

=back

=head1 COPYRIGHT AND LICENSE

Copyright 2008-2012 The Smithsonian Astrophysical Observatory.
B<wikiup> is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation, either version 3 of the License, or (at
your option) any later version.

=head1 AUTHOR

Diab Jerius E<lt>djerius@cfa.harvard.eduE<gt>
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.