Source

unicode-internal / lisp / bytecomp.el

Full commit
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087
2088
2089
2090
2091
2092
2093
2094
2095
2096
2097
2098
2099
2100
2101
2102
2103
2104
2105
2106
2107
2108
2109
2110
2111
2112
2113
2114
2115
2116
2117
2118
2119
2120
2121
2122
2123
2124
2125
2126
2127
2128
2129
2130
2131
2132
2133
2134
2135
2136
2137
2138
2139
2140
2141
2142
2143
2144
2145
2146
2147
2148
2149
2150
2151
2152
2153
2154
2155
2156
2157
2158
2159
2160
2161
2162
2163
2164
2165
2166
2167
2168
2169
2170
2171
2172
2173
2174
2175
2176
2177
2178
2179
2180
2181
2182
2183
2184
2185
2186
2187
2188
2189
2190
2191
2192
2193
2194
2195
2196
2197
2198
2199
2200
2201
2202
2203
2204
2205
2206
2207
2208
2209
2210
2211
2212
2213
2214
2215
2216
2217
2218
2219
2220
2221
2222
2223
2224
2225
2226
2227
2228
2229
2230
2231
2232
2233
2234
2235
2236
2237
2238
2239
2240
2241
2242
2243
2244
2245
2246
2247
2248
2249
2250
2251
2252
2253
2254
2255
2256
2257
2258
2259
2260
2261
2262
2263
2264
2265
2266
2267
2268
2269
2270
2271
2272
2273
2274
2275
2276
2277
2278
2279
2280
2281
2282
2283
2284
2285
2286
2287
2288
2289
2290
2291
2292
2293
2294
2295
2296
2297
2298
2299
2300
2301
2302
2303
2304
2305
2306
2307
2308
2309
2310
2311
2312
2313
2314
2315
2316
2317
2318
2319
2320
2321
2322
2323
2324
2325
2326
2327
2328
2329
2330
2331
2332
2333
2334
2335
2336
2337
2338
2339
2340
2341
2342
2343
2344
2345
2346
2347
2348
2349
2350
2351
2352
2353
2354
2355
2356
2357
2358
2359
2360
2361
2362
2363
2364
2365
2366
2367
2368
2369
2370
2371
2372
2373
2374
2375
2376
2377
2378
2379
2380
2381
2382
2383
2384
2385
2386
2387
2388
2389
2390
2391
2392
2393
2394
2395
2396
2397
2398
2399
2400
2401
2402
2403
2404
2405
2406
2407
2408
2409
2410
2411
2412
2413
2414
2415
2416
2417
2418
2419
2420
2421
2422
2423
2424
2425
2426
2427
2428
2429
2430
2431
2432
2433
2434
2435
2436
2437
2438
2439
2440
2441
2442
2443
2444
2445
2446
2447
2448
2449
2450
2451
2452
2453
2454
2455
2456
2457
2458
2459
2460
2461
2462
2463
2464
2465
2466
2467
2468
2469
2470
2471
2472
2473
2474
2475
2476
2477
2478
2479
2480
2481
2482
2483
2484
2485
2486
2487
2488
2489
2490
2491
2492
2493
2494
2495
2496
2497
2498
2499
2500
2501
2502
2503
2504
2505
2506
2507
2508
2509
2510
2511
2512
2513
2514
2515
2516
2517
2518
2519
2520
2521
2522
2523
2524
2525
2526
2527
2528
2529
2530
2531
2532
2533
2534
2535
2536
2537
2538
2539
2540
2541
2542
2543
2544
2545
2546
2547
2548
2549
2550
2551
2552
2553
2554
2555
2556
2557
2558
2559
2560
2561
2562
2563
2564
2565
2566
2567
2568
2569
2570
2571
2572
2573
2574
2575
2576
2577
2578
2579
2580
2581
2582
2583
2584
2585
2586
2587
2588
2589
2590
2591
2592
2593
2594
2595
2596
2597
2598
2599
2600
2601
2602
2603
2604
2605
2606
2607
2608
2609
2610
2611
2612
2613
2614
2615
2616
2617
2618
2619
2620
2621
2622
2623
2624
2625
2626
2627
2628
2629
2630
2631
2632
2633
2634
2635
2636
2637
2638
2639
2640
2641
2642
2643
2644
2645
2646
2647
2648
2649
2650
2651
2652
2653
2654
2655
2656
2657
2658
2659
2660
2661
2662
2663
2664
2665
2666
2667
2668
2669
2670
2671
2672
2673
2674
2675
2676
2677
2678
2679
2680
2681
2682
2683
2684
2685
2686
2687
2688
2689
2690
2691
2692
2693
2694
2695
2696
2697
2698
2699
2700
2701
2702
2703
2704
2705
2706
2707
2708
2709
2710
2711
2712
2713
2714
2715
2716
2717
2718
2719
2720
2721
2722
2723
2724
2725
2726
2727
2728
2729
2730
2731
2732
2733
2734
2735
2736
2737
2738
2739
2740
2741
2742
2743
2744
2745
2746
2747
2748
2749
2750
2751
2752
2753
2754
2755
2756
2757
2758
2759
2760
2761
2762
2763
2764
2765
2766
2767
2768
2769
2770
2771
2772
2773
2774
2775
2776
2777
2778
2779
2780
2781
2782
2783
2784
2785
2786
2787
2788
2789
2790
2791
2792
2793
2794
2795
2796
2797
2798
2799
2800
2801
2802
2803
2804
2805
2806
2807
2808
2809
2810
2811
2812
2813
2814
2815
2816
2817
2818
2819
2820
2821
2822
2823
2824
2825
2826
2827
2828
2829
2830
2831
2832
2833
2834
2835
2836
2837
2838
2839
2840
2841
2842
2843
2844
2845
2846
2847
2848
2849
2850
2851
2852
2853
2854
2855
2856
2857
2858
2859
2860
2861
2862
2863
2864
2865
2866
2867
2868
2869
2870
2871
2872
2873
2874
2875
2876
2877
2878
2879
2880
2881
2882
2883
2884
2885
2886
2887
2888
2889
2890
2891
2892
2893
2894
2895
2896
2897
2898
2899
2900
2901
2902
2903
2904
2905
2906
2907
2908
2909
2910
2911
2912
2913
2914
2915
2916
2917
2918
2919
2920
2921
2922
2923
2924
2925
2926
2927
2928
2929
2930
2931
2932
2933
2934
2935
2936
2937
2938
2939
2940
2941
2942
2943
2944
2945
2946
2947
2948
2949
2950
2951
2952
2953
2954
2955
2956
2957
2958
2959
2960
2961
2962
2963
2964
2965
2966
2967
2968
2969
2970
2971
2972
2973
2974
2975
2976
2977
2978
2979
2980
2981
2982
2983
2984
2985
2986
2987
2988
2989
2990
2991
2992
2993
2994
2995
2996
2997
2998
2999
3000
3001
3002
3003
3004
3005
3006
3007
3008
3009
3010
3011
3012
3013
3014
3015
3016
3017
3018
3019
3020
3021
3022
3023
3024
3025
3026
3027
3028
3029
3030
3031
3032
3033
3034
3035
3036
3037
3038
3039
3040
3041
3042
3043
3044
3045
3046
3047
3048
3049
3050
3051
3052
3053
3054
3055
3056
3057
3058
3059
3060
3061
3062
3063
3064
3065
3066
3067
3068
3069
3070
3071
3072
3073
3074
3075
3076
3077
3078
3079
3080
3081
3082
3083
3084
3085
3086
3087
3088
3089
3090
3091
3092
3093
3094
3095
3096
3097
3098
3099
3100
3101
3102
3103
3104
3105
3106
3107
3108
3109
3110
3111
3112
3113
3114
3115
3116
3117
3118
3119
3120
3121
3122
3123
3124
3125
3126
3127
3128
3129
3130
3131
3132
3133
3134
3135
3136
3137
3138
3139
3140
3141
3142
3143
3144
3145
3146
3147
3148
3149
3150
3151
3152
3153
3154
3155
3156
3157
3158
3159
3160
3161
3162
3163
3164
3165
3166
3167
3168
3169
3170
3171
3172
3173
3174
3175
3176
3177
3178
3179
3180
3181
3182
3183
3184
3185
3186
3187
3188
3189
3190
3191
3192
3193
3194
3195
3196
3197
3198
3199
3200
3201
3202
3203
3204
3205
3206
3207
3208
3209
3210
3211
3212
3213
3214
3215
3216
3217
3218
3219
3220
3221
3222
3223
3224
3225
3226
3227
3228
3229
3230
3231
3232
3233
3234
3235
3236
3237
3238
3239
3240
3241
3242
3243
3244
3245
3246
3247
3248
3249
3250
3251
3252
3253
3254
3255
3256
3257
3258
3259
3260
3261
3262
3263
3264
3265
3266
3267
3268
3269
3270
3271
3272
3273
3274
3275
3276
3277
3278
3279
3280
3281
3282
3283
3284
3285
3286
3287
3288
3289
3290
3291
3292
3293
3294
3295
3296
3297
3298
3299
3300
3301
3302
3303
3304
3305
3306
3307
3308
3309
3310
3311
3312
3313
3314
3315
3316
3317
3318
3319
3320
3321
3322
3323
3324
3325
3326
3327
3328
3329
3330
3331
3332
3333
3334
3335
3336
3337
3338
3339
3340
3341
3342
3343
3344
3345
3346
3347
3348
3349
3350
3351
3352
3353
3354
3355
3356
3357
3358
3359
3360
3361
3362
3363
3364
3365
3366
3367
3368
3369
3370
3371
3372
3373
3374
3375
3376
3377
3378
3379
3380
3381
3382
3383
3384
3385
3386
3387
3388
3389
3390
3391
3392
3393
3394
3395
3396
3397
3398
3399
3400
3401
3402
3403
3404
3405
3406
3407
3408
3409
3410
3411
3412
3413
3414
3415
3416
3417
3418
3419
3420
3421
3422
3423
3424
3425
3426
3427
3428
3429
3430
3431
3432
3433
3434
3435
3436
3437
3438
3439
3440
3441
3442
3443
3444
3445
3446
3447
3448
3449
3450
3451
3452
3453
3454
3455
3456
3457
3458
3459
3460
3461
3462
3463
3464
3465
3466
3467
3468
3469
3470
3471
3472
3473
3474
3475
3476
3477
3478
3479
3480
3481
3482
3483
3484
3485
3486
3487
3488
3489
3490
3491
3492
3493
3494
3495
3496
3497
3498
3499
3500
3501
3502
3503
3504
3505
3506
3507
3508
3509
3510
3511
3512
3513
3514
3515
3516
3517
3518
3519
3520
3521
3522
3523
3524
3525
3526
3527
3528
3529
3530
3531
3532
3533
3534
3535
3536
3537
3538
3539
3540
3541
3542
3543
3544
3545
3546
3547
3548
3549
3550
3551
3552
3553
3554
3555
3556
3557
3558
3559
3560
3561
3562
3563
3564
3565
3566
3567
3568
3569
3570
3571
3572
3573
3574
3575
3576
3577
3578
3579
3580
3581
3582
3583
3584
3585
3586
3587
3588
3589
3590
3591
3592
3593
3594
3595
3596
3597
3598
3599
3600
3601
3602
3603
3604
3605
3606
3607
3608
3609
3610
3611
3612
3613
3614
3615
3616
3617
3618
3619
3620
3621
3622
3623
3624
3625
3626
3627
3628
3629
3630
3631
3632
3633
3634
3635
3636
3637
3638
3639
3640
3641
3642
3643
3644
3645
3646
3647
3648
3649
3650
3651
3652
3653
3654
3655
3656
3657
3658
3659
3660
3661
3662
3663
3664
3665
3666
3667
3668
3669
3670
3671
3672
3673
3674
3675
3676
3677
3678
3679
3680
3681
3682
3683
3684
3685
3686
3687
3688
3689
3690
3691
3692
3693
3694
3695
3696
3697
3698
3699
3700
3701
3702
3703
3704
3705
3706
3707
3708
3709
3710
3711
3712
3713
3714
3715
3716
3717
3718
3719
3720
3721
3722
3723
3724
3725
3726
3727
3728
3729
3730
3731
3732
3733
3734
3735
3736
3737
3738
3739
3740
3741
3742
3743
3744
3745
3746
3747
3748
3749
3750
3751
3752
3753
3754
3755
3756
3757
3758
3759
3760
3761
3762
3763
3764
3765
3766
3767
3768
3769
3770
3771
3772
3773
3774
3775
3776
3777
3778
3779
3780
3781
3782
3783
3784
3785
3786
3787
3788
3789
3790
3791
3792
3793
3794
3795
3796
3797
3798
3799
3800
3801
3802
3803
3804
3805
3806
3807
3808
3809
3810
3811
3812
3813
3814
3815
3816
3817
3818
3819
3820
3821
3822
3823
3824
3825
3826
3827
3828
3829
3830
3831
3832
3833
3834
3835
3836
3837
3838
3839
3840
3841
3842
3843
3844
3845
3846
3847
3848
3849
3850
3851
3852
3853
3854
3855
3856
3857
3858
3859
3860
3861
3862
3863
3864
3865
3866
3867
3868
3869
3870
3871
3872
3873
3874
3875
3876
3877
3878
3879
3880
3881
3882
3883
3884
3885
3886
3887
3888
3889
3890
3891
3892
3893
3894
3895
3896
3897
3898
3899
3900
3901
3902
3903
3904
3905
3906
3907
3908
3909
3910
3911
3912
3913
3914
3915
3916
3917
3918
3919
3920
3921
3922
3923
3924
3925
3926
3927
3928
3929
3930
3931
3932
3933
3934
3935
3936
3937
3938
3939
3940
3941
3942
3943
3944
3945
3946
3947
3948
3949
3950
3951
3952
3953
3954
3955
3956
3957
3958
3959
3960
3961
3962
3963
3964
3965
3966
3967
3968
3969
3970
3971
3972
3973
3974
3975
3976
3977
3978
3979
3980
3981
3982
3983
3984
3985
3986
3987
3988
3989
3990
3991
3992
3993
3994
3995
3996
3997
3998
3999
4000
4001
4002
4003
4004
4005
4006
4007
4008
4009
4010
4011
4012
4013
4014
4015
4016
4017
4018
4019
4020
4021
4022
4023
4024
4025
4026
4027
4028
4029
4030
4031
4032
4033
4034
4035
4036
4037
4038
4039
4040
4041
4042
4043
4044
4045
4046
4047
4048
4049
4050
4051
4052
4053
4054
4055
4056
4057
4058
4059
4060
4061
4062
4063
4064
4065
4066
4067
4068
4069
4070
4071
4072
4073
4074
4075
4076
4077
4078
4079
4080
4081
4082
4083
4084
4085
4086
4087
4088
4089
4090
4091
4092
4093
4094
4095
4096
4097
4098
4099
4100
4101
4102
4103
4104
4105
4106
4107
4108
4109
4110
4111
4112
4113
4114
4115
4116
4117
4118
4119
4120
4121
4122
4123
4124
4125
4126
4127
4128
4129
4130
4131
4132
4133
4134
4135
4136
4137
4138
4139
4140
4141
4142
4143
4144
4145
4146
4147
4148
4149
4150
4151
4152
4153
4154
4155
4156
4157
4158
4159
4160
4161
4162
4163
4164
4165
4166
4167
4168
4169
4170
4171
4172
4173
4174
4175
4176
4177
4178
4179
4180
4181
4182
4183
4184
4185
4186
4187
4188
4189
4190
4191
4192
4193
4194
4195
4196
4197
4198
4199
4200
4201
4202
4203
4204
4205
4206
4207
4208
4209
4210
4211
4212
4213
4214
4215
4216
4217
4218
4219
4220
4221
4222
4223
4224
4225
4226
4227
4228
4229
4230
4231
4232
4233
4234
4235
4236
4237
4238
4239
4240
4241
4242
4243
4244
4245
4246
4247
4248
4249
4250
4251
4252
4253
4254
4255
4256
4257
4258
4259
4260
4261
4262
4263
4264
4265
4266
4267
4268
4269
4270
4271
4272
4273
4274
4275
4276
4277
4278
4279
4280
4281
4282
4283
4284
4285
4286
4287
4288
4289
4290
4291
4292
4293
4294
4295
4296
4297
4298
4299
4300
4301
4302
4303
4304
4305
4306
4307
4308
4309
4310
4311
4312
4313
4314
4315
4316
4317
4318
4319
4320
4321
4322
4323
4324
4325
4326
4327
4328
4329
4330
4331
4332
4333
4334
4335
4336
4337
4338
4339
4340
4341
4342
4343
4344
4345
4346
4347
4348
4349
4350
4351
4352
4353
4354
4355
4356
4357
4358
4359
4360
4361
4362
4363
4364
4365
4366
4367
4368
4369
4370
4371
4372
4373
4374
4375
4376
4377
4378
4379
4380
4381
4382
4383
4384
4385
4386
4387
4388
4389
4390
4391
4392
4393
4394
4395
4396
4397
4398
4399
4400
4401
4402
4403
4404
4405
4406
4407
4408
4409
4410
4411
4412
4413
4414
4415
4416
4417
4418
4419
4420
4421
4422
4423
4424
4425
4426
4427
4428
4429
4430
4431
4432
4433
4434
4435
4436
4437
4438
4439
4440
4441
4442
4443
4444
4445
4446
4447
4448
4449
4450
4451
4452
4453
4454
4455
4456
4457
4458
4459
4460
4461
4462
4463
4464
4465
4466
4467
4468
4469
4470
4471
4472
4473
4474
4475
4476
4477
4478
4479
4480
4481
4482
4483
4484
4485
4486
4487
4488
4489
4490
4491
4492
4493
4494
4495
4496
4497
4498
4499
4500
4501
4502
4503
4504
4505
4506
4507
4508
4509
4510
4511
4512
4513
4514
4515
4516
4517
4518
4519
4520
4521
4522
4523
4524
4525
4526
4527
4528
4529
4530
4531
4532
4533
4534
4535
4536
4537
4538
4539
4540
4541
4542
4543
4544
4545
4546
4547
4548
4549
4550
4551
4552
4553
4554
4555
4556
4557
4558
4559
4560
4561
4562
4563
4564
4565
4566
4567
4568
4569
4570
4571
4572
4573
4574
4575
4576
4577
4578
4579
4580
4581
4582
4583
4584
4585
4586
4587
4588
4589
4590
4591
4592
4593
4594
4595
4596
4597
4598
4599
4600
4601
4602
4603
4604
4605
4606
4607
4608
4609
4610
4611
4612
4613
4614
4615
4616
4617
4618
4619
4620
4621
4622
4623
4624
4625
4626
4627
4628
4629
4630
4631
4632
4633
4634
4635
4636
4637
4638
4639
4640
4641
4642
4643
4644
4645
4646
4647
4648
4649
4650
4651
4652
4653
4654
4655
4656
4657
4658
4659
4660
4661
4662
4663
4664
4665
4666
4667
4668
4669
4670
4671
4672
4673
4674
4675
4676
4677
4678
4679
4680
4681
4682
4683
4684
4685
4686
4687
4688
4689
4690
4691
4692
4693
4694
4695
4696
4697
4698
4699
4700
4701
4702
4703
4704
4705
4706
4707
4708
4709
4710
4711
4712
4713
4714
4715
4716
4717
4718
4719
4720
4721
4722
4723
4724
4725
4726
4727
4728
4729
4730
4731
4732
4733
4734
4735
4736
4737
4738
4739
4740
4741
4742
4743
4744
4745
4746
4747
4748
4749
4750
4751
4752
4753
4754
4755
4756
4757
4758
4759
4760
4761
4762
4763
4764
4765
4766
4767
4768
4769
4770
4771
4772
4773
4774
4775
4776
4777
4778
4779
4780
4781
4782
4783
4784
4785
4786
4787
4788
4789
4790
4791
4792
4793
4794
4795
4796
4797
4798
4799
4800
4801
4802
4803
4804
4805
4806
4807
4808
4809
4810
4811
4812
4813
4814
4815
4816
4817
4818
4819
4820
4821
4822
4823
4824
4825
4826
4827
4828
4829
4830
4831
4832
4833
4834
4835
4836
4837
4838
4839
4840
4841
4842
4843
4844
4845
4846
4847
4848
4849
4850
4851
4852
4853
4854
4855
4856
4857
4858
4859
4860
4861
4862
4863
4864
4865
4866
4867
4868
4869
4870
4871
4872
4873
4874
4875
4876
4877
4878
4879
4880
4881
4882
4883
4884
4885
4886
4887
4888
4889
4890
4891
4892
4893
4894
4895
4896
4897
4898
4899
4900
4901
4902
4903
4904
4905
4906
4907
4908
4909
4910
4911
4912
4913
4914
4915
4916
4917
4918
4919
4920
4921
4922
4923
4924
4925
4926
4927
4928
4929
4930
4931
4932
4933
4934
4935
4936
4937
4938
4939
4940
4941
4942
4943
4944
4945
4946
4947
4948
4949
4950
4951
4952
4953
4954
4955
4956
4957
4958
4959
4960
4961
4962
4963
4964
4965
4966
4967
4968
4969
4970
4971
4972
4973
4974
4975
4976
4977
4978
4979
4980
4981
4982
4983
4984
4985
4986
4987
4988
4989
4990
4991
4992
4993
4994
4995
4996
4997
4998
4999
5000
5001
5002
5003
5004
5005
5006
5007
5008
5009
5010
5011
5012
5013
5014
5015
5016
5017
5018
5019
5020
5021
5022
5023
5024
5025
5026
5027
5028
5029
5030
5031
5032
5033
5034
5035
5036
5037
;;; bytecomp.el --- compilation of Lisp code into byte code.

;;; Copyright (C) 1985-1987, 1991-1994 Free Software Foundation, Inc.
;;; Copyright (C) 1996 Ben Wing.

;; Authors: Jamie Zawinski <jwz@jwz.org>
;;	Hallvard Furuseth <hbf@ulrik.uio.no>
;;	Ben Wing <ben@xemacs.org>
;;	Martin Buchholz <martin@xemacs.org>
;;	Richard Stallman <rms@gnu.org>
;; Keywords: internal lisp

(defconst byte-compile-version "2.28 XEmacs; 2009-08-09.")

;; This file is part of XEmacs.

;; XEmacs is free software: you can redistribute it and/or modify it
;; under the terms of the GNU General Public License as published by the
;; Free Software Foundation, either version 3 of the License, or (at your
;; option) any later version.

;; XEmacs is distributed in the hope that it will be useful, but WITHOUT
;; ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
;; FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
;; for more details.

;; You should have received a copy of the GNU General Public License
;; along with XEmacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Synched up with: FSF 19.30.

;;; Commentary:

;; The Emacs Lisp byte compiler.  This crunches lisp source into a
;; sort of p-code (`bytecode') which takes up less space and can be
;; interpreted faster.  First, the source code forms are converted to
;; an intermediate form, `lapcode' [`LAP' == `Lisp Assembly Program']
;; which is much easier to manipulate than bytecode.  Then the lapcode
;; is converted to bytecode, which can be considered to be actual
;; machine language.  Optimizations can occur at either the source
;; level or the lapcode level.

;; The user entry points are byte-compile-file,
;; byte-recompile-directory and byte-compile-buffer.

;;; Code:

;;; ========================================================================
;;; Entry points:
;;;	byte-recompile-directory, byte-compile-file,
;;;     batch-byte-compile, batch-byte-recompile-directory,
;;;	byte-compile, compile-defun,
;;;	display-call-tree
;;;  RMS says:
;;; (byte-compile-buffer and byte-compile-and-load-file were turned off
;;;  because they are not terribly useful and get in the way of completion.)
;;; But I'm leaving them. --ben

;;; This version of the byte compiler has the following improvements:
;;;  + optimization of compiled code:
;;;    - removal of unreachable code;
;;;    - removal of calls to side-effectless functions whose return-value
;;;      is unused;
;;;    - compile-time evaluation of safe constant forms, such as (consp nil)
;;;      and (ash 1 6);
;;;    - open-coding of literal lambdas;
;;;    - peephole optimization of emitted code;
;;;    - trivial functions are left uncompiled for speed.
;;;  + support for inline functions;
;;;  + compile-time evaluation of arbitrary expressions;
;;;  + compile-time warning messages for:
;;;    - functions being redefined with incompatible arglists;
;;;    - functions being redefined as macros, or vice-versa;
;;;    - functions or macros defined multiple times in the same file;
;;;    - functions being called with the incorrect number of arguments;
;;;    - functions being called which are not defined globally, in the
;;;      file, or as autoloads;
;;;    - assignment and reference of undeclared free variables;
;;;    - various syntax errors;
;;;  + correct compilation of nested defuns, defmacros, defvars and defsubsts;
;;;  + correct compilation of top-level uses of macros;
;;;  + the ability to generate a histogram of functions called.

;;; User customization variables:
;;;
;;; byte-compile-verbose	Whether to report the function currently being
;;;				compiled in the minibuffer;
;;; byte-optimize		Whether to do optimizations; this may be
;;;				t, nil, 'source, or 'byte;
;;; byte-optimize-log		Whether to report (in excruciating detail)
;;;				exactly which optimizations have been made.
;;;				This may be t, nil, 'source, or 'byte;
;;; byte-compile-error-on-warn	Whether to stop compilation when a warning is
;;;				produced;
;;; byte-compile-delete-errors	Whether the optimizer may delete calls or
;;;				variable references that are side-effect-free
;;;				except that they may return an error.
;;; byte-compile-generate-call-tree	Whether to generate a histogram of
;;;				function calls.  This can be useful for
;;;				finding unused functions, as well as simple
;;;				performance metering.
;;; byte-compile-warnings	List of warnings to issue, or t.  May contain
;;;				'free-vars (references to variables not in the
;;;					    current lexical scope)
;;;				'unused-vars (non-global variables bound but
;;;					      not referenced)
;;;				'unresolved (calls to unknown functions)
;;;				'callargs  (lambda calls with args that don't
;;;					    match the lambda's definition)
;;;				'subr-callargs (calls to subrs with args that
;;;					    don't match the subr's definition)
;;;				'redefine  (function cell redefined from
;;;					    a macro to a lambda or vice versa,
;;;					    or redefined to take other args)
;;;				'obsolete  (obsolete variables and functions)
;;;				'pedantic  (references to Emacs-compatible
;;;					    symbols)
;;;                             'discarded-consing (use of mapcar instead of
;;;                                                 mapc, and similar)
;;;                             'quoted-lambda (quoting a lambda expression
;;;                                             as data, not as a function,
;;;                                             and using it in a function
;;;                                             context )
;;; emacs-lisp-file-regexp	Regexp for the extension of source-files;
;;;				see also the function `byte-compile-dest-file'.
;;; byte-compile-overwrite-file	If nil, delete old .elc files before saving.
;;;
;;; Most of the above parameters can also be set on a file-by-file basis; see
;;; the documentation of the `byte-compiler-options' macro.

;;; New Features:
;;;
;;;  o	The form `defsubst' is just like `defun', except that the function
;;;	generated will be open-coded in compiled code which uses it.  This
;;;	means that no function call will be generated, it will simply be
;;;	spliced in.  Lisp functions calls are very slow, so this can be a
;;;	big win.
;;;
;;;	You can generally accomplish the same thing with `defmacro', but in
;;;	that case, the defined procedure can't be used as an argument to
;;;	mapcar, etc.
;;;
;;;  o	You can make a given function be inline even if it has already been
;;;	defined with `defun' by using the `proclaim-inline' form like so:
;;;		(proclaim-inline my-function)
;;;	This is, in fact, exactly what `defsubst' does.  To make a function no
;;;	longer be inline, you must use `proclaim-notinline'.  Beware that if
;;;	you define a function with `defsubst' and later redefine it with
;;;	`defun', it will still be open-coded until you use `proclaim-notinline'.
;;;
;;;  o	You can also open-code one particular call to a function without
;;;	open-coding all calls.  Use the 'inline' form to do this, like so:
;;;
;;;		(inline (foo 1 2 3))	;; `foo' will be open-coded
;;;	or...
;;;		(inline			;;  `foo' and `baz' will be
;;;		 (foo 1 2 3 (bar 5))	;; open-coded, but `bar' will not.
;;;		 (baz 0))
;;;
;;;  o	It is possible to open-code a function in the same file it is defined
;;;	in without having to load that file before compiling it.  the
;;;	byte-compiler has been modified to remember function definitions in
;;;	the compilation environment in the same way that it remembers macro
;;;	definitions.
;;;
;;;  o  Forms like ((lambda ...) ...) are open-coded.
;;;
;;;  o  The form `eval-when-compile' is like `progn', except that the body
;;;     is evaluated at compile-time.  When it appears at top-level, this
;;;     is analogous to the Common Lisp idiom (eval-when (compile) ...).
;;;     When it does not appear at top-level, it is similar to the
;;;     Common Lisp #. reader macro (but not in interpreted code).
;;;
;;;  o  The form `eval-and-compile' is similar to `eval-when-compile',
;;;     but the whole form is evalled both at compile-time and at run-time.
;;;
;;;  o  The command M-x byte-compile-and-load-file does what you'd think.
;;;
;;;  o  The command `compile-defun' is analogous to `eval-defun'.
;;;
;;;  o  If you run `byte-compile-file' on a filename which is visited in a
;;;     buffer, and that buffer is modified, you are asked whether you want
;;;     to save the buffer before compiling.
;;;
;;;  o  You can add this to /etc/magic to make file(1) recognize the files
;;;     generated by this compiler:
;;;
;;;	  0	string		;ELC		XEmacs Lisp compiled file,
;;;	  >4	byte		x		version %d
;;;
;;; TO DO:
;;;
;;;  o	Should implement declarations and proclamations, notably special,
;;;	unspecial, and ignore.	Do this in such a way as to not break cl.el.
;;;  o	The bound-but-not-used warnings are not issued for variables whose
;;;	bindings were established in the arglist, due to the lack of an
;;;	ignore declaration.  Once ignore exists, this should be turned on.
;;;  o	Warn about functions and variables defined but not used?
;;;	Maybe add some kind of `export' declaration for this?
;;;	(With interactive functions being automatically exported?)
;;;  o	Any reference to a variable, even one which is a no-op, will cause
;;;	the warning not to be given.  Possibly we could use the for-effect
;;;	flag to determine when this reference is useless; possibly more
;;;	complex flow analysis would be necessary.
;;;  o  If the optimizer deletes a variable reference, we might be left with
;;;	a bound-but-not-referenced warning.  Generally this is ok, but not if
;;;	it's a synergistic result of macroexpansion.  Need some way to note
;;;	that a varref is being optimized away?  Of course it would be nice to
;;;	optimize away the binding too, someday, but it's unsafe today.
;;;  o	(See byte-optimize.el for the optimization TODO list.)

(require 'backquote)

(or (fboundp 'defsubst)
    ;; This really ought to be loaded already!
    (load-library "bytecomp-runtime"))

(defvar emacs-lisp-file-regexp "\\.el$"
  "*Regexp which matches Emacs Lisp source files.
You may want to redefine `byte-compile-dest-file' if you change this.")

;; This enables file name handlers such as jka-compr
;; to remove parts of the file name that should not be copied
;; through to the output file name.
(defun byte-compiler-base-file-name (filename)
  (let ((handler (find-file-name-handler filename
					 'byte-compiler-base-file-name)))
    (if handler
	(funcall handler 'byte-compiler-base-file-name filename)
      filename)))

(unless (fboundp 'byte-compile-dest-file)
  ;; The user may want to redefine this along with emacs-lisp-file-regexp,
  ;; so only define it if it is undefined.
  (defun byte-compile-dest-file (filename)
    "Convert an Emacs Lisp source file name to a compiled file name."
    (setq filename (byte-compiler-base-file-name filename))
    (setq filename (file-name-sans-versions filename))
    (if (string-match emacs-lisp-file-regexp filename)
	(concat (substring filename 0 (match-beginning 0)) ".elc")
      (concat filename ".elc"))))

;; This can be the 'byte-compile property of any symbol.
(autoload 'byte-compile-inline-expand "byte-optimize")

;; This is the entrypoint to the lapcode optimizer pass1.
(autoload 'byte-optimize-form "byte-optimize")
;; This is the entrypoint to the lapcode optimizer pass2.
(autoload 'byte-optimize-lapcode "byte-optimize")
(autoload 'byte-compile-unfold-lambda "byte-optimize")

;; This is the entry point to the decompiler, which is used by the
;; disassembler.  The disassembler just requires 'byte-compile, but
;; that doesn't define this function, so this seems to be a reasonable
;; thing to do.
(autoload 'byte-decompile-bytecode "byte-optimize")

(defvar byte-compile-verbose
  (and (not noninteractive) (> (device-baud-rate) search-slow-speed))
  "*Non-nil means print messages describing progress of byte-compiler.")

(defvar byte-compile-print-gensym t
  "*Non-nil means generate code that creates unique symbols at run-time.
This is achieved by printing uninterned symbols using the `#:SYMBOL'
notation, so that they will be read uninterned when run.

With this feature, code that uses uninterned symbols in macros will
not be runnable under pre-21.0 XEmacsen.")

(defvar byte-optimize t
  "*Enables optimization in the byte compiler.
nil means don't do any optimization.
t means do all optimizations.
`source' means do source-level optimizations only.
`byte' means do code-level optimizations only.")

(defvar byte-compile-delete-errors t
  "*If non-nil, the optimizer may delete forms that may signal an error.
This includes variable references and calls to functions such as `car'.")

;; XEmacs addition
(defvar byte-compile-new-bytecodes nil
  "This is completely ignored.  It is only around for backwards
compatibility.")

(defvar byte-compile-checks-on-load '((featurep 'xemacs))
  "A list of expressions to check when first loading a file. 
Emacs will throw an error if any of them fail; checks will be made in
reverse order.")

;; FSF enables byte-compile-dynamic-docstrings but not byte-compile-dynamic
;; by default.  This would be a reasonable conservative approach except
;; for the fact that if you enable either of these, you get incompatible
;; byte code that can't be read by XEmacs 19.13 or before or FSF 19.28 or
;; before.
;;
;; Therefore, neither is enabled for 19.14.  Both are enabled for 20.0
;; because we have no reason to be conservative about changing the
;; way things work. (Ben)

;; However, I don't think that defaulting byte-compile-dynamic to nil
;; is a compatibility issue - rather it is a performance issue.
;; Therefore I am setting byte-compile-dynamic back to nil. (mrb)

(defvar byte-compile-dynamic nil
  "*If non-nil, compile function bodies so they load lazily.
They are hidden comments in the compiled file, and brought into core when the
function is called.

To enable this option, make it a file-local variable
in the source file you want it to apply to.
For example, add  -*-byte-compile-dynamic: t;-*- on the first line.

When this option is true, if you load the compiled file and then move it,
the functions you loaded will not be able to run.")

(defvar byte-compile-dynamic-docstrings (emacs-version>= 20)
  "*If non-nil, compile doc strings for lazy access.
We bury the doc strings of functions and variables
inside comments in the file, and bring them into core only when they
are actually needed.

When this option is true, if you load the compiled file and then move it,
you won't be able to find the documentation of anything in that file.

To disable this option for a certain file, make it a file-local variable
in the source file.  For example, add this to the first line:
  -*-byte-compile-dynamic-docstrings:nil;-*-
You can also set the variable globally.

This option is enabled by default because it reduces Emacs memory usage.")

(defvar byte-optimize-log nil
  "*If true, the byte-compiler will log its optimizations into *Compile-Log*.
If this is 'source, then only source-level optimizations will be logged.
If it is 'byte, then only byte-level optimizations will be logged.")

(defvar byte-compile-error-on-warn nil
  "*If true, the byte-compiler reports warnings with `error'.")

;; byte-compile-warning-types in FSF.
(defvar byte-compile-default-warnings
  '(redefine callargs subr-callargs free-vars unresolved unused-vars obsolete
    discarded-consing quoted-lambda)
  "*The warnings used when byte-compile-warnings is t.")

(defvar byte-compile-warnings t
  "*List of warnings that the compiler should issue (t for the default set).
Elements of the list may be:

  free-vars	references to variables not in the current lexical scope.
  unused-vars	references to non-global variables bound but not referenced.
  unresolved	calls to unknown functions.
  callargs	lambda calls with args that don't match the definition.
  subr-callargs	calls to subrs with args that don't match the definition.
  redefine	function cell redefined from a macro to a lambda or vice
		versa, or redefined to take a different number of arguments.
  obsolete	use of an obsolete function or variable.
  pedantic	warn of use of compatible symbols.
  discarded-consing 
                calls to (some) functions that allocate memory, where that
                memory is immediately discarded; canonically, the use of 
                mapcar instead of mapc
  quoted-lambda passing a lambda expression not quoted as a function, as a
                function argument

The default set is specified by `byte-compile-default-warnings' and
normally encompasses all possible warnings.

See also the macro `byte-compiler-options'.")

(defvar byte-compile-generate-call-tree nil
  "*Non-nil means collect call-graph information when compiling.
This records functions that were called and from where.
If the value is t, compilation displays the call graph when it finishes.
If the value is neither t nor nil, compilation asks you whether to display
the graph.

The call tree only lists functions called, not macros used. Those functions
which the byte-code interpreter knows about directly (eq, cons, etc.) are
not reported.

The call tree also lists those functions which are not known to be called
\(that is, to which no calls have been compiled).  Functions which can be
invoked interactively are excluded from this list.")

(defconst byte-compile-call-tree nil "Alist of functions and their call tree.
Each element looks like

  \(FUNCTION CALLERS CALLS\)

where CALLERS is a list of functions that call FUNCTION, and CALLS
is a list of functions for which calls were generated while compiling
FUNCTION.")

(defvar byte-compile-call-tree-sort 'name
  "*If non-nil, sort the call tree.
The values `name', `callers', `calls', `calls+callers'
specify different fields to sort on.")

(defvar byte-compile-overwrite-file t
  "If nil, old .elc files are deleted before the new is saved, and .elc
files will have the same modes as the corresponding .el file.  Otherwise,
existing .elc files will simply be overwritten, and the existing modes
will not be changed.  If this variable is nil, then an .elc file which
is a symbolic link will be turned into a normal file, instead of the file
which the link points to being overwritten.")

(defvar byte-recompile-directory-ignore-errors-p nil
  "If true, then `byte-recompile-directory' will continue compiling even
when an error occurs in a file.  This is bound to t by
`batch-byte-recompile-directory'.")

(defvar byte-recompile-ignore-uncompilable-mule-files t
  "If non-nil, `byte-recompile-*' ignores non-ASCII .el files in a non-Mule
XEmacs.  This assumes that such files have a -*- coding: ??? -*- magic
cookie in their first line or a ;;;###coding system: magic cookie
early in the file.")

(defvar byte-recompile-directory-recursively t
  "*If true, then `byte-recompile-directory' will recurse on subdirectories.")

(defvar byte-compile-constants nil
  "list of all constants encountered during compilation of this form")
(defvar byte-compile-variables nil
  "list of all variables encountered during compilation of this form")
(defvar byte-compile-bound-variables nil
  "Alist of variables bound in the context of the current form,
that is, the current lexical environment.  This list lives partly
on the specbind stack.  The cdr of each cell is an integer bitmask.")
(defvar byte-compile-output-preface nil
  "Form to output before current by `byte-compile-output-file-form'
This is used for implementing `load-time-value'.")

(defvar byte-compile-force-escape-quoted nil
  "If t, `byte-compile-maybe-reset-coding' always chooses `escape-quoted'

This is for situations where the byte compiler output file needs to be
able to encode character values above ?\\xFF, but this cannot be
easily determined from the input file.")

(defconst byte-compile-referenced-bit 1)
(defconst byte-compile-assigned-bit 2)
(defconst byte-compile-arglist-bit 4)
(defconst byte-compile-global-bit 8)

(defvar byte-compile-free-references)
(defvar byte-compile-free-assignments)

(defvar byte-compiler-error-flag)

;;; A form of eval that includes the currently defined macro definitions.
;;; This helps implement the promise made in the Lispref:
;;;
;;; "If a file being compiled contains a `defmacro' form, the macro is
;;; defined temporarily for the rest of the compilation of that file."
(defun byte-compile-eval (form)
  (let ((save-macro-environment nil)
	;; These are macros in byte-compile-initial-macro-environment that
	;; shouldn't be shadowed when calling #'byte-compile-eval, since
	;; such code is interpreted, not compiled.
	;; #### Consider giving this a docstring and a top-level value.
	(byte-compile-no-shadow '(load-time-value labels flet)))
    (unwind-protect
	(loop
	  for (sym . def) in byte-compile-macro-environment
	  do (when (and (symbolp sym) (not (memq sym byte-compile-no-shadow)))
	       (push
		(if (fboundp sym)
		    (cons sym (symbol-function sym))
		  sym)
		save-macro-environment)
	       (fset sym (cons 'macro def)))
	  finally return (eval form))
      (dolist (elt save-macro-environment)
	(if (symbolp elt)
	    (fmakunbound elt)
	  (fset (car elt) (cdr elt)))))))

(defvar for-effect) ; ## Kludge!  This should be an arg, not a special.

(defconst byte-compile-initial-macro-environment
  `((byte-compiler-options
      . ,#'(lambda (&rest forms)
	     (apply 'byte-compiler-options-handler forms)))
    (eval-when-compile
      . ,#'(lambda (&rest body)
	     (list 'quote (byte-compile-eval (cons 'progn body)))))
    (eval-and-compile
      . ,#'(lambda (&rest body)
	     (byte-compile-eval (cons 'progn body))
	     (cons 'progn body)))
    (the .
      ,#'(lambda (type form)
	   (if (cl-const-expr-p form)
	       (or (eval (cl-make-type-test form type))
		   (byte-compile-warn
		    "%s is not of type %s" form type)))
	   (if byte-compile-delete-errors
	       form
	     (funcall (cdr (symbol-function 'the)) type form))))
    (declare
     . ,#'(lambda (&rest specs)
	    (while specs
	      (if (listp cl-declare-stack) (push (car specs) cl-declare-stack))
	      (cl-do-proclaim (pop specs) nil))))
    (load-time-value
     . ,(symbol-macrolet ((wrapper '#:load-time-value))
          (put wrapper 'byte-compile
               #'(lambda (form)
                   (let* ((gensym (gensym))
                          (byte-compile-bound-variables
                           (acons gensym byte-compile-global-bit
                                  byte-compile-bound-variables)))
                     (setq byte-compile-output-preface
                           (byte-compile-top-level
                            `(progn
                              (setq ,gensym (progn ,(second form)))
                              ,byte-compile-output-preface)
                            t 'file))
                     (byte-compile-form `(symbol-value ',gensym) nil))))
          #'(lambda (form &optional read-only)
              (list wrapper form))))
    (labels
        . ,#'(lambda (bindings &rest body)
               (let* ((names (mapcar 'car bindings))
                      (lambdas (mapcar
                                (function*
                                 (lambda ((name . definition))
                                   (cons 'lambda (cdr (cl-transform-lambda
                                                       definition name)))))
                                bindings))
                      (placeholders
                       (mapcar #'(lambda (lambda)
                                   (make-byte-code (second lambda) "\xc0\x87"
                                                   ;; This list is used for
                                                   ;; the byte-optimize
                                                   ;; property, if the
                                                   ;; function is to be
                                                   ;; inlined. See
                                                   ;; cl-do-proclaim.
                                                   (vector nil) 1))
                               lambdas))
                      (byte-compile-macro-environment
                       (pairlis names (mapcar
                                       #'(lambda (placeholder)
                                           `(lambda (&rest cl-labels-args)
                                              ;; Be careful not to quote
                                              ;; PLACEHOLDER, otherwise
                                              ;; byte-optimize-funcall inlines
                                              ;; it.
                                              (list* 'funcall ,placeholder
                                                     cl-labels-args)))
                                       placeholders)
                                byte-compile-macro-environment))
                      (gensym (gensym)))
                 (labels
                     ((byte-compile-transform-labels (form names lambdas
                                                      placeholders)
                        (let* ((inline
                                 (mapcan
                                  #'(lambda (name placeholder lambda)
                                      (and
                                       (eq
                                        (getf (aref
                                               (compiled-function-constants
                                                placeholder) 0)
                                              'byte-optimizer)
                                        'byte-compile-inline-expand)
                                       `(((function ,placeholder)
                                          ,(byte-compile-lambda lambda name)
                                          (function ,lambda)))))
                                  names placeholders lambdas))
                               (compiled
                                (mapcar* #'byte-compile-lambda 
                                         (if (not inline)
                                             lambdas
                                           ;; See further down for the
                                          ;; rationale of the sublis calls.
                                           (sublis (pairlis
                                                    (mapcar #'cadar inline)
                                                    (mapcar #'third inline))
                                                   (sublis
                                                    (pairlis
                                                     (mapcar #'car inline)
                                                     (mapcar #'second inline))
                                                    lambdas :test #'equal)
                                                   :test #'eq))
                                         names))
                               elt)
                          (mapc #'(lambda (placeholder function)
                                    (nsubst function placeholder compiled
                                            :test #'eq
                                            :descend-structures t))
                                placeholders compiled)
                          (when inline
                            (dolist (triad inline)
                              (nsubst (setq elt (elt compiled
                                                     (position (cadar triad)
                                                               placeholders)))
                                      (second triad) compiled :test #'eq
                                      :descend-structures t)
                              (setf (second triad) elt))
                            ;; For inlined labels: first, replace uses of
                            ;; the placeholder in places where it's not an
                            ;; evident, explicit funcall (that is, where
                            ;; it is not to be inlined) with the compiled
                            ;; function:
                            (setq form (sublis
                                        (pairlis (mapcar #'car inline)
                                                 (mapcar #'second inline))
                                        form :test #'equal)
                                  ;; Now replace uses of the placeholder
                                  ;; where it is an evident funcall with the
                                  ;; lambda, quoted as a function, to allow
                                  ;; byte-optimize-funcall to do its
                                  ;; thing. Note that the lambdas still have
                                  ;; the placeholders, so there's no risk
                                  ;; of recursive inlining.
                                  form (sublis (pairlis
                                                (mapcar #'cadar inline)
                                                (mapcar #'third inline))
                                               form :test #'eq)))
                          (sublis (pairlis placeholders compiled) form
                                  :test #'eq))))
                   (put gensym 'byte-compile
                        #'(lambda (form)
                            (let* ((names (cadr (cl-pop2 form)))
                                   (lambdas (mapcar #'cadr (cdr (pop form))))
                                   (placeholders (cadr (pop form))))
                              (byte-compile-body-do-effect
                               (byte-compile-transform-labels form names
                                                              lambdas
                                                              placeholders)))))
                   (put gensym 'byte-hunk-handler
                        #'(lambda (form)
                            (let* ((names (cadr (cl-pop2 form)))
                                   (lambdas (mapcar #'cadr (cdr (pop form))))
                                   (placeholders (cadr (pop form))))
                              (byte-compile-file-form
                               (cons 'progn
                                     (byte-compile-transform-labels
                                      form names lambdas placeholders))))))
		   (setq body
			 (cl-macroexpand-all `(,gensym ',names (list ,@lambdas)
					       ',placeholders ,@body)
					     byte-compile-macro-environment))
		   (if (position 'lambda (mapcar #'(lambda (object)
						     (car-safe (cdr-safe
								object)))
						 (cdr (third body)))
				 :key #'car-safe :test-not #'eq)
		       ;; #'lexical-let has worked its magic, not all the
		       ;; lambdas are lambdas. Give up on pre-compiling the
		       ;; labels.
		       (setq names (mapcar #'copy-symbol names)
			     lambdas (cdr (third body))
			     body (sublis (pairlis placeholders names)
					  (nthcdr 4 body) :test #'eq)
			     lambdas (sublis (pairlis placeholders names)
					     lambdas :test #'eq)
			     body (cl-macroexpand-all
				   `(lexical-let
				     ,names
				     (setf ,@(mapcan #'list names lambdas))
				     ,@body)
				   byte-compile-macro-environment))
		     body)))))
    (flet .
      ,#'(lambda (bindings &rest body)
           (let* ((names (mapcar 'car bindings))
                  (lambdas (mapcar
                            (function*
                             (lambda ((function . definition))
                               (cons 'lambda (cdr (cl-transform-lambda
                                                   definition function)))))
                            bindings))
                  (gensym (gensym)))
             (put gensym 'byte-compile-flet-environment
                  (pairlis names lambdas))
             (put gensym 'byte-compile
                  #'(lambda (form)
                      (let* ((byte-compile-flet-environment
                              (get (car form) 'byte-compile-flet-environment))
                             (byte-compile-function-environment
                              (append byte-compile-flet-environment
                                      byte-compile-function-environment))
                             name)
                        (dolist (acons byte-compile-flet-environment)
                          (setq name (car acons))
                          (if (and (memq 'redefine byte-compile-warnings)
                                   (or (cdr
                                        (assq name
                                              byte-compile-macro-environment))
                                       (eq 'macro
                                           (ignore-errors
                                             (car (symbol-function name))))))
                              ;; XEmacs change; this is a warning, not an
                              ;; error. The only use case for #'flet instead
                              ;; of #'labels is to shadow a dynamically
                              ;; bound function at runtime, and it's
                              ;; reasonable to do this even if that symbol
                              ;; has a macro binding at compile time.
                              (byte-compile-warn
                               "flet: redefining macro %s as a function"
                               name))
                          (if (get name 'byte-opcode)
                              (byte-compile-warn
                               "flet: %s has a byte code, consider #'labels"
                               name))
                          (if (get name 'byte-compile) 
                              (byte-compile-warn
                               "flet: %s has a byte-compile method, 
consider #'labels" name)))
                        (byte-compile-form (second form)))))
             `(,gensym (letf* ,(mapcar* #'(lambda (name lambda)
                                            `((symbol-function ',name)
                                              ,lambda)) names lambdas)
                         ,@body))))))

  "The default macro-environment passed to macroexpand by the compiler.
Placing a macro here will cause a macro to have different semantics when
expanded by the compiler as when expanded by the interpreter.")

(defvar byte-compile-function-environment nil
  "Alist of functions defined in the file being compiled.
This is so we can inline them when necessary.
Each element looks like (FUNCTIONNAME . DEFINITION).  It is
\(FUNCTIONNAME . nil) when a function is redefined as a macro.")

(defvar byte-compile-autoload-environment nil
 "Alist of functions and macros defined by autoload in the file being compiled.
This is so we can suppress warnings about calls to these functions, even though
they do not have `real' definitions.
Each element looks like (FUNCTIONNAME . CALL-TO-AUTOLOAD).")

(defvar byte-compile-unresolved-functions nil
  "Alist of undefined functions to which calls have been compiled (used for
warnings when the function is later defined with incorrect args).")

(defvar byte-compile-file-domain) ; domain of file being compiled

(defvar byte-compile-tag-number 0)
(defvar byte-compile-output nil
  "Alist describing contents to put in byte code string.
Each element is (INDEX . VALUE)")
(defvar byte-compile-depth 0 "Current depth of execution stack.")
(defvar byte-compile-maxdepth 0 "Maximum depth of execution stack.")


;;; The byte codes; this information is duplicated in bytecode.c

(defconst byte-code-vector nil
  "An array containing byte-code names indexed by byte-code values.")

(defconst byte-stack+-info nil
  "An array with the stack adjustment for each byte-code.")

(defmacro byte-defop (opcode stack-adjust opname &optional docstring)
  ;; This is a speed-hack for building the byte-code-vector at compile-time.
  ;; We fill in the vector at macroexpand-time, and then after the last call
  ;; to byte-defop, we write the vector out as a constant instead of writing
  ;; out a bunch of calls to aset.
  ;; Actually, we don't fill in the vector itself, because that could make
  ;; it problematic to compile big changes to this compiler; we store the
  ;; values on its plist, and remove them later in -extrude.
  (let ((v1 (or (get 'byte-code-vector 'tmp-compile-time-value)
		(put 'byte-code-vector 'tmp-compile-time-value
		     (make-vector 256 nil))))
	(v2 (or (get 'byte-stack+-info 'tmp-compile-time-value)
		(put 'byte-stack+-info 'tmp-compile-time-value
		     (make-vector 256 nil)))))
    (aset v1 opcode opname)
    (aset v2 opcode stack-adjust))
  (if docstring
      (list 'defconst opname opcode (concat "Byte code opcode " docstring "."))
      (list 'defconst opname opcode)))

(defmacro byte-extrude-byte-code-vectors ()
  (prog1 (list 'setq 'byte-code-vector
		     (get 'byte-code-vector 'tmp-compile-time-value)
		     'byte-stack+-info
		     (get 'byte-stack+-info 'tmp-compile-time-value))
    (remprop 'byte-code-vector 'tmp-compile-time-value)
    (remprop 'byte-stack+-info 'tmp-compile-time-value)))


;; unused: 0-7

;; These opcodes are special in that they pack their argument into the
;; opcode word.
;;
(byte-defop   8  1 byte-varref	"for variable reference")
(byte-defop  16 -1 byte-varset	"for setting a variable")
(byte-defop  24 -1 byte-varbind	"for binding a variable")
(byte-defop  32  0 byte-call	"for calling a function")
(byte-defop  40  0 byte-unbind	"for unbinding special bindings")
;; codes 8-47 are consumed by the preceding opcodes

;; unused: 48-55

(byte-defop  56 -1 byte-nth)
(byte-defop  57  0 byte-symbolp)
(byte-defop  58  0 byte-consp)
(byte-defop  59  0 byte-stringp)
(byte-defop  60  0 byte-listp)
(byte-defop  61 -1 byte-old-eq)
(byte-defop  62 -1 byte-old-memq)
(byte-defop  63  0 byte-not)
(byte-defop  64  0 byte-car)
(byte-defop  65  0 byte-cdr)
(byte-defop  66 -1 byte-cons)
(byte-defop  67  0 byte-list1)
(byte-defop  68 -1 byte-list2)
(byte-defop  69 -2 byte-list3)
(byte-defop  70 -3 byte-list4)
(byte-defop  71  0 byte-length)
(byte-defop  72 -1 byte-aref)
(byte-defop  73 -2 byte-aset)
(byte-defop  74  0 byte-symbol-value)
(byte-defop  75  0 byte-symbol-function) ; this was commented out
(byte-defop  76 -1 byte-set)
(byte-defop  77 -1 byte-fset) ; this was commented out
(byte-defop  78 -1 byte-get)
(byte-defop  79 -2 byte-subseq)
(byte-defop  80 -1 byte-concat2)
(byte-defop  81 -2 byte-concat3)
(byte-defop  82 -3 byte-concat4)
(byte-defop  83  0 byte-sub1)
(byte-defop  84  0 byte-add1)
(byte-defop  85 -1 byte-eqlsign)
(byte-defop  86 -1 byte-gtr)
(byte-defop  87 -1 byte-lss)
(byte-defop  88 -1 byte-leq)
(byte-defop  89 -1 byte-geq)
(byte-defop  90 -1 byte-diff)
(byte-defop  91  0 byte-negate)
(byte-defop  92 -1 byte-plus)
(byte-defop  93 -1 byte-max)
(byte-defop  94 -1 byte-min)
(byte-defop  95 -1 byte-mult)
(byte-defop  96  1 byte-point)
(byte-defop  97 -1 byte-eq) ; new as of v20
(byte-defop  98  0 byte-goto-char)
(byte-defop  99  0 byte-insert)
(byte-defop 100  1 byte-point-max)
(byte-defop 101  1 byte-point-min)
(byte-defop 102  0 byte-char-after)
(byte-defop 103  1 byte-following-char)
(byte-defop 104  1 byte-preceding-char)
(byte-defop 105  1 byte-current-column)
(byte-defop 106  0 byte-indent-to)
(byte-defop 107 -1 byte-equal) ; new as of v20
(byte-defop 108  1 byte-eolp)
(byte-defop 109  1 byte-eobp)
(byte-defop 110  1 byte-bolp)
(byte-defop 111  1 byte-bobp)
(byte-defop 112  1 byte-current-buffer)
(byte-defop 113  0 byte-set-buffer)
(byte-defop 114  0 byte-save-current-buffer
  "To make a binding to record the current buffer.")
;;(byte-defop 114  1 byte-read-char-OBSOLETE) ;obsolete as of v19
(byte-defop 115 -1 byte-memq) ; new as of v20
(byte-defop 116  1 byte-interactive-p)

(byte-defop 117  0 byte-forward-char)
(byte-defop 118  0 byte-forward-word)
(byte-defop 119 -1 byte-skip-chars-forward)
(byte-defop 120 -1 byte-skip-chars-backward)
(byte-defop 121  0 byte-forward-line)
(byte-defop 122  0 byte-char-syntax)
(byte-defop 123 -1 byte-buffer-substring)
(byte-defop 124 -1 byte-delete-region)
(byte-defop 125 -1 byte-narrow-to-region)
(byte-defop 126  1 byte-widen)
(byte-defop 127  0 byte-end-of-line)

;; unused: 128

;; These store their argument in the next two bytes
(byte-defop 129  1 byte-constant2
   "for reference to a constant with vector index >= byte-constant-limit")
(byte-defop 130  0 byte-goto "for unconditional jump")
(byte-defop 131 -1 byte-goto-if-nil "to pop value and jump if it's nil")
(byte-defop 132 -1 byte-goto-if-not-nil
	    "to pop value and jump if it's not nil")
(byte-defop 133 -1 byte-goto-if-nil-else-pop
  "to examine top-of-stack, jump and don't pop it if it's nil,
otherwise pop it")
(byte-defop 134 -1 byte-goto-if-not-nil-else-pop
  "to examine top-of-stack, jump and don't pop it if it's non-nil,
otherwise pop it")

(byte-defop 135 -1 byte-return "to pop a value and return it from `byte-code'")
(byte-defop 136 -1 byte-discard "to discard one value from stack")
(byte-defop 137  1 byte-dup     "to duplicate the top of the stack")

(byte-defop 138  0 byte-save-excursion
  "to make a binding to record the buffer, point and mark")
(byte-defop 139  0 byte-save-window-excursion ; almost obsolete
  "to make a binding to record entire window configuration")
(byte-defop 140  0 byte-save-restriction
  "to make a binding to record the current buffer clipping restrictions")
(byte-defop 141 -1 byte-catch
  "for catch.  Takes, on stack, the tag and an expression for the body")
(byte-defop 142 -1 byte-unwind-protect
  "for unwind-protect.  Takes, on stack, an expression for the unwind-action")

;; For condition-case.  Takes, on stack, the variable to bind,
;; an expression for the body, and a list of clauses.
(byte-defop 143 -2 byte-condition-case)

;; For entry to with-output-to-temp-buffer.
;; Takes, on stack, the buffer name.
;; Binds standard-output and does some other things.
;; Returns with temp buffer on the stack in place of buffer name.
(byte-defop 144  0 byte-temp-output-buffer-setup)

;; For exit from with-output-to-temp-buffer.
;; Expects the temp buffer on the stack underneath value to return.
;; Pops them both, then pushes the value back on.
;; Unbinds standard-output and makes the temp buffer visible.
(byte-defop 145 -1 byte-temp-output-buffer-show)

;; To unbind back to the beginning of this frame.
;; Not used yet, but will be needed for tail-recursion elimination.
(byte-defop 146  0 byte-unbind-all)

(byte-defop 147 -2 byte-set-marker)
(byte-defop 148  0 byte-match-beginning)
(byte-defop 149  0 byte-match-end)
(byte-defop 150  0 byte-upcase)
(byte-defop 151  0 byte-downcase)
(byte-defop 152 -1 byte-string=)
(byte-defop 153 -1 byte-string<)
(byte-defop 154 -1 byte-old-equal)
(byte-defop 155 -1 byte-nthcdr)
(byte-defop 156 -1 byte-elt)
(byte-defop 157 -1 byte-old-member)
(byte-defop 158 -1 byte-old-assq)
(byte-defop 159  0 byte-nreverse)
(byte-defop 160 -1 byte-setcar)
(byte-defop 161 -1 byte-setcdr)
(byte-defop 162  0 byte-car-safe)
(byte-defop 163  0 byte-cdr-safe)
(byte-defop 164 -1 byte-nconc)
(byte-defop 165 -1 byte-quo)
(byte-defop 166 -1 byte-rem)
(byte-defop 167  0 byte-numberp)
(byte-defop 168  0 byte-fixnump)

;; unused: 169

;; These are not present in FSF.
;;
(byte-defop 170  0 byte-rel-goto)
(byte-defop 171 -1 byte-rel-goto-if-nil)
(byte-defop 172 -1 byte-rel-goto-if-not-nil)
(byte-defop 173 -1 byte-rel-goto-if-nil-else-pop)
(byte-defop 174 -1 byte-rel-goto-if-not-nil-else-pop)

(byte-defop 175 nil byte-listN)
(byte-defop 176 nil byte-concatN)
(byte-defop 177 nil byte-insertN)

(byte-defop 178  1 byte-bind-multiple-value-limits)
(byte-defop 179 -3 byte-multiple-value-list-internal)
(byte-defop 180  0 byte-multiple-value-call)
(byte-defop 181 -1 byte-throw)

;; these ops are new to v20
(byte-defop 182 -1 byte-member)
(byte-defop 183 -1 byte-assq)

;; unused: 184-191

(byte-defop 192  1 byte-constant	"for reference to a constant")
;; codes 193-255 are consumed by byte-constant.
(defconst byte-constant-limit 64
  "Exclusive maximum index usable in the `byte-constant' opcode.")

(defconst byte-goto-ops
  '(byte-goto byte-goto-if-nil byte-goto-if-not-nil
	      byte-goto-if-nil-else-pop
	      byte-goto-if-not-nil-else-pop)
  "List of byte-codes whose offset is a pc.")

(defconst byte-goto-always-pop-ops
  '(byte-goto-if-nil byte-goto-if-not-nil))

(defconst byte-rel-goto-ops
  '(byte-rel-goto byte-rel-goto-if-nil byte-rel-goto-if-not-nil
		  byte-rel-goto-if-nil-else-pop byte-rel-goto-if-not-nil-else-pop)
  "byte-codes for relative jumps.")

(byte-extrude-byte-code-vectors)

;;; lapcode generator
;;;
;;; the byte-compiler now does source -> lapcode -> bytecode instead of
;;; source -> bytecode, because it's a lot easier to make optimizations
;;; on lapcode than on bytecode.
;;;
;;; Elements of the lapcode list are of the form (<instruction> . <parameter>)
;;; where instruction is a symbol naming a byte-code instruction,
;;; and parameter is an argument to that instruction, if any.
;;;
;;; The instruction can be the pseudo-op TAG, which means that this position
;;; in the instruction stream is a target of a goto.  (car PARAMETER) will be
;;; the PC for this location, and the whole instruction "(TAG pc)" will be the
;;; parameter for some goto op.
;;;
;;; If the operation is varbind, varref, varset or push-constant, then the
;;; parameter is (variable/constant . index_in_constant_vector).
;;;
;;; First, the source code is macroexpanded and optimized in various ways.
;;; Then the resultant code is compiled into lapcode.  Another set of
;;; optimizations are then run over the lapcode.  Then the variables and
;;; constants referenced by the lapcode are collected and placed in the
;;; constants-vector.  (This happens now so that variables referenced by dead
;;; code don't consume space.)  And finally, the lapcode is transformed into
;;; compacted byte-code.
;;;
;;; A distinction is made between variables and constants because the variable-
;;; referencing instructions are more sensitive to the variables being near the
;;; front of the constants-vector than the constant-referencing instructions.
;;; Also, this lets us notice references to free variables.

(defun byte-compile-lapcode (lap)
  "Turns lapcode into bytecode.  The lapcode is destroyed."
  ;; Lapcode modifications: changes the ID of a tag to be the tag's PC.
  (let ((pc 0)			; Program counter
	op off			; Operation & offset
	(bytes '())		; Put the output bytes here
	(patchlist nil)		; List of tags and goto's to patch
	rest rel tmp)
    (while lap
      (setq op (car (car lap))
	    off (cdr (car lap)))
      (cond ((not (symbolp op))
	     (error "Non-symbolic opcode `%s'" op))
	    ((eq op 'TAG)
	     (setcar off pc)
	     (push off patchlist))
	    ((memq op byte-goto-ops)
	     (setq pc (+ pc 3))
	     (setq bytes (cons (cons pc (cdr off))
			       (cons nil
				     (cons (symbol-value op) bytes))))
	     (push bytes patchlist))
	    (t
	     (setq bytes
		   (cond ((cond ((consp off)
				 ;; Variable or constant reference
				 (setq off (cdr off))
				 (eq op 'byte-constant)))
			  (cond ((< off byte-constant-limit)
				 (setq pc (1+ pc))
				 (cons (+ byte-constant off) bytes))
				(t
				 (setq pc (+ 3 pc))
				 (cons (lsh off -8)
				       (cons (logand off 255)
					     (cons byte-constant2 bytes))))))
			 ((and (<= byte-listN (symbol-value op))
			       (<= (symbol-value op) byte-insertN))
			  (setq pc (+ 2 pc))
			  (cons off (cons (symbol-value op) bytes)))
			 ((= byte-multiple-value-call (symbol-value op))
			  (setq pc (1+ pc))
			  ;; Ignore off. 
			  (cons (symbol-value op) bytes))
			 ((< off 6)
			  (setq pc (1+ pc))
			  (cons (+ (symbol-value op) off) bytes))
			 ((< off 256)
			  (setq pc (+ 2 pc))
			  (cons off (cons (+ (symbol-value op) 6) bytes)))
			 (t
			  (setq pc (+ 3 pc))
			  (cons (lsh off -8)
				(cons (logand off 255)
				      (cons (+ (symbol-value op) 7)
					    bytes))))))))
      (setq lap (cdr lap)))
    ;;(if (not (= pc (length bytes)))
    ;;    (error "Compiler error: pc mismatch - %s %s" pc (length bytes)))
    (cond (t ;; starting with Emacs 19.
	   ;; Make relative jumps
	   (setq patchlist (nreverse patchlist))
	   (while (progn
		    (setq off 0)	; PC change because of deleted bytes
		    (setq rest patchlist)
		    (while rest
		      (setq tmp (car rest))
		      (and (consp (car tmp)) ; Jump
			   (prog1 (null (nth 1 tmp)) ; Absolute jump
			     (setq tmp (car tmp)))
			   (progn
			     (setq rel (- (car (cdr tmp)) (car tmp)))
			     (and (<= -129 rel) (< rel 128)))
			   (progn
			     ;; Convert to relative jump.
			     (setcdr (car rest) (cdr (cdr (car rest))))
			     (setcar (cdr (car rest))
				     (+ (car (cdr (car rest)))
					(- byte-rel-goto byte-goto)))
			     (setq off (1- off))))
		      (setcar tmp (+ (car tmp) off)) ; Adjust PC
		      (setq rest (cdr rest)))
		    ;; If optimizing, repeat until no change.
		    (and byte-optimize
			 (not (zerop off)))))))
    ;; Patch PC into jumps
    (let (bytes)
      (while patchlist
	(setq bytes (car patchlist))
	(cond ((atom (car bytes)))	; Tag
	      ((nth 1 bytes)		; Relative jump
	       (setcar bytes (+ (- (car (cdr (car bytes))) (car (car bytes)))
				128)))
	      (t			; Absolute jump
	       (setq pc (car (cdr (car bytes))))	; Pick PC from tag
	       (setcar (cdr bytes) (logand pc 255))
	       (setcar bytes (lsh pc -8))))
	(setq patchlist (cdr patchlist))))
    (concat (nreverse bytes))))


;;; byte compiler messages

(defvar byte-compile-current-form nil)
(defvar byte-compile-current-file nil)
(defvar byte-compile-dest-file nil)

(defmacro byte-compile-log (format-string &rest args)
  `(when (and byte-optimize (memq byte-optimize-log '(t source)))
      (let ((print-escape-newlines t)
	    (print-level 4)
	    (print-length 4))
	(byte-compile-log-1 (format ,format-string ,@args)))))

(defconst byte-compile-last-warned-form 'nothing)

;; Log a message STRING in *Compile-Log*.
;; Also log the current function and file if not already done.
(defun byte-compile-log-1 (string &optional fill)
  (let* ((this-form (or byte-compile-current-form "toplevel forms"))
	 (while-compiling-msg
	  (when (or byte-compile-current-file
		    (not (eq this-form byte-compile-last-warned-form)))
	    (format
	     "While compiling %s%s:"
	     this-form
	     (cond
	      ((stringp byte-compile-current-file)
	       (concat " in file " byte-compile-current-file))
	      ((bufferp byte-compile-current-file)
	       (concat " in buffer "
		       (buffer-name byte-compile-current-file)))
	      (""))))))
    (if noninteractive
	(progn
	  (when while-compiling-msg (message "%s" while-compiling-msg))
	  (message "  %s" string))
      (with-current-buffer (get-buffer-create "*Compile-Log*")
	(goto-char (point-max))
	(when byte-compile-current-file
	  (when (> (point-max) (point-min))
	    (insert "\n\^L\n"))
	  (insert (current-time-string) "\n"))
	(when while-compiling-msg (insert while-compiling-msg "\n"))
	(insert "  " string "\n")
	(when (and fill (not (string-match "\n" string)))
	  (let ((fill-prefix "     ")
		(fill-column 78))
	    (fill-paragraph nil)))))
    (setq byte-compile-current-file nil)
    (setq byte-compile-last-warned-form this-form)))

;; Log the start of a file in *Compile-Log*, and mark it as done.
;; But do nothing in batch mode.
(defun byte-compile-log-file ()
  (when (and byte-compile-current-file (not noninteractive))
    (with-current-buffer (get-buffer-create "*Compile-Log*")
      (when (> (point-max) (point-min))
	(goto-char (point-max))
	(insert "\n\^L\n"))
      (insert "Compiling "
	      (if (stringp byte-compile-current-file)
		  (concat "file " byte-compile-current-file)
		(concat "buffer " (buffer-name byte-compile-current-file)))
	      " at " (current-time-string) "\n")
      (setq byte-compile-current-file nil))))

(defvar byte-compile-inbuffer)
(defvar byte-compile-outbuffer)

(defun byte-compile-warn (format &rest args)
  (setq format (apply 'format format args))
  (if byte-compile-error-on-warn
      (error "%s" format)		; byte-compile-file catches and logs it
    (byte-compile-log-1 (concat "** " format) t)

    ;; This was a first attempt to add line numbers to the
    ;; byte-compilation output.  Unfortunately, it doesn't work
    ;; perfectly: it reports the line number at the end of the form
    ;; (which may be an entire function), rather than the line number
    ;; of the actual problem.  Doing this right is hard because we
    ;; currently use the built-in Lisp parser to parse the entire form
    ;; at once.  What we basically need is a whole separate parser
    ;; that annotates its output with line numbers.  For example, we
    ;; might modify the parser in lread.c so that, with the right
    ;; option set, it replaces every Lisp object contained in the
    ;; structure it returns with a cons of that object and the line
    ;; number it was found on (determined by counting newlines,
    ;; starting from some arbitrary point).  You then have two
    ;; options: (a) Modify the byte compiler so that everything that
    ;; compiles a form deals with the new annotated form rather than
    ;; the old one, or (b) The byte compiler saves this structure
    ;; while converting it into a normal structure that's given to the
    ;; various form handlers, which need no (or less) modification.
    ;; In the former case, finding the line number is trivial because
    ;; it's in the form.  In the latter case, finding the line number
    ;; depends on having a unique Lisp object that can be looked up in
    ;; the annotated structure -- i.e. a list, vector, or string.
    ;; You'd have to look at the various places where errors are spit
    ;; out (not very many, really), and make sure that such a unique
    ;; object is available.  Then you do a depth-first search through
    ;; the annotated structure to find the object.
    ;;
    ;; An alternative way of doing (b) that's probably much more
    ;; efficient (and easier to implement) is simply to have the
    ;; parser in lread.c annotate every unique object using a separate
    ;; hash table.  This also eliminates the need for a search to find
    ;; the line number.  In order to be fine-grained enough to get at
    ;; every symbol in a form -- e.g. if we want to pinpoint a
    ;; particular undefined variable in a function call -- we need to
    ;; annotate every cons, not just each list.  We still have
    ;; (probably unimportant) problems with vectors, since all we have
    ;; is the start of the vector.  If we cared about this, we could
    ;; store in the hash table a list of the line numbers for each
    ;; item in the vector, not just its start.
    ;;
    ;; --ben

;     (byte-compile-log-1 (concat "** line: "
; 				(save-excursion
; 				  (set-buffer byte-compile-inbuffer)
; 				  (int-to-string (line-number)))
; 				" "
; 				format) t)
;;; RMS says:
;;; It is useless to flash warnings too fast to be read.
;;; Besides, they will all be shown at the end.
;;; and comments out the next two lines.
    (or noninteractive  ; already written on stdout.
	(message "Warning: %s" format))))

;;; This function should be used to report errors that have halted
;;; compilation of the current file.
(defun byte-compile-report-error (error-info)
  (setq byte-compiler-error-flag t)
  (byte-compile-log-1
   (concat "!! "
	   (format (if (cdr error-info) "%s (%s)" "%s")
		   (get (car error-info) 'error-message)
		   (prin1-to-string (cdr error-info)))))
  (if stack-trace-on-error
      (backtrace nil t)))

;;; Used by make-obsolete.
(defun byte-compile-obsolete (form)
  (let ((new (get (car form) 'byte-obsolete-info)))
    (if (memq 'obsolete byte-compile-warnings)
	(byte-compile-warn "%s is an obsolete function; %s" (car form)
			   (if (stringp (car new))
			       (car new)
			     (format "use %s instead." (car new)))))
    (funcall (or (cdr new) 'byte-compile-normal-call) form)))

;;; Used by make-obsolete.
(defun byte-compile-compatible (form)
  (let ((new (get (car form) 'byte-compatible-info)))
    (if (memq 'pedantic byte-compile-warnings)
	(byte-compile-warn "%s is provided for compatibility; %s" (car form)
			   (if (stringp (car new))
			       (car new)
			     (format "use %s instead." (car new)))))
    (funcall (or (cdr new) 'byte-compile-normal-call) form)))

;; Compiler options

(defconst byte-compiler-legal-options
  '((optimize byte-optimize (t nil source byte) val)
    (file-format byte-compile-emacs19-compatibility (emacs20)
		 (eq val 'emacs19))
    (delete-errors byte-compile-delete-errors (t nil) val)
    (verbose byte-compile-verbose (t nil) val)
    (new-bytecodes byte-compile-new-bytecodes (t nil) val)
    (warnings byte-compile-warnings
	      ((callargs subr-callargs redefine free-vars unused-vars
			 unresolved discarded-consing quoted-lambda))
	      val)))

;; XEmacs addition
(defconst byte-compiler-obsolete-options
  '((new-bytecodes t) (byte-compile-emacs19-compatibility nil)))

(defun byte-compiler-options-handler (&rest args)
  (let (key val desc choices)
    (while args
      (if (or (atom (car args)) (nthcdr 2 (car args)) (null (cdr (car args))))
	  (error "malformed byte-compiler-option %s" (car args)))
      (setq key (car (car args))
	    val (car (cdr (car args)))
	    desc (assq key byte-compiler-legal-options))
      (or desc
	  (error "unknown byte-compiler option %s" key))
      (if (assq key byte-compiler-obsolete-options)
	  (byte-compile-warn "%s is an obsolete byte-compiler option." key))
      (setq choices (nth 2 desc))
      (if (consp (car choices))
	  (let* (this
		 (handler 'cons)
		 (var (nth 1 desc))
		 (ret (and (memq (car val) '(+ -))
			   (copy-sequence (if (eq t (symbol-value var))
					      (car choices)
					    (symbol-value var))))))
	    (setq choices (car  choices))
	    (while val
	      (setq this (car val))
	      (cond ((memq this choices)
		     (setq ret (funcall handler this ret)))
		    ((eq this '+) (setq handler 'cons))
		    ((eq this '-) (setq handler 'delq))
		    ((error "%s only accepts %s." key choices)))
	      (setq val (cdr val)))
	    (set (nth 1 desc) ret))
	(or (memq val choices)
	    (error "%s must be one of %s." key choices))
	(set (nth 1 desc) (eval (nth 3 desc))))
      (setq args (cdr args)))
    nil))

;;; sanity-checking arglists

(defun byte-compile-fdefinition (name macro-p)
  (let* ((list (if (memq macro-p '(nil subr))
		   byte-compile-function-environment
		 byte-compile-macro-environment))
	 (env (cdr (assq name list))))
    (or env
	(let ((fn name))
	  (while (and (symbolp fn)
		      (fboundp fn)
		      (or (symbolp (symbol-function fn))
			  (consp (symbol-function fn))
			  (and (not macro-p)
			       (compiled-function-p (symbol-function fn)))
			  (and (eq macro-p 'subr) (subrp fn))))
	    (setq fn (symbol-function fn)))
	  (if (or (and (not macro-p) (compiled-function-p fn))
		  (and (eq macro-p 'subr) (subrp fn)))
	      fn
	    (and (consp fn)
		 (not (eq macro-p 'subr))
		 (if (eq 'macro (car fn))
		     (cdr fn)
		   (if macro-p
		       nil
		     (if (eq 'autoload (car fn))
			 nil
		       fn)))))))))

(defun byte-compile-arglist-signature (arglist)
  (let ((args 0)
	opts
	restp)
    (while arglist
      (cond ((eq (car arglist) '&optional)
	     (or opts (setq opts 0)))
	    ((eq (car arglist) '&rest)
	     (if (cdr arglist)
		 (setq restp t
		       arglist nil)))
	    (t
	     (if opts
		 (setq opts (1+ opts))
		 (setq args (1+ args)))))
      (setq arglist (cdr arglist)))
    (cons args (if restp nil (if opts (+ args opts) args)))))


(defun byte-compile-arglist-signatures-congruent-p (old new)
  (not (or
	 (> (car new) (car old))  ; requires more args now
	 (and (null (cdr old))    ; tooks rest-args, doesn't any more
	      (cdr new))
	 (and (cdr new) (cdr old) ; can't take as many args now
	      (< (cdr new) (cdr old)))
	 )))

(defun byte-compile-arglist-signature-string (signature)
  (cond ((null (cdr signature))
	 (format "%d+" (car signature)))
	((= (car signature) (cdr signature))
	 (format "%d" (car signature)))
	(t (format "%d-%d" (car signature) (cdr signature)))))


;; Warn if the form is calling a function with the wrong number of arguments.
(defun byte-compile-callargs-warn (form)
  (let* ((def (or (byte-compile-fdefinition (car form) nil)
		  (byte-compile-fdefinition (car form) t)))
	 (sig (and def (byte-compile-arglist-signature
			 (if (eq 'lambda (car-safe def))
			     (nth 1 def)
			   (if (compiled-function-p def)
			       (compiled-function-arglist def)
			     '(&rest def))))))
	 (ncall (length (cdr form))))
    (if (and (null def)
	     (fboundp 'subr-min-args)
	     (setq def (byte-compile-fdefinition (car form) 'subr)))
	(setq sig (cons (subr-min-args def) (subr-max-args def))))
    (if sig
	(if (or (< ncall (car sig))
		(and (cdr sig) (> ncall (cdr sig))))
	    (byte-compile-warn
	      "%s called with %d argument%s, but %s %s"
	      (car form) ncall
	      (if (= 1 ncall) "" "s")
	      (if (< ncall (car sig))
		  "requires"
		  "accepts only")
	      (byte-compile-arglist-signature-string sig)))
      (or (fboundp (car form)) ; might be a subr or autoload.
	  ;; ## this doesn't work with recursion.
	  (eq (car form) byte-compile-current-form)
	  ;; It's a currently-undefined function.
	  ;; Remember number of args in call.
	  (let ((cons (assq (car form) byte-compile-unresolved-functions))
		(n (length (cdr form))))
	    (if cons
		(or (memq n (cdr cons))
		    (setcdr cons (cons n (cdr cons))))
		(setq byte-compile-unresolved-functions
		      (cons (list (car form) n)
			    byte-compile-unresolved-functions))))))))

;; Warn if the function or macro is being redefined with a different
;; number of arguments.
(defun byte-compile-arglist-warn (form macrop)
  (let ((old (byte-compile-fdefinition (nth 1 form) macrop)))
    (if old
	(let ((sig1 (byte-compile-arglist-signature
		      (if (eq 'lambda (car-safe old))
			  (nth 1 old)
			(if (compiled-function-p old)
			    (compiled-function-arglist old)
			  '(&rest def)))))
	      (sig2 (byte-compile-arglist-signature (nth 2 form))))
	  (or (byte-compile-arglist-signatures-congruent-p sig1 sig2)
	      (byte-compile-warn "%s %s used to take %s %s, now takes %s"
		(if (eq (car form) 'defun) "function" "macro")
		(nth 1 form)
		(byte-compile-arglist-signature-string sig1)
		(if (equal sig1 '(1 . 1)) "argument" "arguments")
		(byte-compile-arglist-signature-string sig2))))
      ;; This is the first definition.  See if previous calls are compatible.
      (let ((calls (assq (nth 1 form) byte-compile-unresolved-functions))
	    nums sig min max)
	(if calls
	    (progn
	      (setq sig (byte-compile-arglist-signature (nth 2 form))
		    nums (sort (copy-sequence (cdr calls)) (function <))
		    min (car nums)
		    max (car (nreverse nums)))
	      (if (or (< min (car sig))
		      (and (cdr sig) (> max (cdr sig))))
		  (byte-compile-warn
	    "%s being defined to take %s%s, but was previously called with %s"
	            (nth 1 form)
		    (byte-compile-arglist-signature-string sig)
		    (if (equal sig '(1 . 1)) " arg" " args")
		    (byte-compile-arglist-signature-string (cons min max))))

	      (setq byte-compile-unresolved-functions
		    (delq calls byte-compile-unresolved-functions)))))
      )))

;; If we have compiled any calls to functions which are not known to be
;; defined, issue a warning enumerating them.
;; `unresolved' in the list `byte-compile-warnings' disables this.
(defun byte-compile-warn-about-unresolved-functions (&optional msg)
  (if (memq 'unresolved byte-compile-warnings)
   (let ((byte-compile-current-form (or msg "the end of the data")))
     ;; First delete the autoloads from the list.
     (if byte-compile-autoload-environment
	 (let ((rest byte-compile-unresolved-functions))
	   (while rest
	     (if (assq (car (car rest)) byte-compile-autoload-environment)
		 (setq byte-compile-unresolved-functions
		       (delq (car rest) byte-compile-unresolved-functions)))
	     (setq rest (cdr rest)))))
     ;; Now warn.
     (if (cdr byte-compile-unresolved-functions)
	 (let* ((str "The following functions are not known to be defined: ")
		(L (+ (length str) 5))
		(rest (reverse byte-compile-unresolved-functions))
		s)
	   (while rest
	     (setq s (symbol-name (car (car rest)))
		   L (+ L (length s) 2)
		   rest (cdr rest))
	     (if (<= L (1- fill-column))
		 (setq str (concat str " " s (and rest ",")))
	       (setq str (concat str "\n    " s (and rest ","))
		     L (+ (length s) 4))))
	   (byte-compile-warn "%s" str))
       (if byte-compile-unresolved-functions
	   (byte-compile-warn "the function %s is not known to be defined."
	    (car (car byte-compile-unresolved-functions)))))))
  nil)

(defun byte-compile-defvar-p (var)
  ;; Whether the byte compiler thinks that non-lexical references to this
  ;; variable are ok.
  (or (globally-boundp var)
      (let ((rest byte-compile-bound-variables))
	(while (and rest var)
	  (if (and (eq var (car-safe (car rest)))
		   (not (= 0 (logand (cdr (car rest))
				     byte-compile-global-bit))))
	      (setq var nil))
	  (setq rest (cdr rest)))
	;; if var is nil at this point, it's a defvar in this file.
	(not var))
      ;; Perhaps (eval-when-compile (defvar foo))
      (and (boundp 'current-load-list)
	   (memq var current-load-list))))


;;; If we have compiled bindings of variables which have no referents, warn.
(defun byte-compile-warn-about-unused-variables ()
  (let ((rest byte-compile-bound-variables)
	(unreferenced '())
	cell)
    (while (and rest
		;; only warn about variables whose lifetime is now ending,
		;; that is, variables from the lexical scope that is now
		;; terminating.  (Think nested lets.)
		(not (eq (car rest) 'new-scope)))
      (setq cell (car rest))
      (if (and (= 0 (logand byte-compile-referenced-bit (cdr cell)))
	       ;; Don't warn about declared-but-unused arguments,
	       ;; for two reasons: first, the arglist structure
	       ;; might be imposed by external forces, and we don't
	       ;; have (declare (ignore x)) yet; and second, inline
	       ;; expansion produces forms like
	       ;;   ((lambda (arg) (byte-code "..." [arg])) x)
	       ;; which we can't (ok, well, don't) recognize as
	       ;; containing a reference to arg, so every inline
	       ;; expansion would generate a warning.  (If we had
	       ;; `ignore' then inline expansion could emit an
	       ;; ignore declaration.)
	       (= 0 (logand byte-compile-arglist-bit (cdr cell)))
	       ;; Don't warn about defvars because this is a
	       ;; legitimate special binding.
	       (not (byte-compile-defvar-p (car cell))))
	  (setq unreferenced (cons (car cell) unreferenced)))
      (setq rest (cdr rest)))
    (setq unreferenced (nreverse unreferenced))
    (while unreferenced
      (byte-compile-warn
       (format "variable %s bound but not referenced" (car unreferenced)))
      (setq unreferenced (cdr unreferenced)))))


(defmacro byte-compile-constant-symbol-p (symbol)
  `(or (keywordp ,symbol) (memq ,symbol '(nil t))))

(defmacro byte-compile-constp (form)
  ;; Returns non-nil if FORM is a constant.
  `(cond ((consp ,form) (memq (car ,form) '(quote function)))
	 ((symbolp ,form) (byte-compile-constant-symbol-p ,form))
	 (t)))

(defmacro byte-compile-close-variables (&rest body)
  `(let
       (;;
	;; Close over these variables to encapsulate the
	;; compilation state
	;;
	(byte-compile-macro-environment
	 ;; Copy it because the compiler may patch into the
	 ;; macroenvironment.
	 (copy-alist byte-compile-initial-macro-environment))
	(byte-compile-function-environment nil)
	(byte-compile-autoload-environment nil)
	(byte-compile-unresolved-functions nil)
	(byte-compile-bound-variables nil)
	(byte-compile-free-references nil)
	(byte-compile-free-assignments nil)
	;;
	;; Close over these variables so that `byte-compiler-options'
	;; can change them on a per-file basis.
	;;
	(byte-compile-verbose byte-compile-verbose)
	(byte-optimize byte-optimize)
	(byte-compile-checks-on-load
	 byte-compile-checks-on-load)
	(byte-compile-dynamic byte-compile-dynamic)
	(byte-compile-dynamic-docstrings
	 byte-compile-dynamic-docstrings)
	(byte-compile-warnings (if (eq byte-compile-warnings t)
				   byte-compile-default-warnings
				 byte-compile-warnings))
	(byte-compile-file-domain nil))
     (prog1
	 (progn ,@body)
       (if (memq 'unused-vars byte-compile-warnings)
	   ;; done compiling in this scope, warn now.
	   (byte-compile-warn-about-unused-variables)))))


(defmacro displaying-byte-compile-warnings (&rest body)
  `(let* ((byte-compile-log-buffer (get-buffer-create "*Compile-Log*"))
	  (byte-compile-point-max-prev (point-max byte-compile-log-buffer)))
     ;; Log the file name or buffer name.
     (byte-compile-log-file)
     ;; Record how much is logged now.
     ;; We will display the log buffer if anything more is logged
     ;; before the end of BODY.
     (defvar byte-compile-warnings-beginning)
     (let ((byte-compile-warnings-beginning
	    (if (boundp 'byte-compile-warnings-beginning)
		byte-compile-warnings-beginning
	      (point-max byte-compile-log-buffer))))

       (unwind-protect
	   (call-with-condition-handler
	       #'(lambda (error-info)
		   (byte-compile-report-error error-info))
	       #'(lambda ()
		   (progn ,@body)))
	 ;; Always set point in log to start of interesting output.
	 (with-current-buffer byte-compile-log-buffer
	   (let ((show-begin
		  (progn (goto-char byte-compile-point-max-prev)
			 (skip-chars-forward "\^L\n")
			 (point))))
	     ;; If there were compilation warnings, display them.
	     (if temp-buffer-show-function
		 (let ((show-buffer (get-buffer-create "*Compile-Log-Show*")))
		   ;; Always clean show-buffer, even when not displaying it,
		   ;; so that misleading previous messages aren't left around.
		   (with-current-buffer show-buffer
		     (setq buffer-read-only nil)
		     (erase-buffer))
		   (copy-to-buffer show-buffer show-begin (point-max))
		   (when (< byte-compile-warnings-beginning (point-max))
		     (funcall temp-buffer-show-function show-buffer)))
	       (when (< byte-compile-warnings-beginning (point-max))
		 (select-window
		  (prog1 (selected-window)
		    (select-window (display-buffer (current-buffer)))
		    (goto-char show-begin)
		    (recenter 1)))))))))))


;;;###autoload
(defun byte-force-recompile (directory)
  "Recompile every `.el' file in DIRECTORY that already has a `.elc' file.
Files in subdirectories of DIRECTORY are processed also."
  (interactive "DByte force recompile (directory): ")
  (byte-recompile-directory directory nil nil t))

;;;###autoload
(defun byte-recompile-directory (directory &optional arg norecursion force)
  "Recompile every `.el' file in DIRECTORY that needs recompilation.
This is if a `.elc' file exists but is older than the `.el' file.
Files in subdirectories of DIRECTORY are also processed unless
optional argument NORECURSION is non-nil.

If the `.elc' file does not exist, normally the `.el' file is *not* compiled.
But a prefix argument (optional second arg) means ask user,
for each such `.el' file, whether to compile it.  Prefix argument 0 means
don't ask and compile the file anyway.

A nonzero prefix argument also means ask about each subdirectory.

If the fourth optional argument FORCE is non-nil,
recompile every `.el' file that already has a `.elc' file."
  (interactive "DByte recompile directory: \nP")
  (if arg
      (setq arg (prefix-numeric-value arg)))
  (if noninteractive
      nil
    (save-some-buffers)
    (redraw-modeline))
  (let ((directories (list (expand-file-name directory)))
	(file-count 0)
	(dir-count 0)
	last-dir)
    (displaying-byte-compile-warnings
     (while directories
       (setq directory (file-name-as-directory (car directories)))
       (or noninteractive (message "Checking %s..." directory))
       (let ((files (directory-files directory))
	     source dest)
	 (while files
	   (setq source (expand-file-name (car files) directory))
	   (if (and (not (member (car files) '("." ".." "RCS" "CVS" "SCCS")))
		    ;; Stay away from directory back-links, etc:
		    (not (file-symlink-p source))
		    (file-directory-p source)
		    byte-recompile-directory-recursively)
	       ;; This file is a subdirectory.  Handle them differently.
	       (if (or (null arg)
		       (eq arg 0)
		       (y-or-n-p (concat "Check " source "? ")))
		   (setq directories
			 (nconc directories (list source))))
	     ;; It is an ordinary file.  Decide whether to compile it.
	     (if (and (string-match emacs-lisp-file-regexp source)
		      (not (auto-save-file-name-p source))
		      ;; make sure not a mule file we can't handle.
		      (or (not byte-recompile-ignore-uncompilable-mule-files)
			  (featurep 'mule)
			  (not (find-coding-system-magic-cookie-in-file
				source)))
		      (setq dest (byte-compile-dest-file source))
		      (if (file-exists-p dest)
			  ;; File was already compiled.
			  (or force (file-newer-than-file-p source dest))
			;; No compiled file exists yet.
			(and arg
			     (or (eq 0 arg)
				 (y-or-n-p (concat "Compile " source "? "))))))
		 (progn ;(if (and noninteractive (not byte-compile-verbose))
			;    (message "Compiling %s..." source))
		        ; we do this in byte-compile-file.
		        (if byte-recompile-directory-ignore-errors-p
			     (batch-byte-compile-1 source)
			  (byte-compile-file source))
			(or noninteractive
			    (message "Checking %s..." directory))
			(setq file-count (1+ file-count))
			(if (not (eq last-dir directory))
			    (setq last-dir directory
				  dir-count (1+ dir-count)))
			)))
	   (setq files (cdr files))))
       (setq directories (cdr directories))))
    (message "Done (Total of %d file%s compiled%s)"
	     file-count (if (= file-count 1) "" "s")
	     (if (> dir-count 1) (format " in %d directories" dir-count) ""))))

;;;###autoload
(defun byte-recompile-file (filename &optional force)
  "Recompile a file of Lisp code named FILENAME if it needs recompilation.
This is if the `.elc' file exists but is older than the `.el' file.

If the `.elc' file does not exist, normally the `.el' file is *not*
compiled.  But a prefix argument (optional second arg) means ask user
whether to compile it.  Prefix argument 0 don't ask and recompile anyway."
  (interactive "fByte recompile file: \nP")
  (let ((dest))
    (if (and (string-match emacs-lisp-file-regexp filename)
	     (not (auto-save-file-name-p filename))
	     (setq dest (byte-compile-dest-file filename))
	     (if (file-exists-p dest)
		 (file-newer-than-file-p filename dest)
	       (and force
		    (or (eq 0 force)
			(y-or-n-p (concat "Compile " filename "? ")))))
	     (or (not byte-recompile-ignore-uncompilable-mule-files)
		 (featurep 'mule)
		 (not (find-coding-system-magic-cookie-in-file filename))))
	(byte-compile-file filename))))

;;;###autoload
(defun byte-compile-file (filename &optional load)
  "Compile a file of Lisp code named FILENAME into a file of byte code.
The output file's name is made by appending `c' to the end of FILENAME.
With prefix arg (noninteractively: 2nd arg), load the file after compiling."
;;  (interactive "fByte compile file: \nP")
  (interactive
   (let ((file buffer-file-name)
	 (file-name nil)
	 (file-dir nil))
     (and file
	  (eq (cdr (assq 'major-mode (buffer-local-variables)))
	      'emacs-lisp-mode)
	  (setq file-name (file-name-nondirectory file)
		file-dir (file-name-directory file)))
     (list (read-file-name (if current-prefix-arg
			       "Byte compile and load file: "
			     "Byte compile file: ")
			   file-dir nil nil file-name)
	   current-prefix-arg)))
  ;; Expand now so we get the current buffer's defaults
  (setq filename (expand-file-name filename))

  ;; If we're compiling a file that's in a buffer and is modified, offer
  ;; to save it first.
  (or noninteractive
      (let ((b (get-file-buffer (expand-file-name filename))))
	(if (and b (buffer-modified-p b)
		 (y-or-n-p (format "save buffer %s first? " (buffer-name b))))
	    (save-excursion (set-buffer b) (save-buffer)))))

  (if (or noninteractive byte-compile-verbose) ; XEmacs change
      (message "Compiling %s..." filename))
  (let (;;(byte-compile-current-file (file-name-nondirectory filename))
	(byte-compile-current-file filename)
	target-file input-buffer output-buffer
	byte-compile-dest-file)
    (setq target-file (byte-compile-dest-file filename))
    (setq byte-compile-dest-file target-file)
    (save-excursion
      (setq input-buffer (get-buffer-create " *Compiler Input*"))
      (set-buffer input-buffer)
      (erase-buffer)
      (insert-file-contents filename)
      ;; Run hooks including the uncompression hook.
      ;; If they change the file name, then change it for the output also.
      (let ((buffer-file-name filename)
	    (default-major-mode 'emacs-lisp-mode)
	    (enable-local-eval nil))
        (normal-mode)
        (setq filename buffer-file-name)))
      (setq byte-compiler-error-flag nil)
    ;; It is important that input-buffer not be current at this call,
    ;; so that the value of point set in input-buffer
    ;; within byte-compile-from-buffer lingers in that buffer.
    (setq output-buffer (byte-compile-from-buffer input-buffer filename))
    (if byte-compiler-error-flag
	nil
      (if byte-compile-verbose
	  (message "Compiling %s...done" filename))
      (kill-buffer input-buffer)
      (save-excursion
	(set-buffer output-buffer)
	(goto-char (point-max))
	(insert "\n")			; aaah, unix.
	(setq target-file (byte-compile-dest-file filename))
	(unless byte-compile-overwrite-file
	  (ignore-file-errors (delete-file target-file)))
	(if (file-writable-p target-file)
	    ;; prevent generic hooks from changing our format, eg,
	    ;; latin-unity is known to change the coding system!
	    (let ((write-region-pre-hook nil))
	      (write-region 1 (point-max) target-file))
	  ;; This is just to give a better error message than write-region
	  (signal 'file-error
		  (list "Opening output file"
			(if (file-exists-p target-file)
			    "cannot overwrite file"
			  "directory not writable or nonexistent")
			target-file)))
	(or byte-compile-overwrite-file
	    (condition-case ()
		(set-file-modes target-file (file-modes filename))
	      (error nil)))
	(kill-buffer (current-buffer)))
      (if (and byte-compile-generate-call-tree
	       (or (eq t byte-compile-generate-call-tree)
		   (y-or-n-p (format "Report call tree for %s? " filename))))
	  (save-excursion
	    (display-call-tree filename)))
      (if load
	  (load target-file))
      t)))

;; RMS comments the next two out.

;;;###autoload
(defun byte-compile-and-load-file (&optional filename)
  "Compile a file of Lisp code named FILENAME into a file of byte code,
and then load it.  The output file's name is made by appending \"c\" to
the end of FILENAME."
  (interactive)
  (if filename ; I don't get it, (interactive-p) doesn't always work
	(byte-compile-file filename t)
    (let ((current-prefix-arg '(4)))
	(call-interactively 'byte-compile-file))))

;;;###autoload
(defun byte-compile-buffer (&optional buffer)
  "Byte-compile and evaluate contents of BUFFER (default: the current buffer)."
  (interactive "bByte compile buffer: ")
  (setq buffer (if buffer (get-buffer buffer) (current-buffer)))
  (message "Compiling %s..." buffer)
  (let* ((filename (or (buffer-file-name buffer)
		       (prin1-to-string buffer)))
	 (byte-compile-current-file buffer))
    (byte-compile-from-buffer buffer filename t))
  (message "Compiling %s...done" buffer)
  t)

;;; compiling a single function
;;;###autoload
(defun compile-defun (&optional arg)
  "Compile and evaluate the current top-level form.
Print the result in the minibuffer.
With argument, insert value in current buffer after the form."
  (interactive "P")
  (save-excursion
    (end-of-defun)
    (beginning-of-defun)
    (let* ((byte-compile-current-file (buffer-file-name))
	   (load-file-name (buffer-file-name))
	   (byte-compile-last-warned-form 'nothing)
	   (value (eval (displaying-byte-compile-warnings
			 (byte-compile-sexp (read (current-buffer))
					    "toplevel forms")))))
      (cond (arg
	     (message "Compiling from buffer... done.")
	     (prin1 value (current-buffer))
	     (insert "\n"))
	    ((message "%s" (prin1-to-string value)))))))

(defun byte-compile-from-buffer (byte-compile-inbuffer filename &optional eval)
  ;; buffer --> output-buffer, or buffer --> eval form, return nil
  (let (byte-compile-outbuffer
	;; Prevent truncation of flonums and lists as we read and print them
	(float-output-format nil)
	(case-fold-search nil)
	(print-length nil)
	(print-level nil)
	;; Simulate entry to byte-compile-top-level
	(byte-compile-constants nil)
	(byte-compile-variables nil)
	(byte-compile-tag-number 0)
	(byte-compile-depth 0)
	(byte-compile-maxdepth 0)
	(byte-compile-output nil)
	;;	  #### This is bound in b-c-close-variables.
	;;	  (byte-compile-warnings (if (eq byte-compile-warnings t)
	;;				     byte-compile-warning-types
	;;				   byte-compile-warnings))
        (byte-compile-force-escape-quoted byte-compile-force-escape-quoted)
        (byte-compile-using-dynamic nil))
    (byte-compile-close-variables
     (save-excursion
       (setq byte-compile-outbuffer
	     (set-buffer (get-buffer-create " *Compiler Output*")))
       (erase-buffer)
       ;;	 (emacs-lisp-mode)
       (setq case-fold-search nil)
       (and filename
	    (not eval)
	    (byte-compile-maybe-reset-coding byte-compile-inbuffer
					     byte-compile-outbuffer))
       (setq byte-compile-using-dynamic
             (or (symbol-value-in-buffer 'byte-compile-dynamic
                                         byte-compile-inbuffer)
                 (symbol-value-in-buffer 'byte-compile-dynamic-docstrings
                                         byte-compile-inbuffer)))
       ;; This is a kludge.  Some operating systems (OS/2, DOS) need to
       ;; write files containing binary information specially.
       ;; Under most circumstances, such files will be in binary
       ;; overwrite mode, so those OS's use that flag to guess how
       ;; they should write their data.  Advise them that .elc files
       ;; need to be written carefully.
       (setq overwrite-mode 'overwrite-mode-binary))
     (displaying-byte-compile-warnings
      (save-excursion
	;; All our save-excursions may have led to a less-than-useful
	;; value for point in the outbuffer:
	(goto-char (point-max byte-compile-outbuffer) byte-compile-outbuffer)
	(set-buffer byte-compile-inbuffer)
	(goto-char 1)

	;; Compile the forms from the input buffer.
	(while (progn
		 (while (progn (skip-chars-forward " \t\n\^L")
			       (looking-at ";"))
		   (forward-line 1))
		 (not (eobp)))
	  (byte-compile-file-form (read byte-compile-inbuffer))
          (or (eq byte-compile-inbuffer (current-buffer))
              (error 'invalid-state 
                     "byte compiling didn't save-excursion appropriately"
                     (current-buffer))))

	;; Compile pending forms at end of file.
	(byte-compile-flush-pending)
	(byte-compile-insert-header filename byte-compile-inbuffer
				    byte-compile-outbuffer)
	(byte-compile-warn-about-unresolved-functions)
	;; Should we always do this?  When calling multiple files, it
	;; would be useful to delay this warning until all have
	;; been compiled.
	(setq byte-compile-unresolved-functions nil)))
     (save-excursion
       (set-buffer byte-compile-outbuffer)
       (goto-char (point-min))
       (when (and (or byte-compile-using-dynamic
                      (eq buffer-file-coding-system 'raw-text-unix))
                  (re-search-forward "[^\x00-\xff]" nil t))
	 (when (or noninteractive byte-compile-verbose)
	   (message
	    "%s: includes char above ?\\xFF, recompiling sans dynamic features."
	    filename))
         (set-symbol-value-in-buffer 'byte-compile-dynamic nil
                                     byte-compile-inbuffer)
         (set-symbol-value-in-buffer 'byte-compile-dynamic-docstrings nil
                                     byte-compile-inbuffer)
         (setq byte-compile-force-escape-quoted t
               byte-compile-outbuffer
               (byte-compile-from-buffer byte-compile-inbuffer 
                                         filename eval)))))
    (if (not eval)
	byte-compile-outbuffer
      (let (form)
	(while (condition-case nil
		   (progn (setq form (read byte-compile-outbuffer))
			  t)
		 (end-of-file nil))
	  (eval form)))
      (kill-buffer byte-compile-outbuffer)
      nil)))

(defvar byte-compile-checks-and-comments-space 475
  "Number of octets of space for checks and comments; used by the dynamic
docstrings code.")

(defun byte-compile-insert-header (filename byte-compile-inbuffer
				   byte-compile-outbuffer)
  (set-buffer byte-compile-inbuffer)
  (let (comments)
    (set-buffer byte-compile-outbuffer)
    (delete-region 1 (1+ byte-compile-checks-and-comments-space))
    (goto-char 1)
    ;;
    ;; The magic number of .elc files is ";ELC", or 0x3B454C43.  After that is
    ;; the file-format version number (19 or 20) as a byte, followed by some
    ;; nulls.  The primary motivation for doing this is to get some binary
    ;; characters up in the first line of the file so that `diff' will simply
    ;; say "Binary files differ" instead of actually doing a diff of two .elc
    ;; files.  An extra benefit is that you can add this to /etc/magic:
    ;;
    ;; 0	string		;ELC		XEmacs Lisp compiled file,
    ;; >4	byte		x		version %d
    ;;
    (insert
     ";ELC"
     20
     "\000\000\000\n")
    (insert (format ";;;###coding system: %s\n"
                    (coding-system-name buffer-file-coding-system)))
    (insert (format
	     "\n(or %s\n    (error \"Loading this file requires %s\"))\n"
             (let ((print-readably t))
               (prin1-to-string (if (> (length 
                                        byte-compile-checks-on-load)
                                       1)
                                    (cons 'and
                                          (setq byte-compile-checks-on-load
                                                (reverse
                                                 byte-compile-checks-on-load)))
                                  (car byte-compile-checks-on-load))))
             (loop
               for check in byte-compile-checks-on-load
               with seen-first = nil
               with res = ""
               do
               (if seen-first
                   (setq res (concat res ", "))
                 (setq seen-first t))
               ;; Print featurep calls differently: 
               (if (and (eq (car check) 'featurep)
                        (eq (car (second check)) 'quote)
                        (symbolp (second (second check))))
                   (setq res (concat res 
                                     (symbol-name (second (second check)))))
                 (setq res (concat res
                                   (let ((print-readably t)) 
                                     (prin1-to-string check)))))
               finally return res)))
    (setq comments 
	  (with-string-as-buffer-contents ""
	    (insert "\n;;; compiled by "
		    (or (and (boundp 'user-mail-address) user-mail-address)
			(concat (user-login-name) "@" (system-name)))
		    " on "
		    (current-time-string) "\n;;; from file " filename "\n")
	    (insert ";;; emacs version " emacs-version ".\n")
	    (insert ";;; bytecomp version " byte-compile-version "\n;;; "
		    (cond
		     ((eq byte-optimize 'source)
		      "source-level optimization only")
		     ((eq byte-optimize 'byte) "byte-level optimization only")
		     (byte-optimize "optimization is on")
		     (t "optimization is off"))
		    "\n")))

    ;; We won't trip this unless the byte-compiler changes, in which case
    ;; it's just a matter of upping the space. 
    (assert (natnump (- (1+ byte-compile-checks-and-comments-space) (point)))
	    t "Not enough space for the feature checks!")

    (if (natnump (- (1+ byte-compile-checks-and-comments-space)
		    (+ (point) (length comments))))
	(insert comments))
    (insert-char ?\  (- (1+ byte-compile-checks-and-comments-space)
			(point)))))

(defun byte-compile-maybe-reset-coding (byte-compile-inbuffer
					byte-compile-outbuffer)
  ;; We also reserve some space for the feature checks:
  (goto-char 1)
  (insert-char ?\  byte-compile-checks-and-comments-space)
  (if (or (featurep '(not mule)) ;; Don't scan buffer if we are not muleized
          (and
	   (not byte-compile-force-escape-quoted)
	   (save-excursion
	     (set-buffer byte-compile-inbuffer)
	     (goto-char (point-min))
	     ;; Look for any non-Latin-1 literals or Unicode character
	     ;; escapes. Any such occurrences in a @#COUNT comment will lead
	     ;; to an escape-quoted coding cookie being inserted, but this is
	     ;; not true of ordinary comments.
	     (let ((non-latin-1-re
		    (concat "[^\000-\377]" 
			    #r"\|\\u[0-9a-fA-F]\{4,4\}\|\\U[0-9a-fA-F]"
			    "\\{8,8\\}"))
		   (case-fold-search nil))
	       (catch 'need-to-escape-quote
		 (while (re-search-forward non-latin-1-re nil t)
		   (skip-chars-backward "^;" (point-at-bol))
		   (if (bolp) (throw 'need-to-escape-quote nil))
		   (forward-line 1))
		 t)))))
      (setq buffer-file-coding-system 'raw-text-unix)
    (setq buffer-file-coding-system 'escape-quoted)
    (pushnew '(featurep 'mule) byte-compile-checks-on-load)
    (save-excursion
      (set-buffer byte-compile-inbuffer)
      (setq byte-compile-dynamic nil
	    byte-compile-dynamic-docstrings nil))))

(defun byte-compile-output-file-form (form)
  ;; writes the given form to the output buffer, being careful of docstrings
  ;; in defun, defmacro, defvar, defconst and autoload because make-docfile is
  ;; so amazingly stupid.
  ;; defalias calls are output directly by byte-compile-file-form-defmumble;
  ;; it does not pay to first build the defalias in defmumble and then parse
  ;; it here.
  (if (and (memq (car-safe form) '(defun defmacro defvar defconst autoload
				   custom-declare-variable))
	   (stringp (nth 3 form)))
      (byte-compile-output-docform nil nil '("\n(" 3 ")") form nil
				   (memq (car form)
					 '(autoload custom-declare-variable)))
    (let* ((print-escape-newlines t)
	   (print-length nil)
	   (print-level nil)
	   (print-readably t)	; print #[] for bytecode, 'x for (quote x)
	   (print-gensym byte-compile-print-gensym)
	   (print-continuous-numbering print-gensym)
	   (print-circle t))
      (when byte-compile-output-preface
        (princ "\n(progn " byte-compile-outbuffer)
        (prin1 byte-compile-output-preface byte-compile-outbuffer))
      (princ "\n" byte-compile-outbuffer)
      (prin1 form byte-compile-outbuffer)
      (when byte-compile-output-preface (princ ")" byte-compile-outbuffer))
      nil)))

(defun byte-compile-output-docform (preface name info form specindex quoted)
  "Print a form with a doc string.  INFO is (prefix doc-index postfix).
If PREFACE and NAME are non-nil, print them too,
before INFO and the FORM but after the doc string itself.
If SPECINDEX is non-nil, it is the index in FORM
of the function bytecode string.  In that case,
we output that argument and the following argument (the constants vector)
together, for lazy loading.
QUOTED says that we have to put a quote before the
list that represents a doc string reference.
`autoload' needs that."
  ;; We need to examine byte-compile-dynamic-docstrings
  ;; in the input buffer (now current), not in the output buffer.
  (let ((dynamic-docstrings byte-compile-dynamic-docstrings))
    (set-buffer
     (prog1 (current-buffer)
       (set-buffer byte-compile-outbuffer)
       (let (position)

	 ;; Insert the doc string, and make it a comment with #@LENGTH.
	 (and (>= (nth 1 info) 0)
	      dynamic-docstrings
	      (progn
		;; Make the doc string start at beginning of line
		;; for make-docfile's sake.
		(insert "\n")
		(setq position
		      (byte-compile-output-as-comment
		       (nth (nth 1 info) form) nil))
		;; If the doc string starts with * (a user variable),
		;; negate POSITION.
		(if (and (stringp (nth (nth 1 info) form))
			 (> (length (nth (nth 1 info) form)) 0)
			 (char= (aref (nth (nth 1 info) form) 0) ?*))
		    (setq position (- position)))))
         (byte-compile-flush-pending)
	 (let* ((print-escape-newlines t)
		(print-readably t)	; print #[] for bytecode, 'x for (quote x)
		(print-gensym byte-compile-print-gensym)
                (print-continuous-numbering print-gensym)
                (print-circle t)
		(index 0))
           (when byte-compile-output-preface
             (princ "\n(progn " byte-compile-outbuffer)
             (prin1 byte-compile-output-preface byte-compile-outbuffer))
	   (if preface
	       (progn
		 (insert preface)
		 (prin1 name byte-compile-outbuffer)))
	   (insert (car info))
	   (prin1 (car form) byte-compile-outbuffer)
	   (while (setq form (cdr form))
	     (setq index (1+ index))
	     (insert " ")
	     (cond ((and (numberp specindex) (= index specindex))
		    (let ((position
			   (byte-compile-output-as-comment
			    (cons (car form) (nth 1 form))
			    t)))
		      (princ (format "(#$ . %d) nil" position)
			     byte-compile-outbuffer)
		      (setq form (cdr form))
		      (setq index (1+ index))))
		   ((= index (nth 1 info))
		    (if position
			(princ (format (if quoted "'(#$ . %d)"  "(#$ . %d)")
				       position)
			       byte-compile-outbuffer)
		      (let ((print-escape-newlines nil))
			(goto-char (prog1 (1+ (point))
				     (prin1 (car form)
					    byte-compile-outbuffer)))
			(insert "\\\n")
			(goto-char (point-max)))))
		   (t
		    (prin1 (car form) byte-compile-outbuffer)))))
	 (insert (nth 2 info))
	 (when byte-compile-output-preface
	   (princ ")" byte-compile-outbuffer))))))
  nil)

(defun byte-compile-keep-pending (form &optional handler)
  (if (memq byte-optimize '(t source))
      (setq form (byte-optimize-form form t)))
  (if handler
      (let ((for-effect t))
	;; To avoid consing up monstrously large forms at load time, we split
	;; the output regularly.
	(and (memq (car-safe form) '(fset defalias define-function))
	     (nthcdr 300 byte-compile-output)
	     (byte-compile-flush-pending))
	(funcall handler form)
	(when for-effect
	  (byte-compile-discard)))
    (byte-compile-form form t))
  nil)

(defun byte-compile-flush-pending ()
  (if byte-compile-output
      (let ((form (byte-compile-out-toplevel t 'file)))
	(cond ((eq (car-safe form) 'progn)
	       (mapc 'byte-compile-output-file-form (cdr form)))
	      (form
	       (byte-compile-output-file-form form)))
	(setq byte-compile-constants nil
	      byte-compile-variables nil
	      byte-compile-depth 0
	      byte-compile-maxdepth 0
	      byte-compile-output nil))))

(defun byte-compile-file-form (form)
  (let ((byte-compile-current-form nil)	; close over this for warnings.
        (byte-compile-output-preface nil)
	handler)
    (cond
     ((not (consp form))
      (byte-compile-keep-pending form))
     ((and (symbolp (car form))
	   (setq handler (get (car form) 'byte-hunk-handler)))
      (cond ((setq form (funcall handler form))
	     (byte-compile-flush-pending)
	     (byte-compile-output-file-form form))))
     ((eq form (setq form (macroexpand form byte-compile-macro-environment)))
      (byte-compile-keep-pending form))
     (t
      (byte-compile-file-form form)))))

;; Functions and variables with doc strings must be output separately,
;; so make-docfile can recognize them.  Most other things can be output
;; as byte-code.

(put 'defsubst 'byte-hunk-handler 'byte-compile-file-form-defsubst)
(defun byte-compile-file-form-defsubst (form)
  (cond ((assq (nth 1 form) byte-compile-unresolved-functions)
	 (setq byte-compile-current-form (nth 1 form))
	 (byte-compile-warn "defsubst %s was used before it was defined"
			    (nth 1 form))))
  (byte-compile-file-form
   (macroexpand form byte-compile-macro-environment))
  ;; Return nil so the form is not output twice.
  nil)

(put 'autoload 'byte-hunk-handler 'byte-compile-file-form-autoload)
(defun byte-compile-file-form-autoload (form)
  ;;
  ;; If this is an autoload of a macro, and all arguments are constants (that
  ;; is, there is no hairy computation going on here) then evaluate the form
  ;; at compile-time.  This is so that we can make use of macros which we
  ;; have autoloaded from the file being compiled.  Normal function autoloads
  ;; are not automatically evaluated at compile time, because there's not
  ;; much point to it (so why bother cluttering up the compile-time namespace.)
  ;;
  ;; If this is an autoload of a function, then record its definition in the
  ;; byte-compile-autoload-environment to suppress any `not known to be
  ;; defined' warnings at the end of this file (this only matters for
  ;; functions which are autoloaded and compiled in the same file, if the
  ;; autoload already exists in the compilation environment, we wouldn't have
  ;; warned anyway.)
  ;;
  (let* ((name (if (byte-compile-constp (nth 1 form))
		   (eval (nth 1 form))))
	 ;; In v19, the 5th arg to autoload can be t, nil, 'macro, or 'keymap.
	 (macrop (and (byte-compile-constp (nth 5 form))
		      (memq (eval (nth 5 form)) '(t macro))))
;;	 (functionp (and (byte-compile-constp (nth 5 form))
;;			 (eq 'nil (eval (nth 5 form)))))
	 )
    (if (and macrop
	     (let ((form form))
	       ;; all forms are constant
	       (while (if (setq form (cdr form))
			  (byte-compile-constp (car form))))
	       (null form)))
	;; eval the macro autoload into the compilation environment
	(eval form))

    (if name
	(let ((old (assq name byte-compile-autoload-environment)))
	  (cond (old
		 (if (memq 'redefine byte-compile-warnings)
		     (byte-compile-warn "multiple autoloads for %s" name))
		 (setcdr old form))
		(t
		 ;; We only use the names in the autoload environment, but
		 ;; it might be useful to have the bodies some day.
		 (setq byte-compile-autoload-environment
		       (cons (cons name form)
			     byte-compile-autoload-environment)))))))
  ;;
  ;; Now output the form.
  (if (stringp (nth 3 form))
      form
    ;; No doc string, so we can compile this as a normal form.
    (byte-compile-keep-pending form 'byte-compile-normal-call)))

(put 'defvar   'byte-hunk-handler 'byte-compile-file-form-defvar-or-defconst)
(put 'defconst 'byte-hunk-handler 'byte-compile-file-form-defvar-or-defconst)
(defun byte-compile-file-form-defvar-or-defconst (form)
  ;; (defvar|defconst VAR [VALUE [DOCSTRING]])
  (if (> (length form) 4)
      (byte-compile-warn
       "%s %s called with %d arguments, but accepts only %s"
       (car form) (nth 1 form) (length (cdr form)) 3))
  (if (and (> (length form) 3) (not (stringp (nth 3 form))))
      (byte-compile-warn "Third arg to %s %s is not a string: %s"
			 (car form) (nth 1 form) (nth 3 form)))
  (if (null (nth 3 form))
      ;; Since there is no doc string, we can compile this as a normal form,
      ;; and not do a file-boundary.
      (byte-compile-keep-pending form)
    (if (memq 'free-vars byte-compile-warnings)
	(setq byte-compile-bound-variables
	      (cons (cons (nth 1 form) byte-compile-global-bit)
		    byte-compile-bound-variables)))
    (cond ((consp (nth 2 form))
	   (setq form (copy-sequence form))
	   (setcar (cdr (cdr form))
		   (byte-compile-top-level (nth 2 form) nil 'file))))

    ;; The following turns out not to be necessary, since we emit a call to
    ;; defvar, which can hack Vfile_domain by itself!
    ;;
    ;; If a file domain has been set, emit (put 'VAR 'variable-domain ...)
    ;; after this defvar.
;    (if byte-compile-file-domain
;	(progn
;	  ;; Actually, this will emit the (put ...) before the (defvar ...)
;	  ;; but I don't think that can matter in this case.
;	  (byte-compile-keep-pending
;	   (list 'put (list 'quote (nth 1 form)) ''variable-domain
;		(list 'quote byte-compile-file-domain)))))
    form))

(put 'require 'byte-hunk-handler 'byte-compile-file-form-eval-boundary)
(defun byte-compile-file-form-eval-boundary (form)
  (eval form)
  (byte-compile-keep-pending form 'byte-compile-normal-call))

(put 'progn 'byte-hunk-handler 'byte-compile-file-form-progn)
(put 'prog1 'byte-hunk-handler 'byte-compile-file-form-progn)
(put 'prog2 'byte-hunk-handler 'byte-compile-file-form-progn)
(defun byte-compile-file-form-progn (form)
  (mapc 'byte-compile-file-form (cdr form))
  ;; Return nil so the forms are not output twice.
  nil)

;; This handler is not necessary, but it makes the output from dont-compile
;; and similar macros cleaner.
(put 'eval 'byte-hunk-handler 'byte-compile-file-form-eval)
(defun byte-compile-file-form-eval (form)
  (if (eq (car-safe (nth 1 form)) 'quote)
      (nth 1 (nth 1 form))
    (byte-compile-keep-pending form)))

(put 'defun 'byte-hunk-handler 'byte-compile-file-form-defun)
(defun byte-compile-file-form-defun (form)
  (byte-compile-file-form-defmumble form nil))

(put 'defmacro 'byte-hunk-handler 'byte-compile-file-form-defmacro)
(defun byte-compile-file-form-defmacro (form)
  (byte-compile-file-form-defmumble form t))

(defun byte-compile-file-form-defmumble (form macrop)
  (let* ((name (car (cdr form)))
	 (this-kind (if macrop 'byte-compile-macro-environment
		      'byte-compile-function-environment))
	 (that-kind (if macrop 'byte-compile-function-environment
		      'byte-compile-macro-environment))
	 (this-one (assq name (symbol-value this-kind)))
	 (that-one (assq name (symbol-value that-kind)))
	 (byte-compile-free-references nil)
	 (byte-compile-free-assignments nil))

    ;; When a function or macro is defined, add it to the call tree so that
    ;; we can tell when functions are not used.
    (if byte-compile-generate-call-tree
	(or (assq name byte-compile-call-tree)
	    (setq byte-compile-call-tree
		  (cons (list name nil nil) byte-compile-call-tree))))

    (setq byte-compile-current-form name) ; for warnings
    (when (memq 'redefine byte-compile-warnings)
      (byte-compile-arglist-warn form macrop))
    (defvar filename) ; #### filename used free
    (when byte-compile-verbose
      (message "Compiling %s... (%s)"
	       (if filename (file-name-nondirectory filename) "")
	       (nth 1 form)))
    (cond (that-one
	   (when (and (memq 'redefine byte-compile-warnings)
		      ;; hack hack: don't warn when compiling the stubs in
		      ;; bytecomp-runtime...
		      (not (assq (nth 1 form)
				 byte-compile-initial-macro-environment)))
	     (byte-compile-warn
	      "%s defined multiple times, as both function and macro"
	      (nth 1 form)))
	   (setcdr that-one nil))
	  (this-one
	   (when (and (memq 'redefine byte-compile-warnings)
		      ;; hack: don't warn when compiling the magic internal
		      ;; byte-compiler macros in bytecomp-runtime.el...
		      (not (assq (nth 1 form)
				 byte-compile-initial-macro-environment)))
	     (byte-compile-warn "%s %s defined multiple times in this file"
				(if macrop "macro" "function")
				(nth 1 form))))
	  ((and (fboundp name)
		(or (subrp (symbol-function name))
		    (eq (car-safe (symbol-function name))
		        (if macrop 'lambda 'macro))))
	   (if (memq 'redefine byte-compile-warnings)
	       (byte-compile-warn "%s %s being redefined as a %s"
				  (if (subrp (symbol-function name))
				      "subr"
				    (if macrop "function" "macro"))
				  (nth 1 form)
				  (if macrop "macro" "function")))
	   ;; shadow existing definition
	   (set this-kind
		(cons (cons name nil) (symbol-value this-kind)))))
    (let ((body (nthcdr 3 form)))
      (if (and (stringp (car body))
	       (symbolp (car-safe (cdr-safe body)))
	       (car-safe (cdr-safe body))
	       (stringp (car-safe (cdr-safe (cdr-safe body)))))
	  (byte-compile-warn "Probable `\"' without `\\' in doc string of %s"
			     (nth 1 form))))

    ;; Generate code for declarations in macro definitions.
    ;; Remove declarations from the body of the macro definition.
    (when macrop
      (let ((byte-compile-defmacro-body (nthcdr 3 form)))
        (if (stringp (car byte-compile-defmacro-body))
            (setq byte-compile-defmacro-body (nthcdr 4 form)))
        (when (and (consp byte-compile-defmacro-body)
                   (eq 'declare (car-safe (car byte-compile-defmacro-body))))
          (if (eq 'declare (car-safe (car-safe
                                      (cdr byte-compile-defmacro-body))))
              (byte-compile-warn "Multiple macro-specific `declare' calls \
not supported by XEmacs."))
          (setq byte-compile-output-preface
                (byte-compile-top-level
                 `(progn (and macro-declaration-function
                              (funcall macro-declaration-function
                                       ',name
                                       ',(car byte-compile-defmacro-body)))
                         ,byte-compile-output-preface) t 'file)))))
    (let* ((new-one (byte-compile-lambda (cons 'lambda (nthcdr 2 form))))
	   (code (byte-compile-byte-code-maker new-one))
           (docform-info
            (cond ((atom code) ; compiled-function-p
                   (if macrop '(" '(macro . #[" 4 "]))") '(" #[" 4 "])")))
                  ((eq (car code) 'quote)
                   (setq code new-one)
                   (if macrop '(" '(macro " 2 "))") '(" '(" 2 "))")))
                  ((if macrop '(" (cons 'macro (" 5 ")))") '(" (" 5 "))"))))))
      (if this-one
	  (setcdr this-one new-one)
	(set this-kind
	     (cons (cons name new-one) (symbol-value this-kind))))
      (if (and (stringp (nth 3 form))
	       (eq 'quote (car-safe code))
	       (eq 'lambda (car-safe (nth 1 code))))
	  (cons (car form)
                (cons name (cdr (nth 1 code))))
	(byte-compile-flush-pending)
	(if (not (stringp (nth 3 form)))
            ;; No doc string.  Provide -1 as the "doc string index" so that
            ;; no element will be treated as a doc string by
            ;; byte-compile-output-doc-form.
            (setq docform-info (list (first docform-info) -1
                                     (third docform-info))))
        (byte-compile-output-docform
         "\n(defalias '"
         name
         docform-info
         ;; The result of byte-compile-byte-code-maker is either a
         ;; compiled-function object, or a list of some kind.  If it's not a
         ;; cons, we must coerce it into a list of the elements to be
         ;; printed to the file.
         (if (consp code)
             code
           (list* (compiled-function-arglist code)
                  (compiled-function-instructions code)
                  (compiled-function-constants code)
                  (compiled-function-stack-depth code)
                  (compiled-function-doc-string code)
                  (if (commandp code)
                      (list (nth 1 (compiled-function-interactive code))))))
         (and (atom code) byte-compile-dynamic
              1)
	   nil))
	nil)))

;; Print Lisp object EXP in the output file, inside a comment,
;; and return the file position it will have.
;; If QUOTED is non-nil, print with quoting; otherwise, print without quoting.
(defun byte-compile-output-as-comment (exp quoted)
  (let ((position (point)))
    (set-buffer
     (prog1 (current-buffer)
       (set-buffer byte-compile-outbuffer)

       ;; Insert EXP, and make it a comment with #@LENGTH.
       (insert " ")
       (if quoted
	   (prin1 exp byte-compile-outbuffer)
	 (princ exp byte-compile-outbuffer))
       (goto-char position)
       ;; Quote certain special characters as needed.
       ;; get_doc_string in doc.c does the unquoting.
       (while (search-forward "\^A" nil t)
	 (replace-match "\^A\^A" t t))
       (goto-char position)
       (while (search-forward "\000" nil t)
	 (replace-match "\^A0" t t))
       (goto-char position)
       (while (search-forward "\037" nil t)
	 (replace-match "\^A_" t t))
       (goto-char (point-max))
       (insert "\037")
       (goto-char position)
       (insert "#@" (format "%d" (- (point-max) position)))

       ;; Save the file position of the object.
       ;; Note we should add 1 to skip the space
       ;; that we inserted before the actual doc string,
       ;; and subtract 1 to convert from an 1-origin Emacs position
       ;; to a file position; they cancel.
       (setq position (point))
       (goto-char (point-max))))
    position))



;; The `domain' declaration.  This is legal only at top-level in a file, and
;; should generally be the first form in the file.  It is not legal inside
;; function bodies.

(put 'domain 'byte-hunk-handler 'byte-compile-file-form-domain)
(defun byte-compile-file-form-domain (form)
  (if (not (null (cdr (cdr form))))
      (byte-compile-warn "domain used with too many arguments: %s" form))
  (let ((domain (nth 1 form)))
    (or (null domain)
	(stringp domain)
	(progn
	  (byte-compile-warn
	   "argument to `domain' declaration must be a literal string: %s"
	   form)
	  (setq domain nil)))
    (setq byte-compile-file-domain domain))
  (byte-compile-keep-pending form 'byte-compile-normal-call))

(defun byte-compile-domain (form)
  (byte-compile-warn "The `domain' declaration is legal only at top-level: %s"
		     (let ((print-escape-newlines t)
			   (print-level 4)
			   (print-length 4))
		       (prin1-to-string form)))
  (byte-compile-normal-call
   (list 'signal ''error
	 (list 'quote (list "`domain' used inside a function" form)))))

;; This is part of bytecomp.el in 19.35:
(put 'custom-declare-variable 'byte-hunk-handler
     'byte-compile-file-form-custom-declare-variable)
(defun byte-compile-file-form-custom-declare-variable (form)
  ;; XEmacs change; our implementation byte compiles and gives warnings
  ;; about the default value code, which GNU's doesn't.
  (let* ((quoted-default (car-safe (cdr-safe (cdr-safe form))))
         (to-examine (car-safe (cdr-safe quoted-default))))
    (if (memq 'free-vars byte-compile-warnings)
        (setq byte-compile-bound-variables
              (cons (cons (nth 1 (nth 1 form))
                          byte-compile-global-bit)
                    byte-compile-bound-variables)))
    ;; Byte compile anything that smells like a lambda. I initially
    ;; considered limiting it to the :initialize, :set and :get args, but
    ;; that's not amazingly forward-compatible, and anyone expecting other
    ;; things to be stored as data, not code, is unrealistic. 
     (loop
       for entry in-ref (nthcdr 4 form)
       do (cond ((and (eq 'function (car-safe entry))
                      (consp (car-safe (cdr-safe entry))))
                 (setf entry (copy-sequence entry))
                 (setcar (cdr entry) (byte-compile-lambda (car (cdr entry)))))
                ((and (eq 'lambda (car-safe entry)))
                 (setf entry (byte-compile-lambda entry)))))
     ;; Byte compile the default value, as we do for defvar. 
     (when (consp (cdr-safe to-examine))
       (setq form (copy-sequence form))
       (setcdr (third form)
               (list (byte-compile-top-level to-examine nil 'file)))
       ;; And save a value to be examined in the custom UI, if that differs
       ;; from the init value.
       (unless (equal to-examine (car-safe (cdr (third form))))
         (setcdr (third form)
                 (list (byte-compile-top-level 
                        ;; This is ugly. custom-declare-variable errors if
                        ;; it's passed a keyword it doesn't know about, and
                        ;; so to make this code run on 21.4, we add code to
                        ;; modify the standard-value property to the
                        ;; byte-compiled value for DEFAULT.
                        `(prog2 (put ,(second form) 'standard-value
                                     '(,to-examine))
                          ,to-examine)
                        nil 'file)))))
    form))

;;;###autoload
(defun byte-compile (form)
  "If FORM is a symbol, byte-compile its function definition.
If FORM is a lambda or a macro, byte-compile it as a function."
  (displaying-byte-compile-warnings
   (byte-compile-close-variables
    (let* ((fun (if (symbolp form)
		    (and (fboundp form) (symbol-function form))
		  form))
	   (macro (eq (car-safe fun) 'macro)))
      (if macro
	  (setq fun (cdr fun)))
      (cond ((eq (car-safe fun) 'lambda)
	     (setq fun (if macro
			   (cons 'macro (byte-compile-lambda fun))
			 (byte-compile-lambda fun)))
	     (if (symbolp form)
		 (defalias form fun)
	       fun)))))))

;;;###autoload
(defun byte-compile-sexp (sexp &optional msg)
  "Compile and return SEXP."
  (displaying-byte-compile-warnings
   (byte-compile-close-variables
    (prog1
	(byte-compile-top-level sexp)
      (byte-compile-warn-about-unresolved-functions msg)))))

;; Given a function made by byte-compile-lambda, make a form which produces it.
(defun byte-compile-byte-code-maker (fun)
  (cond
   ;; ## atom is faster than compiled-func-p.
   ((atom fun)				; compiled-function-p
    fun)
   ;; b-c-lambda didn't produce a compiled-function, so it must be a trivial
   ;; function.
   ((let (tmp)
      (if (and (setq tmp (assq 'byte-code (cdr-safe (cdr fun))))
	       (null (cdr (memq tmp fun))))
	  ;; Generate a make-byte-code call.
	  (let* ((interactive (assq 'interactive (cdr (cdr fun)))))
	    (nconc (list 'make-byte-code
			 (list 'quote (nth 1 fun)) ;arglist
			 (nth 1 tmp)	;instructions
			 (nth 2 tmp)	;constants
			 (nth 3 tmp))	;stack-depth
		   (cond ((stringp (nth 2 fun))
			  (list (nth 2 fun))) ;docstring
			 (interactive
			  (list nil)))
		   (cond (interactive
			  (list (if (or (null (nth 1 interactive))
					(stringp (nth 1 interactive)))
				    (nth 1 interactive)
				  ;; Interactive spec is a list or a variable
				  ;; (if it is correct).
				  (list 'quote (nth 1 interactive))))))))
	;; a non-compiled function (probably trivial)
	(list 'quote fun))))))

;; Byte-compile a lambda-expression and return a valid function.
;; The value is usually a compiled function but may be the original
;; lambda-expression.
(defun byte-compile-lambda (fun &optional name)
  (or (eq 'lambda (car-safe fun))
      (error "not a lambda -- %s" (prin1-to-string fun)))
  (let* ((byte-compile-current-form (or name byte-compile-current-form))
         (arglist (nth 1 fun))
	 (byte-compile-bound-variables
	  (let ((new-bindings
		 (mapcar #'(lambda (x) (cons x byte-compile-arglist-bit))
			 (and (memq 'free-vars byte-compile-warnings)
			      (delq '&rest (delq '&optional
						 (copy-sequence arglist)))))))
	    (nconc new-bindings
		   (cons 'new-scope byte-compile-bound-variables))))
	 (body (cdr (cdr fun)))
	 (doc (if (stringp (car body))
		  (prog1 (car body)
		    ;; Discard the doc string
		    ;; only if it is not the only element of the body.
		    (if (cdr body)
			(setq body (cdr body))))))
	 (int (assq 'interactive body)) compiled-int)
    (dolist (arg arglist)
      (cond ((not (symbolp arg))
	     (byte-compile-warn "non-symbol in arglist: %S" arg))
	    ((byte-compile-constant-symbol-p arg)
	     (byte-compile-warn "constant symbol in arglist: %s" arg))
	    ((and (char= ?\& (aref (symbol-name arg) 0))
		  (not (eq arg '&optional))
		  (not (eq arg '&rest)))
	     (byte-compile-warn "unrecognized `&' keyword in arglist: %s"
				arg))))
    (cond (int
	   ;; Skip (interactive) if it is in front (the most usual location).
	   (if (eq int (car body))
	       (setq body (cdr body)))
	   (cond ((consp (cdr int))
		  (if (cdr (cdr int))
		      (byte-compile-warn "malformed interactive spec: %s"
					 (prin1-to-string int)))
		  ;; If the interactive spec is a call to `list', don't
		  ;; store the compiled form, because `call-interactively'
		  ;; looks at the args of `list' and treats certain
		  ;; functions specially.  Compiling it is nonetheless
		  ;; useful for warnings.
		  (let ((form (nth 1 int)))
		    (while (or (eq (car-safe form) 'let)
			       (eq (car-safe form) 'let*)
			       (eq (car-safe form) 'save-excursion))
		      (while (consp (cdr form))
			(setq form (cdr form)))
		      (setq form (car form)))
		    (setq compiled-int 
			  (byte-compile-top-level (nth 1 int)))
		    (or (eq (car-safe form) 'list)
			(setq int (list 'interactive compiled-int)))))
		 ((cdr int)
		  (byte-compile-warn "malformed interactive spec: %s"
				     (prin1-to-string int))))))
    (let ((compiled (byte-compile-top-level (cons 'progn body) nil 'lambda)))
      (if (memq 'unused-vars byte-compile-warnings)
	  ;; done compiling in this scope, warn now.
	  (byte-compile-warn-about-unused-variables))
      (if (eq 'byte-code (car-safe compiled))
	  (apply 'make-byte-code
		 (append (list arglist)
			 ;; byte-string, constants-vector, stack depth
			 (cdr compiled)
			 ;; optionally, the doc string.
			 (if (or doc int)
			     (list doc))
			 ;; optionally, the interactive spec.
			 (if int
			     (list (nth 1 int)))))
	(setq compiled
	      (nconc (if int (list int))
		     (cond ((eq (car-safe compiled) 'progn) (cdr compiled))
			   (compiled (list compiled)))))
	(nconc (list 'lambda arglist)
	       (if (or doc (stringp (car compiled)))
		   (cons doc (cond (compiled)
				   (body (list nil))))
		 compiled))))))

(defun byte-compile-constants-vector ()
  ;; Builds the constants-vector from the current variables and constants.
  ;;   This modifies the constants from (const . nil) to (const . offset).
  ;; To keep the byte-codes to look up the vector as short as possible:
  ;;   First 6 elements are vars, as there are one-byte varref codes for those.
  ;;   Next up to byte-constant-limit are constants, still with one-byte codes.
  ;;   Next variables again, to get 2-byte codes for variable lookup.
  ;;   The rest of the constants and variables need 3-byte byte-codes.
  (let* ((i -1)
	 (rest (nreverse byte-compile-variables)) ; nreverse because the first
	 (other (nreverse byte-compile-constants)) ; vars often are used most.
	 ret tmp
	 (limits '(5			; Use the 1-byte varref codes,
		   63  ; 1-constlim	;  1-byte byte-constant codes,
		   255			;  2-byte varref codes,
		   65535))		;  3-byte codes for the rest.
	 limit)
    (while (or rest other)
      (setq limit (car limits))
      (while (and rest (not (eq i limit)))
	(if (setq tmp (assq (car (car rest)) ret))
	    (setcdr (car rest) (cdr tmp))
	  (setcdr (car rest) (setq i (1+ i)))
	  (setq ret (cons (car rest) ret)))
	(setq rest (cdr rest)))
      (setq limits (cdr limits)
	    rest (prog1 other
		   (setq other rest))))
    (apply 'vector (nreverse (mapcar 'car ret)))))

;; Given an expression FORM, compile it and return an equivalent byte-code
;; expression (a call to the function byte-code).
(defun byte-compile-top-level (form &optional for-effect output-type)
  ;; OUTPUT-TYPE advises about how form is expected to be used:
  ;;	'eval or nil	-> a single form,
  ;;	'progn or t	-> a list of forms,
  ;;	'lambda		-> body of a lambda,
  ;;	'file		-> used at file-level.
  (let ((byte-compile-constants nil)
	(byte-compile-variables nil)
	(byte-compile-tag-number 0)
	(byte-compile-depth 0)
	(byte-compile-maxdepth 0)
	(byte-compile-output nil))
    (if (memq byte-optimize '(t source))
	(setq form (byte-optimize-form form for-effect)))
    (while (and (eq (car-safe form) 'progn) (null (cdr (cdr form))))
      (setq form (nth 1 form)))
    (if (and (eq 'byte-code (car-safe form))
	     (not (memq byte-optimize '(t byte)))
	     (stringp (nth 1 form))
	     (vectorp (nth 2 form))
	     (natnump (nth 3 form)))
	form
      (byte-compile-form form for-effect)
      (byte-compile-out-toplevel for-effect output-type))))

(defun byte-compile-out-toplevel (&optional for-effect output-type)
  (if for-effect
      ;; The stack is empty. Push a value to be returned from (byte-code ..).
      (if (eq (car (car byte-compile-output)) 'byte-discard)
	  (setq byte-compile-output (cdr byte-compile-output))
	(byte-compile-push-constant
	 ;; Push any constant - preferably one which already is used, and
	 ;; a number or symbol - ie not some big sequence.  The return value
	 ;; isn't returned, but it would be a shame if some textually large
	 ;; constant was not optimized away because we chose to return it.
	 (and (not (assq nil byte-compile-constants)) ; Nil is often there.
	      (let ((tmp (reverse byte-compile-constants)))
		(while (and tmp (not (or (symbolp (car (car tmp)))
					 (numberp (car (car tmp))))))
		  (setq tmp (cdr tmp)))
		(car (car tmp)))))))
  (byte-compile-out 'byte-return 0)
  (setq byte-compile-output (nreverse byte-compile-output))
  (if (memq byte-optimize '(t byte))
      (setq byte-compile-output
	    (byte-optimize-lapcode byte-compile-output for-effect)))

  ;; Decompile trivial functions:
  ;; only constants and variables, or a single funcall except in lambdas.
  ;; Except for Lisp_Compiled objects, forms like (foo "hi")
  ;; are still quicker than (byte-code "..." [foo "hi"] 2).
  ;; Note that even (quote foo) must be parsed just as any subr by the
  ;; interpreter, so quote should be compiled into byte-code in some contexts.
  ;; What to leave uncompiled:
  ;;	lambda	-> never.  we used to leave it uncompiled if the body was
  ;;		   a single atom, but that causes confusion if the docstring
  ;;		   uses the (file . pos) syntax.  Besides, now that we have
  ;;		   the Lisp_Compiled type, the compiled form is faster.
  ;;	eval	-> atom, quote or (function atom atom atom)
  ;;	progn	-> as <<same-as-eval>> or (progn <<same-as-eval>> atom)
  ;;	file	-> as progn, but takes both quotes and atoms, and longer forms.
  (let (rest
	(maycall (not (eq output-type 'lambda))) ; t if we may make a funcall.
	tmp body)
    (cond
     ;; #### This should be split out into byte-compile-nontrivial-function-p.
     ((or (eq output-type 'lambda)
	  (nthcdr (if (eq output-type 'file) 50 8) byte-compile-output)
	  (assq 'TAG byte-compile-output) ; Not necessary, but speeds up a bit.
	  (not (setq tmp (assq 'byte-return byte-compile-output)))
	  (progn
	    (setq rest (nreverse
			(cdr (memq tmp (reverse byte-compile-output)))))
	    (while (cond
		    ((memq (car (car rest)) '(byte-varref byte-constant))
		     (setq tmp (car (cdr (car rest))))
		     (if (if (eq (car (car rest)) 'byte-constant)
			     (or (consp tmp)
				 (and (symbolp tmp)
				      (not (byte-compile-constant-symbol-p tmp)))))
			 (if maycall
			     (setq body (cons (list 'quote tmp) body)))
		       (setq body (cons tmp body))))
		    ((and maycall
			  ;; Allow a funcall if at most one atom follows it.
			  (null (nthcdr 3 rest))
			  (setq tmp (get (car (car rest)) 'byte-opcode-invert))
			  (or (null (cdr rest))
			      (and (memq output-type '(file progn t))
				   (cdr (cdr rest))
				   (eq (car (nth 1 rest)) 'byte-discard)
				   (progn (setq rest (cdr rest)) t))))
		     (setq maycall nil)	; Only allow one real function call.
		     (setq body (nreverse body))
		     (setq body (list
				 (if (and (eq tmp 'funcall)
					  (eq (car-safe (car body)) 'quote))
				     (cons (nth 1 (car body)) (cdr body))
				   (cons tmp body))))
		     (or (eq output-type 'file)
			 (not (delq nil (mapcar 'consp (cdr (car body))))))))
	      (setq rest (cdr rest)))
	    rest))
      (let ((byte-compile-vector (byte-compile-constants-vector)))
	(list 'byte-code (byte-compile-lapcode byte-compile-output)
	      byte-compile-vector byte-compile-maxdepth)))
     ;; it's a trivial function
     ((cdr body) (cons 'progn (nreverse body)))
     ((car body)))))

;; Given BODY, compile it and return a new body.
(defun byte-compile-top-level-body (body &optional for-effect)
  (setq body (byte-compile-top-level (cons 'progn body) for-effect t))
  (cond ((eq (car-safe body) 'progn)
	 (cdr body))
	(body
	 (list body))))

;; This is the recursive entry point for compiling each subform of an
;; expression.
;; If for-effect is non-nil, byte-compile-form will output a byte-discard
;; before terminating (ie. no value will be left on the stack).
;; A byte-compile handler may, when for-effect is non-nil, choose output code
;; which does not leave a value on the stack, and then set for-effect to nil
;; (to prevent byte-compile-form from outputting the byte-discard).
;; If a handler wants to call another handler, it should do so via
;; byte-compile-form, or take extreme care to handle for-effect correctly.
;; (Use byte-compile-form-do-effect to reset the for-effect flag too.)
;;
(defun byte-compile-form (form &optional for-effect)
  (setq form (macroexpand form byte-compile-macro-environment))
  (cond ((not (consp form))
	 (cond ((or (not (symbolp form))
		    (byte-compile-constant-symbol-p form))
		(byte-compile-constant form))
	       ((and for-effect byte-compile-delete-errors)
		(setq for-effect nil))
	       (t (byte-compile-variable-ref 'byte-varref form))))
	((symbolp (car form))
	 (let* ((fn (car form))
		(handler (get fn 'byte-compile)))
	   (if (memq fn '(t nil))
	       (byte-compile-warn "%s called as a function" fn))
	   (if handler
	       (funcall handler form)
	     (if (memq 'callargs byte-compile-warnings)
		 (byte-compile-callargs-warn form))
	     (byte-compile-normal-call form))))
	((and (or (compiled-function-p (car form))
		  (eq (car-safe (car form)) 'lambda))
	      ;; if the form comes out the same way it went in, that's
	      ;; because it was malformed, and we couldn't unfold it.
	      (not (eq form (setq form (byte-compile-unfold-lambda form)))))
	 (byte-compile-form form for-effect)
	 (setq for-effect nil))
	((byte-compile-normal-call form)))
  (when for-effect
    (byte-compile-discard)))

;; Generate the list of functions with keyword arguments like so:
;; 
;; (delete-duplicates
;;  (sort*
;;   (loop
;;     for symbol being each symbol in obarray
;;     with arglist = nil
;;     if (and (fboundp symbol)
;; 	    (ignore-errors (setq symbol (indirect-function symbol)))
;; 	    (cond
;; 	     ((and (subrp symbol) (setq symbol (intern (subr-name symbol)))))
;; 	     ((and (compiled-function-p symbol)
;; 		   (setq symbol (compiled-function-annotation symbol)))))
;; 	    (setq arglist (function-arglist symbol))
;; 	    (setq arglist (ignore-errors (read-from-string arglist)))
;; 	    (setq arglist (car arglist))
;; 	    (setq arglist (position '&key arglist)))
;;     collect (cons symbol arglist))
;;   #'string-lessp
;;   :key #'car) :test #'eq :key #'car)
;;
;; That won't include those that take advantage of cl-seq.el's
;; cl-parsing-keywords macro, but the below list does.

(map nil
     (function*
      (lambda ((function . nargs))
	;; Document that the car of OBJECT, a symbol, describes a function
	;; taking keyword arguments from the argument index described by
	;; the cdr of OBJECT.
	(put function 'byte-compile-keyword-start nargs)))
     '((adjoin . 3) (assoc* . 3) (assoc-if . 3) (assoc-if-not . 3)
       (count . 3) (count-if . 3) (count-if-not . 3) (define-behavior . 3)
       (define-behavior-group . 2) (delete* . 3) (delete-duplicates . 2)
       (delete-if . 3) (delete-if-not . 3) (fill . 3) (find . 3) (find-if . 3)
       (find-if-not . 3) (internal-make-translation-table . 1)
       (make-Print-context . 1) (make-hash-table . 1) (make-saved-window . 1)
       (make-window-configuration . 1) (member* . 3)
       (member-if . 3) (member-if-not . 3) (merge . 5) (nsublis . 3)
       (nsubst . 4) (nsubst-if . 4) (nsubst-if-not . 4) (nsubstitute . 4)
       (nsubstitute-if . 4) (nsubstitute-if-not . 4) (override-behavior . 2)
       (position . 3) (position-if . 3) (position-if-not . 3) (rassoc* . 3)
       (rassoc-if . 3) (rassoc-if-not . 3) (reduce . 3) (remove* . 3)
       (remove-duplicates . 2) (remove-if . 3) (remove-if-not . 3)
       (replace . 3) (sort* . 3) (stable-sort . 3) (sublis . 3)
       (subsetp . 3) (subst . 4) (subst-if . 4) (subst-if-not . 4)
       (substitute . 4) (substitute-if . 4) (substitute-if-not . 4)
       (tree-equal . 3)))

(defun byte-compile-normal-call (form)
  (and (symbolp (car form)) (get (car form) 'byte-compile-keyword-start)
       (let ((plist (nthcdr (get (car form) 'byte-compile-keyword-start)
			    form)))
	 (symbol-macrolet
	     ((not-present '#:not-present))
	   (if (not (valid-plist-p plist))
	       (byte-compile-warn
		"#'%s: ill-formed keyword argument list: %S" (car form) plist)
	     (and
	      (memq 'callargs byte-compile-warnings)
	      (map nil
		   (function*
		    (lambda ((function . nargs))
                      (let ((value (plist-get plist function not-present)))
                        (when (and (not (eq value not-present))
                                   (byte-compile-constp value))
                          (byte-compile-callargs-warn
                           (cons (eval value)
                                 (member*
                                  nargs
                                  ;; Dummy arguments. There's no need for
                                  ;; it to be longer than even 2, now, but
                                  ;; very little harm in it.
                                  '(9 8 7 6 5 4 3 2 1))))
                          (when (and (eq (car-safe value) 'quote)
                                     (eq (car-safe (nth 1 value)) 'lambda)
                                     (or
                                      (null (memq 'quoted-lambda
                                                  byte-compile-warnings))
                                      (byte-compile-warn
                                       "Passing a quoted lambda to #'%s, \
keyword %s, forcing function quoting" (car form) function)))
                            (setcar value 'function))))))
                   '((:key . 1) (:test . 2) (:test-not . 2) (:if . 1)
                     (:if-not . 1))))))))
  (if byte-compile-generate-call-tree
      (byte-compile-annotate-call-tree form))
  (byte-compile-push-constant (car form))
  (mapc 'byte-compile-form (cdr form)) ; wasteful, but faster.
  (byte-compile-out 'byte-call (length (cdr form))))

;; kludge added to XEmacs to work around the bogosities of a nonlexical lisp.
(or (fboundp 'globally-boundp) (fset 'globally-boundp 'boundp))

(defun byte-compile-variable-ref (base-op var &optional varbind-flags)
  (if (or (not (symbolp var)) (byte-compile-constant-symbol-p var))
      (byte-compile-warn
       (case base-op
	 (byte-varref "Variable reference to %s %s")
	 (byte-varset "Attempt to set %s %s")
	 (byte-varbind "Attempt to let-bind %s %s"))
       (if (symbolp var) "constant symbol" "non-symbol")
       var)
    (if (and (get var 'byte-obsolete-variable)
	     (memq 'obsolete byte-compile-warnings))
	(let ((ob (get var 'byte-obsolete-variable)))
	  (byte-compile-warn "%s is an obsolete variable; %s" var
			     (if (stringp ob)
				 ob
			       (format "use %s instead." ob)))))
    (if (and (get var 'byte-compatible-variable)
	     (memq 'pedantic byte-compile-warnings))
	(let ((ob (get var 'byte-compatible-variable)))
	  (byte-compile-warn "%s is provided for compatibility; %s" var
			     (if (stringp ob)
				 ob
			       (format "use %s instead." ob)))))
    (if (memq 'free-vars byte-compile-warnings)
	(if (eq base-op 'byte-varbind)
	    (setq byte-compile-bound-variables
		  (cons (cons var (or varbind-flags 0))
			byte-compile-bound-variables))
	  (or (globally-boundp var)
	      (let ((cell (assq var byte-compile-bound-variables)))
		(if cell (setcdr cell
				 (logior (cdr cell)
					 (if (eq base-op 'byte-varset)
					     byte-compile-assigned-bit
					   byte-compile-referenced-bit)))))
	      (and (boundp 'current-load-list)
		   (memq var current-load-list))
	      (if (eq base-op 'byte-varset)
		  (or (memq var byte-compile-free-assignments)
		      (progn
			(byte-compile-warn "assignment to free variable %s"
					   var)
			(setq byte-compile-free-assignments
			      (cons var byte-compile-free-assignments))))
		(or (memq var byte-compile-free-references)
		    (progn
		      (byte-compile-warn "reference to free variable %s" var)
		      (setq byte-compile-free-references
			    (cons var byte-compile-free-references)))))))))
  (let ((tmp (assq var byte-compile-variables)))
    (or tmp
	(setq tmp (list var)
	      byte-compile-variables (cons tmp byte-compile-variables)))
    (byte-compile-out base-op tmp)))

(defmacro byte-compile-get-constant (const)
  `(or (if (stringp ,const)
	   (assoc ,const byte-compile-constants)
	 (assq ,const byte-compile-constants))
       (car (setq byte-compile-constants
		  (cons (list ,const) byte-compile-constants)))))

;; Use this when the value of a form is a constant.  This obeys for-effect.
(defun byte-compile-constant (const)
  (if for-effect
      (setq for-effect nil)
    (byte-compile-out 'byte-constant (byte-compile-get-constant const))))

;; Use this for a constant that is not the value of its containing form.
;; This ignores for-effect.
(defun byte-compile-push-constant (const)
  (let ((for-effect nil))
    (inline (byte-compile-constant const))))


;; Compile those primitive ordinary functions
;; which have special byte codes just for speed.

(defmacro byte-defop-compiler (function &optional compile-handler)
  ;; add a compiler-form for FUNCTION.
  ;; If FUNCTION is a symbol, then the variable "byte-SYMBOL" must name
  ;; the opcode to be used.  If is a list, the first element
  ;; is the function and the second element is the bytecode-symbol.
  ;; COMPILE-HANDLER is the function to use to compile this byte-op, or
  ;; may be the abbreviations 0, 1, 2, 3, 0-1, 1-2, 2-3, 0+1, 1+1, 2+1,
  ;; 0-1+1, 1-2+1, 2-3+1, 0+2, or 1+2.  If it is nil, then the handler is
  ;; "byte-compile-SYMBOL."
  (let (opcode)
    (if (symbolp function)
	(setq opcode (intern (concat "byte-" (symbol-name function))))
      (setq opcode (car (cdr function))
	    function (car function)))
    (let ((fnform
	   (list 'put (list 'quote function) ''byte-compile
		 (list 'quote
		       (or (cdr (assq compile-handler
				      '((0 . byte-compile-no-args)
					(1 . byte-compile-one-arg)
					(2 . byte-compile-two-args)
					(3 . byte-compile-three-args)
					(0-1 . byte-compile-zero-or-one-arg)
					(1-2 . byte-compile-one-or-two-args)
					(2-3 . byte-compile-two-or-three-args)
					(0+1 . byte-compile-no-args-with-one-extra)
					(1+1 . byte-compile-one-arg-with-one-extra)
					(2+1 . byte-compile-two-args-with-one-extra)
					(0-1+1 . byte-compile-zero-or-one-arg-with-one-extra)
					(1-2+1 . byte-compile-one-or-two-args-with-one-extra)
					(2-3+1 . byte-compile-two-or-three-args-with-one-extra)
					(0+2 . byte-compile-no-args-with-two-extra)
					(1+2 . byte-compile-one-arg-with-two-extra)

					)))
			   compile-handler
			   (intern (concat "byte-compile-"
					   (symbol-name function))))))))
      (if opcode
	  (list 'progn fnform
		(list 'put (list 'quote function)
		      ''byte-opcode (list 'quote opcode))
		(list 'put (list 'quote opcode)
		      ''byte-opcode-invert (list 'quote function)))
	fnform))))

(defmacro byte-defop-compiler-1 (function &optional compile-handler)
  (list 'byte-defop-compiler (list function nil) compile-handler))


(put 'byte-call 'byte-opcode-invert 'funcall)
(put 'byte-list1 'byte-opcode-invert 'list)
(put 'byte-list2 'byte-opcode-invert 'list)
(put 'byte-list3 'byte-opcode-invert 'list)
(put 'byte-list4 'byte-opcode-invert 'list)
(put 'byte-listN 'byte-opcode-invert 'list)
(put 'byte-concat2 'byte-opcode-invert 'concat)
(put 'byte-concat3 'byte-opcode-invert 'concat)
(put 'byte-concat4 'byte-opcode-invert 'concat)
(put 'byte-concatN 'byte-opcode-invert 'concat)
(put 'byte-insertN 'byte-opcode-invert 'insert)

;; How old is this stuff? -slb
;(byte-defop-compiler (dot byte-point)		0+1)
;(byte-defop-compiler (dot-max byte-point-max)	0+1)
;(byte-defop-compiler (dot-min byte-point-min)	0+1)
(byte-defop-compiler point		0+1)
(byte-defop-compiler eq		2)
(byte-defop-compiler point-max		0+1)
(byte-defop-compiler point-min		0+1)
(byte-defop-compiler following-char	0+1)
(byte-defop-compiler preceding-char	0+1)
(byte-defop-compiler current-column	0+1)
;; FSF has special function here; generalized here by the 1+2 stuff.
(byte-defop-compiler (indent-to-column byte-indent-to) 1+2)
(byte-defop-compiler indent-to		1+2)
(byte-defop-compiler equal	2)
(byte-defop-compiler eolp		0+1)
(byte-defop-compiler eobp		0+1)
(byte-defop-compiler bolp		0+1)
(byte-defop-compiler bobp		0+1)
(byte-defop-compiler current-buffer	0)
;;(byte-defop-compiler read-char	0) ;; obsolete
(byte-defop-compiler memq	2)
(byte-defop-compiler interactive-p	0)
(byte-defop-compiler widen		0+1)
(byte-defop-compiler end-of-line	0-1+1)
(byte-defop-compiler forward-char	0-1+1)
(byte-defop-compiler forward-line	0-1+1)
(byte-defop-compiler symbolp		1)
(byte-defop-compiler consp		1)
(byte-defop-compiler stringp		1)
(byte-defop-compiler listp		1)
(byte-defop-compiler not		1)
(byte-defop-compiler (null byte-not)	1)
(byte-defop-compiler car		1)
(byte-defop-compiler cdr		1)
(byte-defop-compiler length		1)
(byte-defop-compiler symbol-value       1)
(byte-defop-compiler symbol-function	1)
(byte-defop-compiler (1+ byte-add1)	1)
(byte-defop-compiler (1- byte-sub1)	1)
(byte-defop-compiler goto-char		1+1)
(byte-defop-compiler char-after		0-1+1)
(byte-defop-compiler set-buffer		1)
;;(byte-defop-compiler set-mark		1) ;; obsolete
(byte-defop-compiler forward-word	0-1+1)
(byte-defop-compiler char-syntax	1+1)
(byte-defop-compiler nreverse		1)
(byte-defop-compiler car-safe		1)
(byte-defop-compiler cdr-safe		1)
(byte-defop-compiler numberp		1)
(byte-defop-compiler fixnump		1)
(byte-defop-compiler skip-chars-forward     1-2+1)
(byte-defop-compiler skip-chars-backward    1-2+1)
(byte-defop-compiler eq			2)
; (byte-defop-compiler old-eq 	 	2)
; (byte-defop-compiler old-memq		2)
(byte-defop-compiler cons		2)
(byte-defop-compiler aref		2)
(byte-defop-compiler get		2+1)
(byte-defop-compiler nth		2)
(byte-defop-compiler subseq byte-compile-subseq)
(byte-defop-compiler (substring byte-subseq) 2-3)
(byte-defop-compiler (move-marker byte-set-marker) 2-3)
(byte-defop-compiler set-marker		2-3)
(byte-defop-compiler match-beginning	1)
(byte-defop-compiler match-end		1)
(byte-defop-compiler upcase		1+1)
(byte-defop-compiler downcase		1+1)
(byte-defop-compiler string=		2)
(byte-defop-compiler string<		2)
(byte-defop-compiler (string-equal byte-string=) 2)
(byte-defop-compiler (string-lessp byte-string<) 2)
; (byte-defop-compiler old-equal	2)
(byte-defop-compiler nthcdr		2)
(byte-defop-compiler elt		2)
(byte-defop-compiler old-member	2)
(byte-defop-compiler old-assq		2)
(byte-defop-compiler (rplaca byte-setcar) 2)
(byte-defop-compiler (rplacd byte-setcdr) 2)
(byte-defop-compiler setcar		2)
(byte-defop-compiler setcdr		2)
(byte-defop-compiler delete-region	2+1)
(byte-defop-compiler narrow-to-region	2+1)
(byte-defop-compiler (% byte-rem)	2)
(byte-defop-compiler aset		3)

(byte-defop-compiler-1 bind-multiple-value-limits)
(byte-defop-compiler multiple-value-list-internal)
(byte-defop-compiler-1 multiple-value-call)
(byte-defop-compiler throw)

(byte-defop-compiler member	2)
(byte-defop-compiler assq	2)

;;####(byte-defop-compiler move-to-column	1)
(byte-defop-compiler-1 interactive byte-compile-noop)
(byte-defop-compiler-1 domain byte-compile-domain)

;; As of GNU Emacs 19.18 and Lucid Emacs 19.8, mod and % are different: `%'
;; means integral remainder and may have a negative result; `mod' is always
;; positive, and accepts floating point args.  All code which uses `mod' and
;; requires the new interpretation must be compiled with bytecomp version 2.18
;; or newer, or the emitted code will run the byte-code for `%' instead of an
;; actual call to `mod'.  So be careful of compiling new code with an old
;; compiler.  Note also that `%' is more efficient than `mod' because the
;; former is byte-coded and the latter is not.
;;(byte-defop-compiler (mod byte-rem) 2)


(defun byte-compile-warn-wrong-args (form n)
  (when (memq 'subr-callargs byte-compile-warnings)
    (byte-compile-warn "%s called with %d arg%s, but requires %s"
		       (car form) (length (cdr form))
		       (if (eql 1 (length (cdr form))) "" "s") n)))

(defun byte-compile-subr-wrong-args (form n)
  (byte-compile-warn-wrong-args form n)
  ;; get run-time wrong-number-of-args error.
  (byte-compile-normal-call form))

(defun byte-compile-no-args (form)
  (case (length (cdr form))
    (0 (byte-compile-out (get (car form) 'byte-opcode) 0))
    (t (byte-compile-subr-wrong-args form "none"))))

(defun byte-compile-one-arg (form)
  (case (length (cdr form))
    (1 (byte-compile-form (car (cdr form)))  ;; Push the argument
       (byte-compile-out (get (car form) 'byte-opcode) 0))
    (t (byte-compile-subr-wrong-args form 1))))

(defun byte-compile-two-args (form)
  (case (length (cdr form))
    (2 (byte-compile-form (nth 1 form))  ;; Push the arguments
       (byte-compile-form (nth 2 form))
       (byte-compile-out (get (car form) 'byte-opcode) 0))
    (t (byte-compile-subr-wrong-args form 2))))

(defun byte-compile-three-args (form)
  (case (length (cdr form))
    (3 (byte-compile-form (nth 1 form))  ;; Push the arguments
       (byte-compile-form (nth 2 form))
       (byte-compile-form (nth 3 form))
       (byte-compile-out (get (car form) 'byte-opcode) 0))
    (t (byte-compile-subr-wrong-args form 3))))

(defun byte-compile-zero-or-one-arg (form)
  (case (length (cdr form))
    (0 (byte-compile-one-arg (append form '(nil))))
    (1 (byte-compile-one-arg form))
    (t (byte-compile-subr-wrong-args form "0-1"))))

(defun byte-compile-one-or-two-args (form)
  (case (length (cdr form))
    (1 (byte-compile-two-args (append form '(nil))))
    (2 (byte-compile-two-args form))
    (t (byte-compile-subr-wrong-args form "1-2"))))

(defun byte-compile-two-or-three-args (form)
  (case (length (cdr form))
    (2 (byte-compile-three-args (append form '(nil))))
    (3 (byte-compile-three-args form))
    (t (byte-compile-subr-wrong-args form "2-3"))))

;; from Ben Wing <ben@xemacs.org>: some inlined functions have extra
;; optional args added to them in XEmacs 19.12.  Changing the byte
;; interpreter to deal with these args would be wrong and cause
;; incompatibility, so we generate non-inlined calls for those cases.
;; Without the following functions, spurious warnings will be generated;
;; however, they would still compile correctly because
;; `byte-compile-subr-wrong-args' also converts the call to non-inlined.

(defun byte-compile-no-args-with-one-extra (form)
  (case (length (cdr form))
    (0 (byte-compile-no-args form))
    (1 (if (eq nil (nth 1 form))
	   (byte-compile-no-args (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "0-1"))))

(defun byte-compile-one-arg-with-one-extra (form)
  (case (length (cdr form))
    (1 (byte-compile-one-arg form))
    (2 (if (eq nil (nth 2 form))
	   (byte-compile-one-arg (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "1-2"))))

(defun byte-compile-two-args-with-one-extra (form)
  (case (length (cdr form))
    (2 (byte-compile-two-args form))
    (3 (if (eq nil (nth 3 form))
	   (byte-compile-two-args (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "2-3"))))

(defun byte-compile-zero-or-one-arg-with-one-extra (form)
  (case (length (cdr form))
    (0 (byte-compile-one-arg (append form '(nil))))
    (1 (byte-compile-one-arg form))
    (2 (if (eq nil (nth 2 form))
	   (byte-compile-one-arg (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "0-2"))))

(defun byte-compile-one-or-two-args-with-one-extra (form)
  (case (length (cdr form))
    (1 (byte-compile-two-args (append form '(nil))))
    (2 (byte-compile-two-args form))
    (3 (if (eq nil (nth 3 form))
	   (byte-compile-two-args (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "1-3"))))

(defun byte-compile-two-or-three-args-with-one-extra (form)
  (case (length (cdr form))
    (2 (byte-compile-three-args (append form '(nil))))
    (3 (byte-compile-three-args form))
    (4 (if (eq nil (nth 4 form))
	   (byte-compile-three-args (butlast form))
	 (byte-compile-normal-call form)))
    (t (byte-compile-subr-wrong-args form "2-4"))))

(defun byte-compile-no-args-with-two-extra (form)
  (case (length (cdr form))
    (0     (byte-compile-no-args form))
    ((1 2) (byte-compile-normal-call form))
    (t     (byte-compile-subr-wrong-args form "0-2"))))

(defun byte-compile-one-arg-with-two-extra (form)
  (case (length (cdr form))
    (1     (byte-compile-one-arg form))
    ((2 3) (byte-compile-normal-call form))
    (t     (byte-compile-subr-wrong-args form "1-3"))))

(defun byte-compile-noop (form)
  (byte-compile-constant nil))

(defun byte-compile-discard ()
  (byte-compile-out 'byte-discard 0))

(defun byte-compile-max (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-subr-wrong-args form "1 or more"))
      (1 (byte-compile-form (car args))
	 (when (not byte-compile-delete-errors)
	   (byte-compile-out 'byte-dup 0)
	   (byte-compile-out 'byte-max 0)))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (byte-compile-form elt)
	   (byte-compile-out 'byte-max 0))))))

(defun byte-compile-min (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-subr-wrong-args form "1 or more"))
      (1 (byte-compile-form (car args))
	 (when (not byte-compile-delete-errors)
	   (byte-compile-out 'byte-dup 0)
	   (byte-compile-out 'byte-min 0)))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (byte-compile-form elt)
	   (byte-compile-out 'byte-min 0))))))


;; more complicated compiler macros

(byte-defop-compiler list)
(byte-defop-compiler concat)
(byte-defop-compiler fset)
(byte-defop-compiler insert)
(byte-defop-compiler-1 function byte-compile-function-form)
(byte-defop-compiler max)
(byte-defop-compiler min)
(byte-defop-compiler (+ byte-plus)	byte-compile-plus)
(byte-defop-compiler-1 -		byte-compile-minus)
(byte-defop-compiler (* byte-mult)	byte-compile-mult)
(byte-defop-compiler (/ byte-quo)	byte-compile-quo)
(byte-defop-compiler nconc)
(byte-defop-compiler-1 beginning-of-line)

(byte-defop-compiler (=  byte-eqlsign)	byte-compile-arithcompare)
(byte-defop-compiler (<  byte-lss)	byte-compile-arithcompare)
(byte-defop-compiler (>  byte-gtr)	byte-compile-arithcompare)
(byte-defop-compiler (<= byte-leq)	byte-compile-arithcompare)
(byte-defop-compiler (>= byte-geq)	byte-compile-arithcompare)

(defun byte-compile-arithcompare (form)
  (case (length (cdr form))
    (0 (byte-compile-subr-wrong-args form "1 or more"))
    (1 (if byte-compile-delete-errors
	   (byte-compile-constant t)
	 (byte-compile-normal-call form)))
    (2 (byte-compile-two-args form))
    (t (byte-compile-normal-call form))))

(byte-defop-compiler /= byte-compile-/=)

(defun byte-compile-/= (form)
  (case (length (cdr form))
    (0 (byte-compile-subr-wrong-args form "1 or more"))
    (1 (byte-compile-constant t))
    ;; optimize (/= X Y) to (not (= X Y))
    (2 (byte-compile-form-do-effect `(not (= ,@(cdr form)))))
    (t (byte-compile-normal-call form))))

;; buffer-substring now has its own function.  This used to be
;; 2+1, but now all args are optional.
(byte-defop-compiler buffer-substring)

(defun byte-compile-buffer-substring (form)
  ;; buffer-substring used to take exactly two args, but now takes 0-3.
  ;; convert 0-2 to two args and use special bytecode operand.
  ;; convert 3 args to a normal call.
  (case (length (cdr form))
    (0 (byte-compile-two-args (append form '(nil nil))))
    (1 (byte-compile-two-args (append form '(nil))))
    (2 (byte-compile-two-args form))
    (3 (byte-compile-normal-call form))
    (t (byte-compile-subr-wrong-args form "0-3"))))

(defun byte-compile-list (form)
  (let* ((args (cdr form))
	 (nargs (length args)))
    (cond
     ((eql nargs 0)
      (byte-compile-constant nil))
     ((< nargs 5)
      (mapc 'byte-compile-form args)
      (byte-compile-out
       (aref [byte-list1 byte-list2 byte-list3 byte-list4] (1- nargs))
       0))
     ((< nargs 256)
      (mapc 'byte-compile-form args)
      (byte-compile-out 'byte-listN nargs))
     (t (byte-compile-normal-call form)))))

(defun byte-compile-concat (form)
  (let* ((args (cdr form))
	 (nargs (length args)))
    ;; Concat of one arg is not a no-op if arg is not a string.
    (cond
     ((memq nargs '(2 3 4))
      (mapc 'byte-compile-form args)
      (byte-compile-out
       (aref [byte-concat2 byte-concat3 byte-concat4] (- nargs 2))
       0))
     ((eq nargs 0)
      (byte-compile-form ""))
     ((< nargs 256)
      (mapc 'byte-compile-form args)
      (byte-compile-out 'byte-concatN nargs))
     ((byte-compile-normal-call form)))))

(defun byte-compile-plus (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-constant 0))
      (1 (byte-compile-plus (append form '(0))))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (case elt
	     (0  (when (not byte-compile-delete-errors)
		   (byte-compile-constant 0)
		   (byte-compile-out 'byte-plus 0)))
	     (+1 (byte-compile-out 'byte-add1 0))
	     (-1 (byte-compile-out 'byte-sub1 0))
	     (t
	      (byte-compile-form elt)
	      (byte-compile-out 'byte-plus 0))))))))

(defun byte-compile-minus (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-subr-wrong-args form "1 or more"))
      (1 (byte-compile-form (car args))
	 (byte-compile-out 'byte-negate 0))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (case elt
	     (0  (when (not byte-compile-delete-errors)
		   (byte-compile-constant 0)
		   (byte-compile-out 'byte-diff 0)))
	     (+1 (byte-compile-out 'byte-sub1 0))
	     (-1 (byte-compile-out 'byte-add1 0))
	     (t
	      (byte-compile-form elt)
	      (byte-compile-out 'byte-diff 0))))))))

(defun byte-compile-mult (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-constant 1))
      (1 (byte-compile-mult (append form '(1))))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (case elt
	     (1  (when (not byte-compile-delete-errors)
		   (byte-compile-constant 1)
		   (byte-compile-out 'byte-mult 0)))
	     (-1 (byte-compile-out 'byte-negate 0))
	     (2  (byte-compile-out 'byte-dup 0)
		 (byte-compile-out 'byte-plus 0))
	     (t
	      (byte-compile-form elt)
	      (byte-compile-out 'byte-mult 0))))))))

(defun byte-compile-quo (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-subr-wrong-args form "1 or more"))
      (1 (byte-compile-constant 1)
	 (byte-compile-form (car args))
	 (byte-compile-out 'byte-quo 0))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (case elt
	     (+1 (when (not byte-compile-delete-errors)
		   (byte-compile-constant 1)
		   (byte-compile-out 'byte-quo 0)))
	     (-1 (byte-compile-out 'byte-negate 0))
	     (t
	      (when (and (numberp elt) (= elt 0))
		(byte-compile-warn "Attempt to divide by zero: %s" form))
	      (byte-compile-form elt)
	      (byte-compile-out 'byte-quo 0))))))))

(defun byte-compile-nconc (form)
  (let ((args (cdr form)))
    (case (length args)
      (0 (byte-compile-constant nil))
      ;; nconc of one arg is a noop, even if that arg isn't a list.
      (1 (byte-compile-form (car args)))
      (t (byte-compile-form (car args))
	 (dolist (elt (cdr args))
	   (byte-compile-form elt)
	   (byte-compile-out 'byte-nconc 0))))))

(defun byte-compile-fset (form)
  ;; warn about forms like (fset 'foo '(lambda () ...))
  ;; (where the lambda expression is non-trivial...)
  ;; Except don't warn if the first argument is 'make-byte-code, because
  ;; I'm sick of getting mail asking me whether that warning is a problem.
  (let ((fn (nth 2 form))
	body)
    (when (and (eq (car-safe fn) 'quote)
	       (eq (car-safe (setq fn (nth 1 fn))) 'lambda)
	       (not (eq (car-safe (cdr-safe (nth 1 form))) 'make-byte-code)))
      (setq body (cdr (cdr fn)))
      (if (stringp (car body)) (setq body (cdr body)))
      (if (eq 'interactive (car-safe (car body))) (setq body (cdr body)))
      (if (and (consp (car body))
	       (not (eq 'byte-code (car (car body))))
	       (memq 'quoted-lambda byte-compile-warnings))
	  (byte-compile-warn
    "A quoted lambda form is the second argument of fset.  This is probably
     not what you want, as that lambda cannot be compiled.  Consider using
     the syntax (function (lambda (...) ...)) instead."))))
  (byte-compile-two-args form))

(defun byte-compile-subseq (form)
  (byte-compile-two-or-three-args form)
  ;; Check that XEmacs supports the substring-subseq equivalence.
  (pushnew '(eq 'subseq (symbol-function 'substring))
           byte-compile-checks-on-load :test #'equal))

(defmacro byte-compile-funarg-n (&rest n)
  `#'(lambda (form)
       ,@(loop
          for en in n
          collect `(let ((fn (nth ,en form)))
                    (when (and (eq (car-safe fn) 'quote)
                               (eq (car-safe (nth 1 fn)) 'lambda)
                               (or
                                (null (memq 'quoted-lambda
                                            byte-compile-warnings))
                                (byte-compile-warn
                                 "Passing a quoted lambda (arg %d) to #'%s, \
forcing function quoting" ,en (car form))))
                      (setcar fn 'function))))
          (byte-compile-normal-call form)))

;; (mapcar '(lambda (x) ..) ..) ==> (mapcar (function (lambda (x) ..)) ..)
;; for cases where it's guaranteed that first arg will be used as a lambda.
(defalias 'byte-compile-funarg (byte-compile-funarg-n 1))

;; (sort ... '(lambda (x) ..)) ==> (sort ... (function (lambda (x) ..)))
;; for cases where it's guaranteed that second arg will be used as a lambda.
(defalias 'byte-compile-funarg-2 (byte-compile-funarg-n 2))

;; For #'merge, basically.
(defalias 'byte-compile-funarg-4 (byte-compile-funarg-n 4))

;; For #'call-with-condition-handler, basically.
(defalias 'byte-compile-funarg-1-2 (byte-compile-funarg-n 1 2))

;; XEmacs change; don't cons up the list if it's going to be immediately
;; discarded. GNU give a warning in `byte-compile-normal-call' instead, and
;; only for #'mapcar.
(defun byte-compile-maybe-mapc (form)
  (and for-effect
       (or (null (memq 'discarded-consing byte-compile-warnings))
	   (byte-compile-warn
	    "Discarding the result of #'%s; maybe you meant #'mapc?"
	    (car form)))
       (setq form (cons 'mapc (cdr form))))
  (byte-compile-funarg form))

(defun byte-compile-maplist (form)
  (and for-effect
       (or (null (memq 'discarded-consing byte-compile-warnings))
	   (byte-compile-warn
	    "Discarding the result of #'maplist; maybe you meant #'mapl?"))
       (setq form (cons 'mapl (cdr form))))
  (byte-compile-funarg form))

;; For when calls to #'sort or #'mapcar have more than two args, something
;; recent XEmacs can handle, but GNU and 21.4 can't.
(defmacro byte-compile-maybe-add-* (complex max)
  `#'(lambda (form)
       (when (> (length (cdr form)) ,max)
         (when (memq 'callargs byte-compile-warnings)
           (byte-compile-warn
            "#'%s called with %d arguments, using #'%s instead"
            (car form) (length (cdr form)) ',complex))
         (setq form (cons ',complex (cdr form))))
       (funcall (or (get ',complex 'byte-compile)
                    'byte-compile-normal-call) form)))

(defalias 'byte-compile-mapcar (byte-compile-maybe-add-* mapcar* 2))

(defalias 'byte-compile-sort (byte-compile-maybe-add-* sort* 2))

(defalias 'byte-compile-fillarray (byte-compile-maybe-add-* fill 2))

;; (function foo) must compile like 'foo, not like (symbol-function 'foo).
;; Otherwise it will be incompatible with the interpreter,
;; and (funcall (function foo)) will lose with autoloads.

(defun byte-compile-function-form (form)
  (if (cddr form)
      (byte-compile-normal-call
       `(signal 'wrong-number-of-arguments '(function ,(length (cdr form)))))
    (byte-compile-constant (if (eq 'lambda (car-safe (nth 1 form)))
                               (byte-compile-lambda (nth 1 form))
                             (nth 1 form)))))

(defun byte-compile-insert (form)
  (cond ((null (cdr form))
	 (byte-compile-constant nil))
	((<= (length form) 256)
	 (mapc 'byte-compile-form (cdr form))
	 (if (cdr (cdr form))
	     (byte-compile-out 'byte-insertN (length (cdr form)))
	   (byte-compile-out 'byte-insert 0)))
	((memq t (mapcar 'consp (cdr (cdr form))))
	 (byte-compile-normal-call form))
	;; We can split it; there is no function call after inserting 1st arg.
	(t
	 (while (setq form (cdr form))
	   (byte-compile-form (car form))
	   (byte-compile-out 'byte-insert 0)
	   (when (cdr form)
	     (byte-compile-discard))))))

;; alas, the old (pre-19.12, and all existing versions of FSFmacs 19)
;; byte compiler will generate incorrect code for
;; (beginning-of-line nil buffer) because it buggily doesn't
;; check the number of arguments passed to beginning-of-line.

(defun byte-compile-beginning-of-line (form)
  (let ((len (length form)))
    (cond ((> len 3)
	   (byte-compile-subr-wrong-args form "0-2"))
	  ((or (eql len 3) (not (byte-compile-constp (nth 1 form))))
	   (byte-compile-normal-call form))
	  (t
	   (byte-compile-form
	    (list 'forward-line
		  (if (integerp (setq form (or (eval (nth 1 form)) 1)))
		      (1- form)
		    (byte-compile-warn
		     "Non-numeric arg to beginning-of-line: %s" form)
		    (list '1- (list 'quote form))))
	    t)
	   (byte-compile-constant nil)))))


(byte-defop-compiler set)
(byte-defop-compiler-1 setq)
(byte-defop-compiler-1 set-default)
(byte-defop-compiler-1 setq-default)

(byte-defop-compiler-1 quote)
(byte-defop-compiler-1 quote-form)

(defun byte-compile-setq (form)
  (let ((args (cdr form)) var val)
    (if (null args)
	;; (setq), with no arguments.
	(byte-compile-form nil for-effect)
      (while args
	(setq var (pop args))
	(if (null args)
	    ;; Odd number of args?  Let `set' get the error.
	    (byte-compile-form `(set ',var) for-effect)
	  (setq val (pop args))
          (byte-compile-form val)
          (unless (or args for-effect)
            (byte-compile-out 'byte-dup 0))
          (byte-compile-variable-ref 'byte-varset var)))))
  (setq for-effect nil))

(defun byte-compile-set (form)
  ;; Compile (set 'foo x) as (setq foo x) for trivially better code and so
  ;; that we get applicable warnings.  Compile everything else (including
  ;; malformed calls) like a normal 2-arg byte-coded function.
  (let ((symform (nth 1 form))
	(valform (nth 2 form))
	sym)
    (if (and (eql (length form) 3)
	     (eql (safe-length symform) 2)
	     (eq (car symform) 'quote)
	     (symbolp (setq sym (car (cdr symform)))))
	(byte-compile-setq `(setq ,sym ,valform))
      (byte-compile-two-args form))))

(defun byte-compile-setq-default (form)
  (let ((args (cdr form)))
    (if (null args)
	;; (setq-default), with no arguments.
	(byte-compile-form nil for-effect)
      ;; emit multiple calls to `set-default' if necessary
      (while args
	(byte-compile-form
	 ;; Odd number of args?  Let `set-default' get the error.
	 `(set-default ',(pop args) ,@(if args (list (pop args)) nil))
	 (if args t for-effect)))))
  (setq for-effect nil))

(defun byte-compile-set-default (form)
  (let* ((args (cdr form))
	 (nargs (length args))
	 (var (car args)))
    (when (and (eql (safe-length var) 2) (eq (car var) 'quote))
      (let ((sym (nth 1 var)))
	(cond
	 ((not (symbolp sym))
	  (byte-compile-warn "Attempt to set-globally non-symbol %s" sym))
	 ((byte-compile-constant-symbol-p sym)
	  (byte-compile-warn "Attempt to set-globally constant symbol %s" sym))
	 ((let ((cell (assq sym byte-compile-bound-variables)))
	    (and cell
		 (setcdr cell (logior (cdr cell) byte-compile-assigned-bit))
		 t)))
	 ;; notice calls to set-default/setq-default for variables which
	 ;; have not been declared with defvar/defconst.
	 ((globally-boundp sym))	; OK
	 ((not (memq 'free-vars byte-compile-warnings))) ; warnings suppressed?
	 ((memq sym byte-compile-free-assignments)) ; already warned about sym
	 (t
	  (byte-compile-warn "assignment to free variable %s" sym)
	  (push sym byte-compile-free-assignments)))))
    (if (eql nargs 2)
	;; now emit a normal call to set-default
	(byte-compile-normal-call form)
      (byte-compile-subr-wrong-args form 2))))


(defun byte-compile-quote (form)
  (if (cddr form)
      (byte-compile-normal-call
       `(signal 'wrong-number-of-arguments '(quote ,(length (cdr form)))))
    (byte-compile-constant (car (cdr form)))))

(defun byte-compile-quote-form (form)
  (if (cddr form)
      (byte-compile-normal-call
       `(signal 'wrong-number-of-arguments '(quote ,(length (cdr form)))))
    (byte-compile-constant (byte-compile-top-level (nth 1 form)))))

;;; control structures

(defun byte-compile-body (body &optional for-effect)
  (while (cdr body)
    (byte-compile-form (car body) t)
    (setq body (cdr body)))
  (byte-compile-form (car body) for-effect))

(proclaim-inline byte-compile-body-do-effect)
(defun byte-compile-body-do-effect (body)
  (byte-compile-body body for-effect)
  (setq for-effect nil))

(proclaim-inline byte-compile-form-do-effect)
(defun byte-compile-form-do-effect (form)
  (byte-compile-form form for-effect)
  (setq for-effect nil))

(byte-defop-compiler-1 inline byte-compile-progn)
(byte-defop-compiler-1 progn)
(byte-defop-compiler-1 prog1)
(byte-defop-compiler-1 multiple-value-prog1)
(byte-defop-compiler-1 values)
(byte-defop-compiler-1 values-list)
(byte-defop-compiler-1 prog2)
(byte-defop-compiler-1 if)
(byte-defop-compiler-1 cond)
(byte-defop-compiler-1 and)
(byte-defop-compiler-1 or)
(byte-defop-compiler-1 while)
(byte-defop-compiler-1 funcall)
(byte-defop-compiler-1 apply byte-compile-funarg)
(byte-defop-compiler-1 mapcar byte-compile-mapcar)
(byte-defop-compiler-1 mapcar* byte-compile-maybe-mapc)
(byte-defop-compiler-1 mapatoms byte-compile-funarg)
(byte-defop-compiler-1 mapconcat byte-compile-funarg)
(byte-defop-compiler-1 mapc byte-compile-funarg)
(byte-defop-compiler-1 maphash byte-compile-funarg)
(byte-defop-compiler-1 map-char-table byte-compile-funarg)
(byte-defop-compiler-1 mapvector byte-compile-maybe-mapc)
(byte-defop-compiler-1 mapc-internal byte-compile-funarg)
(byte-defop-compiler-1 maplist byte-compile-maplist)
(byte-defop-compiler-1 mapl byte-compile-funarg)
(byte-defop-compiler-1 mapcan byte-compile-funarg)
(byte-defop-compiler-1 mapcon byte-compile-funarg)
(byte-defop-compiler-1 map-database byte-compile-funarg)
(byte-defop-compiler-1 map-extent-children byte-compile-funarg)
(byte-defop-compiler-1 map-extents byte-compile-funarg)
(byte-defop-compiler-1 map-plist byte-compile-funarg)
(byte-defop-compiler-1 map-range-table byte-compile-funarg)
(byte-defop-compiler-1 map-syntax-table byte-compile-funarg)

(byte-defop-compiler-1 remove-if byte-compile-funarg)
(byte-defop-compiler-1 remove-if-not byte-compile-funarg)
(byte-defop-compiler-1 delete-if byte-compile-funarg)
(byte-defop-compiler-1 delete-if-not byte-compile-funarg)
(byte-defop-compiler-1 find-if byte-compile-funarg)
(byte-defop-compiler-1 find-if-not byte-compile-funarg)
(byte-defop-compiler-1 position-if byte-compile-funarg)
(byte-defop-compiler-1 position-if-not byte-compile-funarg)
(byte-defop-compiler-1 count-if byte-compile-funarg)
(byte-defop-compiler-1 count-if-not byte-compile-funarg)
(byte-defop-compiler-1 member-if byte-compile-funarg)
(byte-defop-compiler-1 member-if-not byte-compile-funarg)
(byte-defop-compiler-1 assoc-if byte-compile-funarg)
(byte-defop-compiler-1 assoc-if-not byte-compile-funarg)
(byte-defop-compiler-1 rassoc-if byte-compile-funarg)
(byte-defop-compiler-1 rassoc-if-not byte-compile-funarg)
(byte-defop-compiler-1 reduce byte-compile-funarg)
(byte-defop-compiler-1 some byte-compile-funarg)
(byte-defop-compiler-1 every byte-compile-funarg)
(byte-defop-compiler-1 notany byte-compile-funarg)
(byte-defop-compiler-1 notevery byte-compile-funarg)

(byte-defop-compiler-1 walk-windows byte-compile-funarg)
(byte-defop-compiler-1 get-window-with-predicate byte-compile-funarg)

(byte-defop-compiler-1 map byte-compile-funarg-2)
(byte-defop-compiler-1 map-into byte-compile-funarg-2)
(byte-defop-compiler-1 apropos-internal byte-compile-funarg-2)
(byte-defop-compiler-1 sort byte-compile-sort)
(byte-defop-compiler-1 sort* byte-compile-funarg-2)
(byte-defop-compiler-1 stable-sort byte-compile-funarg-2)
(byte-defop-compiler-1 substitute-if byte-compile-funarg-2)
(byte-defop-compiler-1 substitute-if-not byte-compile-funarg-2)
(byte-defop-compiler-1 nsubstitute-if byte-compile-funarg-2)
(byte-defop-compiler-1 nsubstitute-if-not byte-compile-funarg-2)
(byte-defop-compiler-1 subst-if byte-compile-funarg-2)
(byte-defop-compiler-1 subst-if-not byte-compile-funarg-2)
(byte-defop-compiler-1 nsubst-if byte-compile-funarg-2)
(byte-defop-compiler-1 nsubst-if-not byte-compile-funarg-2)

(byte-defop-compiler-1 merge byte-compile-funarg-4)

(byte-defop-compiler-1 call-with-condition-handler byte-compile-funarg-1-2)
(byte-defop-compiler-1 mapcar-extents byte-compile-funarg-1-2)

(byte-defop-compiler-1 let)
(byte-defop-compiler-1 let*)

(byte-defop-compiler-1 integerp)
(byte-defop-compiler-1 eql)
(byte-defop-compiler-1 fillarray)

(defun byte-compile-progn (form)
  (byte-compile-body-do-effect (cdr form)))

(defun byte-compile-prog1 (form)
  (setq form (cdr form))
  ;; #'prog1 never returns multiple values:
  (byte-compile-form-do-effect `(or ,(pop form) nil))
  (byte-compile-body form t))

(defun byte-compile-multiple-value-prog1 (form)
  (setq form (cdr form))
  (byte-compile-form-do-effect (pop form))
  (byte-compile-body form t))

(defun byte-compile-values (form)
  (if (eql 2 (length form))
      (if (byte-compile-constp (second form))
	  (byte-compile-form-do-effect (second form))
	;; #'or compiles to bytecode, #'values doesn't:
	(byte-compile-form-do-effect `(or ,(second form) nil)))
    (byte-compile-normal-call form)))

(defun byte-compile-values-list (form)
  (if (and (eql 2 (length form))
           (or (null (second form))
               (and (consp (second form))
                    (eq (car (second form))
                        'quote)
                    (not (symbolp (car-safe (cdr (second form))))))))
      (byte-compile-form-do-effect (car-safe (cdr (second form))))
    (byte-compile-normal-call form)))

(defun byte-compile-prog2 (form)
  (setq form (cdr form))
  (byte-compile-form (pop form) t)
  ;; #'prog2 never returns multiple values:
  (byte-compile-form-do-effect `(or ,(pop form) nil))
  (byte-compile-body form t))

(defmacro byte-compile-goto-if (cond discard tag)
  `(byte-compile-goto
    (if ,cond
	(if ,discard 'byte-goto-if-not-nil 'byte-goto-if-not-nil-else-pop)
      (if ,discard 'byte-goto-if-nil 'byte-goto-if-nil-else-pop))
    ,tag))

(defun byte-compile-if (form)
  (byte-compile-form (car (cdr form)))
  (if (null (nthcdr 3 form))
      ;; No else-forms
      (let ((donetag (byte-compile-make-tag)))
	(byte-compile-goto-if nil for-effect donetag)
	(byte-compile-form (nth 2 form) for-effect)
	(byte-compile-out-tag donetag))
    (let ((donetag (byte-compile-make-tag)) (elsetag (byte-compile-make-tag)))
      (byte-compile-goto 'byte-goto-if-nil elsetag)
      (byte-compile-form (nth 2 form) for-effect)
      (byte-compile-goto 'byte-goto donetag)
      (byte-compile-out-tag elsetag)
      (byte-compile-body (cdr (cdr (cdr form))) for-effect)
      (byte-compile-out-tag donetag)))
  (setq for-effect nil))

(defun byte-compile-cond (clauses)
  (let ((donetag (byte-compile-make-tag))
	nexttag clause)
    (while (setq clauses (cdr clauses))
      (setq clause (car clauses))
      (cond ((or (eq (car clause) t)
		 (and (eq (car-safe (car clause)) 'quote)
		      (car-safe (cdr-safe (car clause)))))
	     ;; Unconditional clause
	     (setq clause (cons t clause)
		   clauses nil))
	    ((cdr clauses)
	     (byte-compile-form (car clause))
	     (if (null (cdr clause))
		 ;; First clause is a singleton.
		 (byte-compile-goto-if t for-effect donetag)
	       (setq nexttag (byte-compile-make-tag))
	       (byte-compile-goto 'byte-goto-if-nil nexttag)
	       (byte-compile-body (cdr clause) for-effect)
	       (byte-compile-goto 'byte-goto donetag)
	       (byte-compile-out-tag nexttag)))))
    ;; Last clause
    (and (cdr clause) (not (eq (car clause) t))
	 (progn (byte-compile-form (car clause))
		(byte-compile-goto-if nil for-effect donetag)
		(setq clause (cdr clause))))
    (byte-compile-body-do-effect clause)
    (byte-compile-out-tag donetag)))

(defun byte-compile-and (form)
  (let ((failtag (byte-compile-make-tag))
	(args (cdr form)))
    (if (null args)
	(byte-compile-form-do-effect t)
      (while (cdr args)
	(byte-compile-form (car args))
	(byte-compile-goto-if nil for-effect failtag)
	(setq args (cdr args)))
      (byte-compile-form-do-effect (car args))
      (byte-compile-out-tag failtag))))

(defun byte-compile-or (form)
  (let ((wintag (byte-compile-make-tag))
	(args (cdr form)))
    (if (null args)
	(byte-compile-form-do-effect nil)
      (while (cdr args)
	(byte-compile-form (car args))
	(byte-compile-goto-if t for-effect wintag)
	(setq args (cdr args)))
      (byte-compile-form-do-effect (car args))
      (byte-compile-out-tag wintag))))

(defun byte-compile-while (form)
  (let ((endtag (byte-compile-make-tag))
	(looptag (byte-compile-make-tag)))
    (byte-compile-out-tag looptag)
    (byte-compile-form (car (cdr form)))
    (byte-compile-goto-if nil for-effect endtag)
    (byte-compile-body (cdr (cdr form)) t)
    (byte-compile-goto 'byte-goto looptag)
    (byte-compile-out-tag endtag)
    (setq for-effect nil)))

(defun byte-compile-funcall (form)
  (if (and (memq 'callargs byte-compile-warnings)
           (byte-compile-constp (second form)))
      (byte-compile-callargs-warn (cons (cl-const-expr-val (second form))
                                        (nthcdr 2 form))))
  (if (and byte-optimize
           (eq 'function (car-safe (cadr form)))
           (eq 'lambda (car-safe (cadadr form)))
	    (or
	     (not (eq (setq form (cons (cadadr form) (cddr form)))
		      (setq form (byte-compile-unfold-lambda form))))
	     (prog1 nil (setq form `(funcall #',(car form) ,@(cdr form))))))
      ;; The byte-compile part of the #'labels implementation, above,
      ;; happens after macroexpansion and after the source optimizer has
      ;; done its thing. When labels are to be made inline we can have code
      ;; that looks like (funcall #'(lambda ...) ...), when the code that
      ;; the optimizer saw looked like (funcall #<compiled-function ...>
      ;; ...).
      ;;
      ;; So, the optimizer doesn't have the opportunity to transform the
      ;; former to (let (...) ...), and it's reasonable to do that here (since
      ;; the labels implementation doesn't change other code that would need
      ;; running through the optimizer; the lambda itself has already been
      ;; through the optimizer).
      ;;
      ;; Equally reasonable, and conceptually a bit clearer, would be to do
      ;; the transformation to (funcall #'(lambda ...) ...) in the
      ;; byte-optimizer, breaking most of the #'sublis calls out of the
      ;; byte-compile method.
      (byte-compile-form form)
    (mapc 'byte-compile-form (cdr form))
    (byte-compile-out 'byte-call (length (cdr (cdr form))))))


(defun byte-compile-let (form)
  ;; First compute the binding values in the old scope.
  (let ((varlist (car (cdr form))))
    (while varlist
      (if (consp (car varlist))
	  (byte-compile-form (car (cdr (car varlist))))
	(byte-compile-push-constant nil))
      (setq varlist (cdr varlist))))
  (let ((byte-compile-bound-variables
	 (cons 'new-scope byte-compile-bound-variables))
	(varlist (reverse (car (cdr form))))
	(extra-flags
	 ;; If this let is of the form (let (...) (byte-code ...))
	 ;; then assume that it is the result of a transformation of
	 ;; ((lambda (...) (byte-code ... )) ...) and thus compile
	 ;; the variable bindings as if they were arglist bindings
	 ;; (which matters for what warnings.)
	 (if (eq 'byte-code (car-safe (nth 2 form)))
	     byte-compile-arglist-bit
	   nil)))
    (while varlist
      (byte-compile-variable-ref 'byte-varbind
				 (if (consp (car varlist))
				     (car (car varlist))
				   (car varlist))
				 extra-flags)
      (setq varlist (cdr varlist)))
    (byte-compile-body-do-effect (cdr (cdr form)))
    (if (memq 'unused-vars byte-compile-warnings)
	;; done compiling in this scope, warn now.
	(byte-compile-warn-about-unused-variables))
    (byte-compile-out 'byte-unbind (length (car (cdr form))))))

(defun byte-compile-let* (form)
  (let ((byte-compile-bound-variables
	 (cons 'new-scope byte-compile-bound-variables))
	(varlist (copy-sequence (car (cdr form)))))
    (while varlist
      (if (atom (car varlist))
	  (byte-compile-push-constant nil)
	(byte-compile-form (car (cdr (car varlist))))
	(setcar varlist (car (car varlist))))
      (byte-compile-variable-ref 'byte-varbind (car varlist))
      (setq varlist (cdr varlist)))
    (byte-compile-body-do-effect (cdr (cdr form)))
    (if (memq 'unused-vars byte-compile-warnings)
	;; done compiling in this scope, warn now.
	(byte-compile-warn-about-unused-variables))
    (byte-compile-out 'byte-unbind (length (car (cdr form))))))

;; We've renamed the integerp bytecode to fixnump, and changed its semantics
;; accordingly.  This means #'integerp itself can't be as fast as it used to
;; be, since it no longer has a bytecode to itself.  As it happens, though,
;; most of the non-core calls to #'integerp are in contexts where it is
;; either going to receive a fixnum, or something non-numeric entirely; the
;; contexts where it needs to distinguish between an integer and a float are
;; very rare. So, we can have (integerp X) compile to:
;;
;; (or (fixnump X) (and (numberp X) (funcall #'integerp X)))
;;
;; without the multiple evaluation of X, and where #'fixnump and #'numberp
;; both have bytecodes. We ignore for-effect, because byte-optimize.el will
;; delete this call in its presence.
;;
;; This approach is byte-code compatible with 21.4 and with earlier 21.5
;; (except that earlier 21.5 with bignum support will confuse Bfixnump and
;; Bintegerp; which it did in dealing with byte-compiled code from 21.4
;; anyway).

(defun byte-compile-integerp (form)
  (if (not (eql (length form) 2))
      (byte-compile-subr-wrong-args form 1)
    (let ((donetag (byte-compile-make-tag))
	  (wintag (byte-compile-make-tag))
	  (failtag (byte-compile-make-tag)))
      (byte-compile-constant 'integerp)
      (byte-compile-form (second form))
      (byte-compile-out 'byte-dup 0)
      (byte-compile-out 'byte-fixnump 0)
      (byte-compile-goto 'byte-goto-if-not-nil wintag)
      (byte-compile-out 'byte-dup 0)
      (byte-compile-out 'byte-numberp 0)
      (byte-compile-goto 'byte-goto-if-nil failtag)
      (byte-compile-out 'byte-call 1)
      ;; At this point, the only thing from this function remaining on the
      ;; stack is the return value of the called #'integerp, which reflects
      ;; exactly what we want. Go directly to donetag, do not discard
      ;; anything.
      (byte-compile-goto 'byte-goto donetag)
      (byte-compile-out-tag failtag)
      (byte-compile-discard)
      (byte-compile-discard)
      (byte-compile-constant nil)
      (byte-compile-goto 'byte-goto donetag)
      (byte-compile-out-tag wintag)
      (byte-compile-discard)
      (byte-compile-discard)
      (byte-compile-constant t)
      (byte-compile-out-tag donetag))))

(defun byte-compile-eql (form)
  (if (eql 3 (length form))
    (let ((donetag (byte-compile-make-tag))
	  (eqtag (byte-compile-make-tag)))
      (mapc 'byte-compile-form (cdr form))
      (byte-compile-out 'byte-dup 0)
      (byte-compile-out 'byte-numberp 0)
      (byte-compile-goto 'byte-goto-if-nil eqtag)
      (byte-compile-out 'byte-dup 0)
      (byte-compile-out 'byte-fixnump 0)
      (byte-compile-goto 'byte-goto-if-not-nil eqtag)
      (byte-compile-out 'byte-equal 0)
      (byte-compile-goto 'byte-goto donetag)
      (byte-compile-out-tag eqtag)
      (byte-compile-out 'byte-eq 0)
      (byte-compile-out-tag donetag))
    (byte-compile-subr-wrong-args form 2)))

;;(byte-defop-compiler-1 /= byte-compile-negated)
(byte-defop-compiler-1 atom byte-compile-negated)
(byte-defop-compiler-1 nlistp byte-compile-negated)

;;(put '/= 'byte-compile-negated-op '=)
(put 'atom 'byte-compile-negated-op 'consp)
(put 'nlistp 'byte-compile-negated-op 'listp)

(defun byte-compile-negated (form)
  (byte-compile-form-do-effect (byte-compile-negation-optimizer form)))

;; Even when optimization is off, atom is optimized to (not (consp ...)).
(defun byte-compile-negation-optimizer (form)
  ;; an optimizer for forms where <form1> is less efficient than (not <form2>)
  (list 'not
    (cons (or (get (car form) 'byte-compile-negated-op)
	      (error
	       "Compiler error: `%s' has no `byte-compile-negated-op' property"
	       (car form)))
	  (cdr form))))

;;; other tricky macro-like special-operators

(byte-defop-compiler-1 catch)
(byte-defop-compiler-1 unwind-protect)
(byte-defop-compiler-1 condition-case)
(byte-defop-compiler-1 save-excursion)
(byte-defop-compiler-1 save-current-buffer)
(byte-defop-compiler-1 save-restriction)
(byte-defop-compiler-1 with-output-to-temp-buffer)
;; no track-mouse.

(defvar byte-compile-active-blocks nil)

(defun byte-compile-catch (form)
  "Byte-compile and return a `catch' from.

If FORM is the result of macroexpanding a `block' form (the TAG argument is
a quoted symbol with a `cl-block-name' property) and there is no
corresponding `return-from' within the block--or equivalently, it was
optimized away--just byte compile and return the BODY."
  (let* ((symbol (car-safe (cdr-safe (nth 1 form))))
	 (not-present '#:not-present)
	 (block (cond ((null symbol) not-present)
                      ((not (symbolp symbol)) not-present)
                      (t (get symbol 'cl-block-name not-present))))
	 (elt (and (not (eq block not-present)) (list block)))
	 (byte-compile-active-blocks
	  (if elt
	      (cons elt byte-compile-active-blocks)
	    byte-compile-active-blocks))
	 (body
	  (byte-compile-top-level (cons 'progn (cddr form))
                                  (and (not elt) for-effect))))
    (if (and elt (not (cdr elt)))
	;; A lexical block without any contained return-from clauses:
	(byte-compile-form body)
      ;; A normal catch call, or a lexical block with a contained
      ;; return-from clause.
      (byte-compile-form (car (cdr form)))
      (byte-compile-push-constant body)
      (byte-compile-out 'byte-catch 0))))

(defun byte-compile-unwind-protect (form)
  (byte-compile-push-constant
   (byte-compile-top-level-body (cdr (cdr form)) t))
  (byte-compile-out 'byte-unwind-protect 0)
  (byte-compile-form-do-effect (car (cdr form)))
  (byte-compile-out 'byte-unbind 1))

;;(defun byte-compile-track-mouse (form)
;;  (byte-compile-form
;;   (list
;;    'funcall
;;    (list 'quote
;;	    (list 'lambda nil
;;		  (cons 'track-mouse
;;			(byte-compile-top-level-body (cdr form))))))))

(defun byte-compile-condition-case (form)
  (let* ((var (nth 1 form))
	 (byte-compile-bound-variables
	  (if var
	      (cons (cons var 0)
		    (cons 'new-scope byte-compile-bound-variables))
	    (cons 'new-scope byte-compile-bound-variables))))
    (or (symbolp var)
	(byte-compile-warn
	 "%s is not a variable-name or nil (in condition-case)"
	 (prin1-to-string var)))
    (byte-compile-push-constant var)
    (byte-compile-push-constant (byte-compile-top-level
				 (nth 2 form) for-effect))
    (let ((clauses (cdr (cdr (cdr form))))
	  compiled-clauses)
      (while clauses
	(let* ((clause (car clauses))
               (condition (car clause)))
          (cond ((not (or (symbolp condition)
			  (and (listp condition)
			       (let ((syms condition) (ok t))
				 (while syms
				   (if (not (symbolp (car syms)))
				       (setq ok nil))
				   (setq syms (cdr syms)))
				 ok))))
                 (byte-compile-warn
                   "%s is not a symbol naming a condition or a list of such (in condition-case)"
                   (prin1-to-string condition)))
;;                ((not (or (eq condition 't)
;;			  (and (stringp (get condition 'error-message))
;;			       (consp (get condition 'error-conditions)))))
;;                 (byte-compile-warn
;;                   "%s is not a known condition name (in condition-case)"
;;                   condition))
		)
	  (setq compiled-clauses
		(cons (cons condition
			    (byte-compile-top-level-body
			     (cdr clause) for-effect))
		      compiled-clauses)))
	(setq clauses (cdr clauses)))
      (byte-compile-push-constant (nreverse compiled-clauses)))
    (if (memq 'unused-vars byte-compile-warnings)
	;; done compiling in this scope, warn now.
	(byte-compile-warn-about-unused-variables))
    (byte-compile-out 'byte-condition-case 0)))


(defun byte-compile-save-excursion (form)
  (byte-compile-out 'byte-save-excursion 0)
  (byte-compile-body-do-effect (cdr form))
  (byte-compile-out 'byte-unbind 1))

(defun byte-compile-save-restriction (form)
  (byte-compile-out 'byte-save-restriction 0)
  (byte-compile-body-do-effect (cdr form))
  (byte-compile-out 'byte-unbind 1))

(defun byte-compile-save-current-buffer (form)
  (byte-compile-out 'byte-save-current-buffer 0)
  (byte-compile-body-do-effect (cdr form))
  (byte-compile-out 'byte-unbind 1))

(defun byte-compile-with-output-to-temp-buffer (form)
  (byte-compile-form (car (cdr form)))
  (byte-compile-out 'byte-temp-output-buffer-setup 0)
  (byte-compile-body (cdr (cdr form)))
  (byte-compile-out 'byte-temp-output-buffer-show 0))
  
(defun byte-compile-multiple-value-call (form)
  (if (< (length form) 2)
      (progn
        (byte-compile-warn-wrong-args form 1)
        (byte-compile-normal-call
         `(signal 'wrong-number-of-arguments '(,(car form)
                                               ,(length (cdr form))))))
    (setq form (cdr form))
    (byte-compile-form (car form))
    (byte-compile-push-constant 0)
    (byte-compile-variable-ref 'byte-varref 'multiple-values-limit)
    ;; bind-multiple-value-limits leaves two existing values on the stack,
    ;; and pushes a new value, the specpdl_depth() at the time it was
    ;; called.
    (byte-compile-out 'byte-bind-multiple-value-limits 0)
    (mapc 'byte-compile-form (cdr form))
    ;; Most of the other code puts this sort of value in the program stream,
    ;; not pushing it on the stack.
    (byte-compile-push-constant (+ 3 (length form)))
    (byte-compile-out 'byte-multiple-value-call (+ 3 (length form)))
    (pushnew '(subrp (symbol-function 'multiple-value-call))
             byte-compile-checks-on-load
             :test #'equal)))

(defun byte-compile-multiple-value-list-internal (form)
  (if (not (eql 4 (length form)))
      (progn
        (byte-compile-warn-wrong-args form 3)
        (byte-compile-normal-call
         `(signal 'wrong-number-of-arguments '(,(car form)
                                               ,(length (cdr form))))))
    (byte-compile-form (nth 1 form))
    (byte-compile-form (nth 2 form))
    (byte-compile-out 'byte-bind-multiple-value-limits 0)
    (byte-compile-form (nth 3 form))
    (byte-compile-out (get (car form) 'byte-opcode) 0)
    (pushnew '(subrp (symbol-function 'multiple-value-call))
             byte-compile-checks-on-load
             :test #'equal)))

(defun byte-compile-throw (form)
  ;; We can't use byte-compile-two-args for throw because in the event that
  ;; the form does not have two args, it tries to #'funcall it expecting a
  ;; runtime wrong-number-of-arguments error. Now that #'throw is a special
  ;; form, it provokes an invalid-function error instead (or at least it
  ;; should; there's a kludge around for the moment in eval.c that avoids
  ;; that, but this file should not assume that that will always be there).
  (if (not (eql 2 (length (cdr form))))
      (progn
        (byte-compile-warn-wrong-args form 2)
        (byte-compile-normal-call
         `(signal 'wrong-number-of-arguments '(,(car form)
                                               ,(length (cdr form))))))
    ;; If this form was macroexpanded from `return-from', mark the
    ;; corresponding block as having been referenced.
    (let* ((symbol (car-safe (cdr-safe (nth 1 form))))
           (not-present '#:not-present)
	   (block (if (and symbol (symbolp symbol))
		      (get symbol 'cl-block-name not-present)
		    not-present))
	   (assq (and (not (eq block not-present))
                      (assq block byte-compile-active-blocks))))
      (if assq
	  (setcdr assq t)
	(if (not (eq block not-present))
	    ;; No corresponding enclosing block.
	    (byte-compile-warn "return-from: no enclosing block named `%s'"
			       block))))
    (mapc 'byte-compile-form (cdr form))  ;; Push the arguments
    (byte-compile-out (get (car form) 'byte-opcode) 0)
    (pushnew '(null (function-max-args 'throw)) byte-compile-checks-on-load
             :test #'equal)))

;;; top-level forms elsewhere

(byte-defop-compiler-1 defun)
(byte-defop-compiler-1 defmacro)
(byte-defop-compiler-1 defvar)
(byte-defop-compiler-1 defvar   byte-compile-defvar-or-defconst)
(byte-defop-compiler-1 defconst byte-compile-defvar-or-defconst)
(byte-defop-compiler-1 autoload)
;; According to Mly this can go now that lambda is a macro
;(byte-defop-compiler-1 lambda byte-compile-lambda-form)
(byte-defop-compiler-1 defalias)
(byte-defop-compiler-1 define-function)

(defun byte-compile-defun (form)
  ;; This is not used for file-level defuns with doc strings.
  (byte-compile-two-args ; Use this to avoid byte-compile-fset's warning.
   (list 'fset (list 'quote (nth 1 form))
	 (byte-compile-byte-code-maker
	  (byte-compile-lambda (cons 'lambda (cdr (cdr form)))))))
  (byte-compile-discard)
  (byte-compile-constant (nth 1 form)))

(defun byte-compile-defmacro (form)
  ;; This is not used for file-level defmacros with doc strings.
  (byte-compile-body-do-effect
   (list (list 'fset (list 'quote (nth 1 form))
	       (let ((code (byte-compile-byte-code-maker
			    (byte-compile-lambda
			     (cons 'lambda (cdr (cdr form)))))))
		 (if (eq (car-safe code) 'make-byte-code)
		     (list 'cons ''macro code)
		   (list 'quote (cons 'macro (eval code))))))
	 (list 'quote (nth 1 form)))))

(defun byte-compile-defvar-or-defconst (form)
  ;; This is not used for file-level defvar/defconsts with doc strings:
  ;; byte-compile-file-form-defvar-or-defconst will be used in that case.
  ;; (defvar|defconst VAR [VALUE [DOCSTRING]])
  (let ((fun (nth 0 form))
	(var (nth 1 form))
	(value (nth 2 form))
	(string (nth 3 form)))
    (when (> (length form) 4)
      (byte-compile-warn
       "%s %s called with %d arguments, but accepts only %s"
       fun var (length (cdr form)) 3))
    (when (memq 'free-vars byte-compile-warnings)
      (push (cons var byte-compile-global-bit) byte-compile-bound-variables))
    (byte-compile-body-do-effect
     (list
      ;; Put the defined variable in this library's load-history entry
      ;; just as a real defvar would, but only in top-level forms with values.
      (when (and (> (length form) 2)
		 (null byte-compile-current-form))
	`(push ',var current-load-list))
      (when (> (length form) 3)
	(when (and string (not (stringp string)))
	  (byte-compile-warn "Third arg to %s %s is not a string: %s"
			     fun var string))
	`(put ',var 'variable-documentation ,string))
      (if (cdr (cdr form))		; `value' provided
	  (if (eq fun 'defconst)
	      ;; `defconst' sets `var' unconditionally.
	      `(setq ,var ,value)
	    ;; `defvar' sets `var' only when unbound.
	    `(if (not (default-boundp ',var)) (set-default ',var ,value))))
      `',var))))

(defun byte-compile-autoload (form)
  (and (byte-compile-constp (nth 1 form))
       (byte-compile-constp (nth 5 form))
       (memq (eval (nth 5 form)) '(t macro))  ; macro-p
       (not (fboundp (eval (nth 1 form))))
       (byte-compile-warn
	"The compiler ignores `autoload' except at top level.  You should
     probably put the autoload of the macro `%s' at top-level."
	(eval (nth 1 form))))
  (byte-compile-normal-call form))

;; Lambda's in valid places are handled as special cases by various code.
;; The ones that remain are errors.
;; According to Mly this can go now that lambda is a macro
;(defun byte-compile-lambda-form (form)
;  (byte-compile-warn
;   "`lambda' used in function position is invalid: probably you mean #'%s"
;   (let ((print-escape-newlines t)
;	 (print-level 4)
;	 (print-length 4))
;     (prin1-to-string form)))
;  (byte-compile-normal-call
;   (list 'signal ''error
;	 (list 'quote (list "`lambda' used in function position" form)))))

;; Compile normally, but deal with warnings for the function being defined.
(defun byte-compile-defalias (form)
  (if (and (consp (cdr form)) (consp (nth 1 form))
	   (eq (car (nth 1 form)) 'quote)
	   (consp (cdr (nth 1 form)))
	   (symbolp (nth 1 (nth 1 form)))
	   (consp (nthcdr 2 form))
	   (consp (nth 2 form))
	   (eq (car (nth 2 form)) 'quote)
	   (consp (cdr (nth 2 form)))
	   (symbolp (nth 1 (nth 2 form))))
      (progn
	(byte-compile-defalias-warn (nth 1 (nth 1 form))
				    (nth 1 (nth 2 form)))
	(setq byte-compile-function-environment
	      (cons (cons (nth 1 (nth 1 form))
			  (nth 1 (nth 2 form)))
		    byte-compile-function-environment))))
  (byte-compile-normal-call form))

(defun byte-compile-define-function (form)
  (byte-compile-defalias form))

;; Turn off warnings about prior calls to the function being defalias'd.
;; This could be smarter and compare those calls with
;; the function it is being aliased to.
(defun byte-compile-defalias-warn (new alias)
  (let ((calls (assq new byte-compile-unresolved-functions)))
    (if calls
	(setq byte-compile-unresolved-functions
	      (delq calls byte-compile-unresolved-functions)))))

;;; tags

;; Note: Most operations will strip off the 'TAG, but it speeds up
;; optimization to have the 'TAG as a part of the tag.
;; Tags will be (TAG . (tag-number . stack-depth)).
(defun byte-compile-make-tag ()
  (list 'TAG (setq byte-compile-tag-number (1+ byte-compile-tag-number))))


(defun byte-compile-out-tag (tag)
  (push tag byte-compile-output)
  (if (cdr (cdr tag))
      (progn
	;; ## remove this someday
	(and byte-compile-depth
	  (not (= (cdr (cdr tag)) byte-compile-depth))
	  (error "Compiler bug: depth conflict at tag %d" (car (cdr tag))))
	(setq byte-compile-depth (cdr (cdr tag))))
    (setcdr (cdr tag) byte-compile-depth)))

(defun byte-compile-goto (opcode tag)
  (push (cons opcode tag) byte-compile-output)
  (setcdr (cdr tag) (if (memq opcode byte-goto-always-pop-ops)
			(1- byte-compile-depth)
		      byte-compile-depth))
  (setq byte-compile-depth (and (not (eq opcode 'byte-goto))
				(1- byte-compile-depth))))

(defun byte-compile-out (opcode offset)
  (push (cons opcode offset) byte-compile-output)
  (case opcode
    (byte-call
     (setq byte-compile-depth (- byte-compile-depth offset)))
    (byte-return
     ;; This is actually an unnecessary case, because there should be
     ;; no more opcodes behind byte-return.
     (setq byte-compile-depth nil))
    (byte-multiple-value-call
     (setq byte-compile-depth (- byte-compile-depth offset)))
    (t
     (setq byte-compile-depth (+ byte-compile-depth
				 (or (aref byte-stack+-info
					   (symbol-value opcode))
				     (- (1- offset))))
	   byte-compile-maxdepth (max byte-compile-depth
				      byte-compile-maxdepth))))
  ;;(if (< byte-compile-depth 0) (error "Compiler error: stack underflow"))
  )


;;; call tree stuff

(defun byte-compile-annotate-call-tree (form)
  (let (entry)
    ;; annotate the current call
    (if (setq entry (assq (car form) byte-compile-call-tree))
	(or (memq byte-compile-current-form (nth 1 entry)) ;callers
	    (setcar (cdr entry)
		    (cons byte-compile-current-form (nth 1 entry))))
      (push (list (car form) (list byte-compile-current-form) nil)
	    byte-compile-call-tree))
    ;; annotate the current function
    (if (setq entry (assq byte-compile-current-form byte-compile-call-tree))
	(or (memq (car form) (nth 2 entry)) ;called
	    (setcar (cdr (cdr entry))
		    (cons (car form) (nth 2 entry))))
      (push (list byte-compile-current-form nil (list (car form)))
	    byte-compile-call-tree))))

;; Renamed from byte-compile-report-call-tree
;; to avoid interfering with completion of byte-compile-file.
;;;###autoload
(defun display-call-tree (&optional filename)
  "Display a call graph of a specified file.
This lists which functions have been called, what functions called
them, and what functions they call.  The list includes all functions
whose definitions have been compiled in this Emacs session, as well as
all functions called by those functions.

The call graph does not include macros, inline functions, or
primitives that the byte-code interpreter knows about directly \(eq,
cons, etc.\).

The call tree also lists those functions which are not known to be called
\(that is, to which no calls have been compiled\), and which cannot be
invoked interactively."
  (interactive)
  (message "Generating call tree...")
  (with-output-to-temp-buffer "*Call-Tree*"
    (set-buffer "*Call-Tree*")
    (erase-buffer)
    (message "Generating call tree... (sorting on %s)"
	     byte-compile-call-tree-sort)
    (insert "Call tree for "
	    (cond ((null byte-compile-current-file) (or filename "???"))
		  ((stringp byte-compile-current-file)
		   byte-compile-current-file)
		  (t (buffer-name byte-compile-current-file)))
	    " sorted on "
	    (prin1-to-string byte-compile-call-tree-sort)
	    ":\n\n")
    (if byte-compile-call-tree-sort
	(setq byte-compile-call-tree
	      (sort byte-compile-call-tree
		    (cond
		     ((eq byte-compile-call-tree-sort 'callers)
		      #'(lambda (x y) (< (length (nth 1 x))
					 (length (nth 1 y)))))
		     ((eq byte-compile-call-tree-sort 'calls)
		      #'(lambda (x y) (< (length (nth 2 x))
					 (length (nth 2 y)))))
		     ((eq byte-compile-call-tree-sort 'calls+callers)
		      #'(lambda (x y) (< (+ (length (nth 1 x))
					    (length (nth 2 x)))
					 (+ (length (nth 1 y))
					    (length (nth 2 y))))))
		     ((eq byte-compile-call-tree-sort 'name)
		      #'(lambda (x y) (string< (car x)
					       (car y))))
		     (t (error
		      "`byte-compile-call-tree-sort': `%s' - unknown sort mode"
			       byte-compile-call-tree-sort))))))
    (message "Generating call tree...")
    (let ((rest byte-compile-call-tree)
	  (b (current-buffer))
	  f p
	  callers calls)
      (while rest
	(prin1 (car (car rest)) b)
	(setq callers (nth 1 (car rest))
	      calls (nth 2 (car rest)))
	(insert "\t"
	  (cond ((not (fboundp (setq f (car (car rest)))))
		 (if (null f)
		     " <top level>";; shouldn't insert nil then, actually -sk
		   " <not defined>"))
		((subrp (setq f (symbol-function f)))
		 " <subr>")
		((symbolp f)
		 (format " ==> %s" f))
		((compiled-function-p f)
		 "<compiled function>")
		((not (consp f))
		 "<malformed function>")
		((eq 'macro (car f))
		 (if (or (compiled-function-p (cdr f))
			 (assq 'byte-code (cdr (cdr (cdr f)))))
		     " <compiled macro>"
		   " <macro>"))
		((assq 'byte-code (cdr (cdr f)))
		 "<compiled lambda>")
		((eq 'lambda (car f))
		 "<function>")
		(t "???"))
	  (format " (%d callers + %d calls = %d)"
		  ;; Does the optimizer eliminate common subexpressions?-sk
		  (length callers)
		  (length calls)
		  (+ (length callers) (length calls)))
	  "\n")
	(if callers
	    (progn
	      (insert "  called by:\n")
	      (setq p (point))
	      (insert "    " (if (car callers)
				 (mapconcat 'symbol-name callers ", ")
			       "<top level>"))
	      (let ((fill-prefix "    "))
		(fill-region-as-paragraph p (point)))))
	(if calls
	    (progn
	      (insert "  calls:\n")
	      (setq p (point))
	      (insert "    " (mapconcat 'symbol-name calls ", "))
	      (let ((fill-prefix "    "))
		(fill-region-as-paragraph p (point)))))
	(insert "\n")
	(setq rest (cdr rest)))

      (message "Generating call tree...(finding uncalled functions...)")
      (setq rest byte-compile-call-tree)
      (let ((uncalled nil))
	(while rest
	  (or (nth 1 (car rest))
	      (null (setq f (car (car rest))))
	      (byte-compile-fdefinition f t)
	      (commandp (byte-compile-fdefinition f nil))
	      (setq uncalled (cons f uncalled)))
	  (setq rest (cdr rest)))
	(if uncalled
	    (let ((fill-prefix "  "))
	      (insert "Noninteractive functions not known to be called:\n  ")
	      (setq p (point))
	      (insert (mapconcat 'symbol-name (nreverse uncalled) ", "))
	      (fill-region-as-paragraph p (point)))))
      )
    (message "Generating call tree...done.")
    ))


;;; by crl@newton.purdue.edu
;;;  Only works noninteractively.
;;;###autoload
(defun batch-byte-compile ()
  "Run `byte-compile-file' on the files remaining on the command line.
Use this from the command line, with `-batch';
it won't work in an interactive Emacs.
Each file is processed even if an error occurred previously.
For example, invoke \"xemacs -batch -f batch-byte-compile $emacs/ ~/*.el\"."
  ;; command-line-args-left is what is left of the command line (from
  ;; startup.el)
  (defvar command-line-args-left)	;Avoid 'free variable' warning
  (if (not noninteractive)
      (error "`batch-byte-compile' is to be used only with -batch"))
  (let ((error nil))
    (while command-line-args-left
      (if (null (batch-byte-compile-one-file))
	  (setq error t)))
    (message "Done")
    (kill-emacs (if error 1 0))))

;;;###autoload
(defun batch-byte-compile-one-file ()
  "Run `byte-compile-file' on a single file remaining on the command line.
Use this from the command line, with `-batch';
it won't work in an interactive Emacs."
  ;; command-line-args-left is what is left of the command line (from
  ;; startup.el)
  (defvar command-line-args-left)	;Avoid 'free variable' warning
  (if (not noninteractive)
      (error "`batch-byte-compile-one-file' is to be used only with -batch"))
  (let (error
	(file-to-process (car command-line-args-left)))
    (setq command-line-args-left (cdr command-line-args-left))
    (if (file-directory-p (expand-file-name file-to-process))
	(let ((files (directory-files file-to-process))
	      source dest)
	  (while files
	    (if (and (string-match emacs-lisp-file-regexp (car files))
		     (not (auto-save-file-name-p (car files)))
		     (setq source (expand-file-name
				   (car files)
				   file-to-process))
		     (setq dest (byte-compile-dest-file source))
		     (file-exists-p dest)
		     (file-newer-than-file-p source dest))
		(if (null (batch-byte-compile-1 source))
		    (setq error t)))
	    (setq files (cdr files)))
	  (null error))
      (batch-byte-compile-1 file-to-process))))

(defun batch-byte-compile-1 (file)
  (condition-case err
      (progn (byte-compile-file file) t)
    (error
     (princ ">>Error occurred processing ")
     (princ file)
     (princ ": ")
     (if (fboundp 'display-error) ; XEmacs 19.8+
	 (display-error err nil)
       (princ (or (get (car err) 'error-message) (car err)))
       (mapc #'(lambda (x) (princ " ") (prin1 x)) (cdr err)))
     (princ "\n")
     nil)))

;;;###autoload
(defun batch-byte-recompile-directory-norecurse ()
  "Same as `batch-byte-recompile-directory' but without recursion."
  (setq byte-recompile-directory-recursively nil)
  (batch-byte-recompile-directory))

;;;###autoload
(defun batch-byte-recompile-directory (&optional arg)
  "Runs `byte-recompile-directory' on the dirs remaining on the command line.
Must be used only with `-batch', and kills Emacs on completion.
For example, invoke `xemacs -batch -f batch-byte-recompile-directory .'.

The optional argument is passed to `byte-recompile-directory' as the
prefix argument; see the documentation there for its meaing.
In particular, passing 0 means to compile files for which no `.elc' files
exist."
  ;; command-line-args-left is what is left of the command line (startup.el)
  (defvar command-line-args-left)	;Avoid 'free variable' warning
  (if (not noninteractive)
      (error "batch-byte-recompile-directory is to be used only with -batch"))
  (or command-line-args-left
      (setq command-line-args-left '(".")))
  (let ((byte-recompile-directory-ignore-errors-p t))
    (while command-line-args-left
      (byte-recompile-directory (car command-line-args-left) arg)
      (setq command-line-args-left (cdr command-line-args-left))))
  (kill-emacs 0))

(make-obsolete 'elisp-compile-defun 'compile-defun)
(make-obsolete 'byte-compile-report-call-tree 'display-call-tree)

;; other make-obsolete calls in obsolete.el.

(provide 'byte-compile)
(provide 'bytecomp)


;;; report metering (see the hacks in bytecode.c)

(if (boundp 'byte-code-meter)
    (defun byte-compile-report-ops ()
      (defvar byte-code-meter)
      (with-output-to-temp-buffer "*Meter*"
	(set-buffer "*Meter*")
	(let ((i 0) n op off)
	  (while (< i 256)
	    (setq n (aref (aref byte-code-meter 0) i)
		  off nil)
	    (if t ;(not (zerop n))
		(progn
		  (setq op i)
		  (setq off nil)
		  (cond ((< op byte-nth)
			 (setq off (logand op 7))
			 (setq op (logand op 248)))
			((>= op byte-constant)
			 (setq off (- op byte-constant)
			       op byte-constant)))
		  (setq op (aref byte-code-vector op))
		  (insert (format "%-4d" i))
		  (insert (symbol-name op))
		  (if off (insert " [" (int-to-string off) "]"))
		  (indent-to 40)
		  (insert (int-to-string n) "\n")))
	    (setq i (1+ i)))))))


;; To avoid "lisp nesting exceeds max-lisp-eval-depth" when bytecomp compiles
;; itself, compile some of its most used recursive functions (at load time).
;;
(eval-when-compile
 (or (compiled-function-p (symbol-function 'byte-compile-form))
     (let ((byte-optimize nil) ; do it fast
	   (byte-compile-warnings nil))
       (map nil (if noninteractive
		    #'byte-compile
		  #'(lambda (x)
		      (message "compiling %s..." x)
		      (byte-compile x)
		      (message "compiling %s...done" x)))
	    '(byte-compile-normal-call
	      byte-compile-form
	      byte-compile-body
	      ;; Inserted some more than necessary, to speed it up.
	      byte-compile-top-level
	      byte-compile-out-toplevel
	      byte-compile-constant
	      byte-compile-variable-ref)))))

;;; Some packages byte-compile with -no-autoloads, so this is necessary:
(autoload 'cl-compile-time-init "cl-macs")

;; XEmacs; call this explicitly, don't implement it using bytecomp-load-hook.
(cl-compile-time-init)

(run-hooks 'bytecomp-load-hook)

;;; bytecomp.el ends here