aotus / source / aotus_module.f90

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
!> This module provides high level Fortran interfaces
!! to retrieve values from a Lua script.
module aotus_module
  use flu_binding
  use aot_kinds_module, only: double_k, single_k, long_k
  use aot_table_module, only: aot_table_getval

  implicit none

  private

  public :: aoterr_Fatal, aoterr_NonExistent, aoterr_WrongType
  public :: get_config_val, open_config, close_config
  public :: get_top_val, get_table_val

  !> Some parameters for the error handling.
  !!
  !! They indicate the bits to set in case of
  !! the corresponding error, to allow appropiate
  !! reactions of the calling application.
  integer, parameter :: aoterr_Fatal = 0
  integer, parameter :: aoterr_NonExistent = 1
  integer, parameter :: aoterr_WrongType = 2

  !> Get the value on top of the stack
  !!
  !! This is the most basic operation to
  !! retrieve a value.
  !! It is also most flexible in the sense,
  !! that it does not matter how the value
  !! actually gets on top of the stack by
  !! previous Lua operations.
  interface get_top_val
    module procedure get_top_real
    module procedure get_top_double
    module procedure get_top_integer
    module procedure get_top_long
    module procedure get_top_string
    module procedure get_top_logical
  end interface

  !> Get a global configuration value from the script.
  !!
  !! This provides a convenient direct access to
  !! global variables from the Lua script.
  !! \todo unify the arguments and naming with the rest
  !!       of the library, rename the config_val to key,
  !!       to make the interface more consistent.
  interface get_config_val
    module procedure get_config_real
    module procedure get_config_double
    module procedure get_config_integer
    module procedure get_config_long
    module procedure get_config_string
    module procedure get_config_logical
  end interface

  !> Get a value from a table.
  !!
  !! First the given !! key is looked up, if this fails, the value
  !! at the given position is looked up, and if this also fails,
  !! the default value is returned.
  !! Positional addressing is only valid, as long,
  !! as no value was provided by an explicit key
  !! in the list before the entry in question.
  interface get_table_val
    module procedure get_table_real
    module procedure get_table_double
    module procedure get_table_integer
    module procedure get_table_long
    module procedure get_table_string
    module procedure get_table_logical
  end interface

contains

  subroutine open_config(conf, filename)
    type(flu_State) :: conf
    character(len=*), intent(in) :: filename
    integer :: str_len

    conf = fluL_newstate()

    if (fluL_loadfile(conf, filename) .ne. 0) then
      write(*,*) "cannot load configuration file: ", &
        &        flu_tolstring(conf, -1, str_len)
      STOP
    end if

    call fluL_openlibs(conf)

    if (flu_pcall(conf, 0, 0, 0) .ne. 0) then
      write(*,*) "cannot run configuration file: ", &
        &        flu_tolstring(conf, -1, str_len)
      STOP
    end if

  end subroutine open_config


  subroutine close_config(conf)
    type(flu_State) :: conf

    call flu_close(conf)

  end subroutine close_config


  subroutine get_top_real(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    real(kind=single_k), intent(out) :: top_val
    integer, intent(out) :: ErrCode
    real(kind=single_k), optional, intent(in) :: default

    logical :: not_retrievable

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      if (flu_isNumber(conf, -1)) then
        top_val = flu_toNumber(conf, -1)
      else
        ErrCode = ibSet(ErrCode, aoterr_WrongType)
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
        not_retrievable = .true.
      end if
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_real


  subroutine get_top_double(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    real(kind=double_k), intent(out) :: top_val
    integer, intent(out) :: ErrCode
    real(kind=double_k), optional, intent(in) :: default

    logical :: not_retrievable

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      if (flu_isNumber(conf, -1)) then
        top_val = flu_toDouble(conf, -1)
      else
        ErrCode = ibSet(ErrCode, aoterr_WrongType)
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
        not_retrievable = .true.
      end if
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_double


  subroutine get_top_integer(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    integer, intent(out) :: top_val
    integer, intent(out) :: ErrCode
    integer, optional, intent(in) :: default

    logical :: not_retrievable

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      if (flu_isNumber(conf, -1)) then
        top_val = int(flu_toDouble(conf, -1))
      else
        ErrCode = ibSet(ErrCode, aoterr_WrongType)
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
        not_retrievable = .true.
      end if
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_integer

  subroutine get_top_long(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    integer(kind=long_k), intent(out) :: top_val
    integer, intent(out) :: ErrCode
    integer(kind=long_k), optional, intent(in) :: default

    logical :: not_retrievable

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      if (flu_isNumber(conf, -1)) then
        top_val = int(flu_toDouble(conf, -1),kind=long_k)
      else
        ErrCode = ibSet(ErrCode, aoterr_WrongType)
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
        not_retrievable = .true.
      end if
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_long

  subroutine get_top_logical(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    logical, intent(out) :: top_val
    integer, intent(out) :: ErrCode
    logical, optional, intent(in) :: default

    logical :: not_retrievable

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      if (flu_isBoolean(conf, -1)) then
        top_val = flu_toBoolean(conf, -1)
      else
        ErrCode = ibSet(ErrCode, aoterr_WrongType)
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
        not_retrievable = .true.
      end if
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_logical


  subroutine get_top_string(conf, top_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*) :: top_val
    integer, intent(out) :: ErrCode
    character(len=*), optional, intent(in) :: default

    logical :: not_retrievable
    character, pointer :: cstring(:)
    integer :: i, StrLen, StrLimit

    ErrCode = 0
    not_retrievable = .false.

    if (flu_isNoneOrNil(conf, -1)) then
      ErrCode = ibSet(ErrCode, aoterr_NonExistent)
      not_retrievable = .true.
    else
      cstring => flu_toLString(conf, -1, StrLen)
      StrLimit = min(StrLen, len(top_val))
      top_val = ''
      do i=1,StrLimit
        top_val(i:i) = cstring(i)
      end do
    end if

    if (not_retrievable) then
      if (present(default)) then
        top_val = default
      else
        ErrCode = ibSet(ErrCode, aoterr_Fatal)
      end if
    end if
    call flu_pop(conf)

  end subroutine get_top_string


  subroutine get_config_real(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    real(kind=single_k), intent(out) :: conf_val
    integer, intent(out) :: ErrCode
    real(kind=single_k), optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_real


  subroutine get_config_double(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    real(kind=double_k), intent(out) :: conf_val
    integer, intent(out) :: ErrCode
    real(kind=double_k), optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_double


  subroutine get_config_integer(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    integer, intent(out) :: conf_val
    integer, intent(out) :: ErrCode
    integer, optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_integer


  subroutine get_config_long(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    integer(kind=long_k), intent(out) :: conf_val
    integer, intent(out) :: ErrCode
    integer(kind=long_k), optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_long


  subroutine get_config_logical(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    logical, intent(out) :: conf_val
    integer, intent(out) :: ErrCode
    logical, optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_logical


  subroutine get_config_string(conf, var, conf_val, ErrCode, default)
    type(flu_State) :: conf
    character(len=*), intent(in) :: var
    character(len=*) :: conf_val
    integer, intent(out) :: ErrCode
    character(len=*), optional, intent(in) :: default

    call flu_getglobal(conf, var)
    call get_top_val(conf, conf_val, ErrCode, default)

  end subroutine get_config_string


  subroutine get_table_real(conf, thandle, tab_val, ErrCode, var, pos, default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    real(kind=single_k), intent(out) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    real(kind=single_k), intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_real


  subroutine get_table_double(conf, thandle, tab_val, ErrCode, var, pos, &
    &                         default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    real(kind=double_k), intent(out) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    real(kind=double_k), intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_double


  subroutine get_table_integer(conf, thandle, tab_val, ErrCode, var, pos, &
    &                          default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    integer, intent(out) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    integer, intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_integer

  subroutine get_table_long(conf, thandle, tab_val, ErrCode, var, pos, default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    integer(kind=long_k), intent(out) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    integer(kind=long_k), intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_long

  subroutine get_table_logical(conf, thandle, tab_val, ErrCode, var, pos, &
    &                          default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    logical, intent(out) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    logical, intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_logical


  subroutine get_table_string(conf, thandle, tab_val, ErrCode, var, pos, &
    &                         default)
    type(flu_State) :: conf
    integer, intent(in) :: thandle
    character(len=*) :: tab_val
    integer, intent(out) :: ErrCode

    character(len=*), intent(in), optional :: var
    integer, intent(in), optional :: pos
    character(len=*), intent(in), optional :: default

    call aot_table_getval(L=conf, thandle=thandle, &
      &                   key=var, pos=pos)
    call get_top_val(conf, tab_val, ErrCode, default)

  end subroutine get_table_string


end module aotus_module
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.