Wiki

Example SPARQL Queries

Endpoint: http://137.92.56.159:40935/glycostore_launch/query

More examples are provided in ./src/test/sparqlExampleTest.java

Search by Identifier

PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan/> 
 SELECT DISTINCT ?SaccharideURI ?Uoxf 
  WHERE {
?SaccharideURI glycan:has_glycobase_id 723;
 glycan:has_uoxf ?Uoxf .
}

Structures from a Collection

PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan/> 
 SELECT DISTINCT ?Uoxf ?GlycoBaseId
  WHERE {
?ReferenceCompoundURI glycan:is_from_report "O-Glycans" ;
 glycan:has_glycan ?SaccharideURI.
?SaccharideURI glycan:has_uoxf ?Uoxf ;
 glycan:has_glycobase_id ?GlycoBaseId.
}

Structures from Sample

 PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan/> 
 SELECT DISTINCT ?Uoxf ?GlycoBaseId
  WHERE {
?ReferenceCompoundURI glycan:is_from_source ?SourceURI ;
 glycan:has_glycan ?SaccharideURI.
?SourceURI glycan:from_sample "Cow" .
?SaccharideURI glycan:has_uoxf ?Uoxf ;
 glycan:has_glycobase_id ?GlycoBaseId.
}

Structures from a Publication

PREFIX glycan: <http://purl.jp/bio/12/glyco/glycan/> 
PREFIX dc: <http://purl.org/dc/elements/1.1/> 
 SELECT DISTINCT ?GlycoBaseId ?Uoxf ?LabelType (AVG(?Gu) AS ?avgGu) 
  WHERE {
?ReferenceCompoundURI glycan:published_in ?PaperURI ;
 glycan:has_lc_chromatogram_peak ?PeakURI ;
 glycan:is_from_profile ?ProfileURI ;
 glycan:has_glycan ?SaccharideURI .
?SaccharideURI glycan:has_glycobase_id ?GlycoBaseId ;
 glycan:has_uoxf ?Uoxf .
?ProfileURI glycan:has_label ?LabelType .
?PeakURI glycan:has_glucose_unit ?Gu .
?PaperURI dc:title "HPLC-based analysis of serum N-glycans on a 96-well plate platform with dedicated database software." .
}  GROUP BY ?GlycoBaseId ?Uoxf ?LabelType  ORDER BY ?avgGu

Library

GlycoStore_RDF.jar Java 8 required