clojuresque / scriptoresque / src / main / groovy / clojuresque / ClojureScriptPlugin.groovy

The default branch has multiple heads

/*-
 * Copyright 2012 © Meikel Brandmeyer.
 * All rights reserved.
 *
 * Permission is hereby granted, free of charge, to any person obtaining a
 * copy of this software and associated documentation files (the "Software"),
 * to deal in the Software without restriction, including without limitation
 * the rights to use, copy, modify, merge, publish, distribute, sublicense,
 * and/or sell copies of the Software, and to permit persons to whom the
 * Software is furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included
 * in all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
 * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
 * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
 * IN THE SOFTWARE.
 */

package clojuresque

import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.internal.project.ProjectInternal

public class ClojureScriptPlugin implements Plugin<Project> {
    public void apply(Project project) {
        project.apply plugin: ClojureBasePlugin.class

        configureConfigurations(project)
        configureSourceSets(project)
        configureCompilation(project)
        configureGzip(project)
    }

    private void configureConfigurations(Project project) {
        project.dependencies {
            clojuresque group: "clojuresque", name: "scriptoresque-runtime",
                version: Util.properties.getProperty("clojuresque.version")
        }
    }

    private void configureSourceSets(Project project) {
        ProjectInternal projectInternal = (ProjectInternal)project

        project.sourceSets.each { sourceSet ->
            ClojureScriptSourceSet clojureScriptSourceSet =
                new ClojureScriptSourceSet(sourceSet.name, projectInternal.fileResolver)

            sourceSet.convention.plugins.clojureScript = clojureScriptSourceSet
            sourceSet.clojureScript.srcDirs = [ String.format("src/%s/cljs", sourceSet.name) ]
            sourceSet.resources.filter.exclude("**/*.cljs")
            sourceSet.allSource.source(clojureScriptSourceSet.clojureScript)
        }
    }

    private void configureCompilation(Project project) {
        project.sourceSets.each { set ->
            if (set.equals(project.sourceSets.test))
                return
            def File destDir = project.file(
                String.format("%s/javascript/%s", project.buildDir.path, set.name))

            String taskName = set.getCompileTaskName("clojureScript")
            ClojureScriptCompileTask task = project.tasks.add(name: taskName,
                    type: ClojureScriptCompileTask.class) {
                destinationDir = destDir
                outputFile = project.file("${destDir}/all.js")
                source set.clojureScript
                clojureScriptRoots = set.clojureScript
                classpath = project.files(
                    set.compileClasspath,
                    set.clojure.srcDirs,
                    project.configurations.development
                )
                description =
                    String.format("Compile the %s ClojureScript source.",
                            set.name)
            }
            project.tasks[set.classesTaskName].dependsOn task
        }
    }

    private void configureGzip(Project project) {
        project.sourceSets.each { set ->
            if (set.equals(project.sourceSets.test))
                return
            def File destDir = project.file(
                String.format("%s/javascript/%s", project.buildDir.path, set.name))

            String compileTaskName = set.getCompileTaskName("clojureScript")
            ClojureScriptCompileTask compileTask = project.tasks[compileTaskName]

            String taskName = set.getTaskName("gzip", "clojureScript")
            ClojureScriptGzipTask gzipTask = project.tasks.add(name: taskName,
                    type: ClojureScriptGzipTask.class) {
                destinationDir = destDir
                source compileTask
                description =
                    String.format("Gzip the %s ClojureScript compilate.",
                            set.name)
            }
        }
    }
}
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.