Source

baseten / Sources / PGTSSchemaDescription.mm

//
// PGTSSchemaDescription.mm
// BaseTen
//
// Copyright (C) 2006-2009 Marko Karppinen & Co. LLC.
//
// Before using this software, please review the available licensing options
// by visiting http://www.karppinen.fi/baseten/licensing/ or by contacting
// us at sales@karppinen.fi. Without an additional license, this software
// may be distributed only in compliance with the GNU General Public License.
//
//
// This program is free software; you can redistribute it and/or modify
// it under the terms of the GNU General Public License, version 2.0,
// as published by the Free Software Foundation.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program; if not, write to the Free Software
// Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
//
// $Id$
//

#import "PGTSSchemaDescription.h"
#import "PGTSHOM.h"
#import "PGTSTableDescription.h"
#import "PGTSCollections.h"
#import "BXLogger.h"


using namespace PGTS;


@implementation PGTSSchemaDescription
- (id) init
{
	if ((self = [super init]))
	{
		mTablesByName = new IdMap ();
		mTableLock = [[NSLock alloc] init];
	}
	return self;
}


- (void) dealloc
{
	for (IdMap::const_iterator it = mTablesByName->begin (); mTablesByName->end () != it; it++)
	{
		[it->first release];
		[it->second release];
	}
	delete mTablesByName;
	
	[mAllTables release];
	[mTableLock release];
	[super dealloc];
}


- (void) finalize
{
	delete mTablesByName;
	[super finalize];
}


- (PGTSTableDescription *) tableNamed: (NSString *) name
{
	Expect (name);
	return FindObject (mTablesByName, name);
}


- (void) addTable: (PGTSTableDescription *) table
{
	ExpectV (table);
	[mTableLock lock];
	if (mAllTables)
	{
		[mAllTables release];
		mAllTables = nil;
	}
	[mTableLock unlock];
	InsertConditionally (mTablesByName, table);
}

- (NSArray *) allTables
{
	[mTableLock lock];
	if (! mAllTables)
	{
		NSMutableArray* tables = [NSMutableArray arrayWithCapacity: mTablesByName->size ()];
		for (IdMap::const_iterator it = mTablesByName->begin (), end = mTablesByName->end ();
			 it != end; it++)
		{
			[tables addObject: it->second];
		}
		mAllTables = [tables copy];
	}
	[mTableLock unlock];
	return [[mAllTables retain] autorelease];
}
@end
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.