Source

riak / src / riak_delete.erl

%% This file is provided to you under the Apache License,
%% Version 2.0 (the "License"); you may not use this file
%% except in compliance with the License.  You may obtain
%% a copy of the License at

%%   http://www.apache.org/licenses/LICENSE-2.0

%% Unless required by applicable law or agreed to in writing,
%% software distributed under the License is distributed on an
%% "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
%% KIND, either express or implied.  See the License for the
%% specific language governing permissions and limitations
%% under the License.    

%% @doc Interface used by riak_api for object deletion.

-module(riak_delete).

-export([delete/5]).

%% @spec delete(riak_object:bucket(), riak_object:key(), RW :: integer(),
%%              TimeoutMillisecs :: integer(), Client :: pid()) -> term()
%% @doc Delete the object at Bucket/Key.  Direct return value is uninteresting,
%%      see riak_client:delete/3 for expected gen_server replies to Client.
delete(Bucket,Key,RW,Timeout,Client) ->           
    RealStartTime = riak_util:moment(),
    ReqID = erlang:phash2({random:uniform(),self(),Bucket,Key,RealStartTime}),
    riak_eventer:notify(riak_delete, delete_start, {ReqID, Bucket, Key}),
    case gen_server2:call({riak_api, node()},
                          {get,Bucket,Key,RW,Timeout}) of
        {ok, OrigObj} ->
            RemainingTime = Timeout - (riak_util:moment() - RealStartTime),
            OrigMD = hd([MD || {MD,_V} <- riak_object:get_contents(OrigObj)]),
            NewObj = riak_object:update_metadata(OrigObj,
                            dict:store(<<"X-Riak-Deleted">>, "true", OrigMD)),
            {ok, C} = riak:local_client(),
            Reply = C:put(NewObj, RW, RW, RemainingTime),
            case Reply of
                ok -> 
                    spawn(fun()-> riak_bucketkeys:del_key(Bucket,Key) end),
                    spawn(
                      fun()-> reap(Bucket,Key,RemainingTime,Timeout,ReqID) end);
                _ -> nop
            end,
            riak_eventer:notify(riak_delete, delete_reply, {ReqID, Reply}),
            gen_server2:reply(Client, Reply);
        {error, notfound} ->
            spawn(fun()-> riak_bucketkeys:del_key(Bucket,Key) end),
            riak_eventer:notify(riak_delete, delete_reply,
                                {ReqID, {error, notfound}}),
            gen_server2:reply(Client, {error, notfound});
        X ->
            riak_eventer:notify(riak_delete, delete_reply, {ReqID, X}),
            gen_server2:reply(Client, X)
    end.

reap(Bucket, Key, WaitTime, Timeout, ReqId) ->
    timer:sleep(WaitTime),
    case gen_server2:call({riak_api, node()}, 
                          {get, Bucket, Key, 1, Timeout}) of
        {error, notfound} ->
            riak_eventer:notify(riak_delete, finalize_reap, 
                                {ReqId, Bucket, Key, ok});
        {ok, _Obj} ->
            riak_eventer:notify(riak_delete, finalize_reap, 
                                {ReqId, Bucket, Key, not_deleted});
        O ->
            riak_eventer:notify(riak_delete, finalize_reap,
                                {ReqId, Bucket, Key, O})
    end.
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.