**FREE

///
// \brief BlueDroplet : Simple Hello World Example
//
// This example shows how to compose and start the server and how
// to register a REST end point at the server.
//
// The end point registers for HTTP GET method and returns the text
// "Hello World".
//
// \author Mihael Schmidt
// \date   19.01.2017
//
///


ctl-opt main(main) dftactgrp(*no) actgrp(*caller);


//-------------------------------------------------------------------------------------------------
// Prototypes
//-------------------------------------------------------------------------------------------------
/include 'bluedroplet/bluedroplet_h.rpgle'

dcl-pr main extpgm('BDHELLO') end-pr;

dcl-pr sayHello extproc('sayHello');
  service pointer const;
  connection pointer const;
  message pointer const;
  endpoint pointer const;
end-pr;


//-------------------------------------------------------------------------------------------------
// Procedures
//-------------------------------------------------------------------------------------------------
dcl-proc main;
  dcl-s service pointer;

  service = droplet_service_create();

  droplet_service_enableLogging(service : *on);
  droplet_service_setLogLevel(service : DROPLET_LOG_LEVEL_DEBUG);

  droplet_service_addEndPoint(service : %paddr('sayHello') : '/say' : DROPLET_GET);

  droplet_service_start(service);

  droplet_service_finalize(service);
end-proc;


///
// \brief Say Hello World
//
// This method returns the string "Hello World".
//
// \param REST service instance
// \param Connection
// \param HTTP message
///
dcl-proc sayHello export;
  dcl-pi *N;
    service pointer const;
    connection pointer const;
    message pointer const;
    endpoint pointer const;
  end-pi;

  droplet_service_send(connection : DROPLET_OK : 'Hello World' : DROPLET_TEXT);
end-proc;