Commits

Howard Lewis Ship committed bd9f406

Tag version 1.6.0-annadale-5

  • Participants
  • Parent commits a8a8d2b

Comments (0)

Files changed (1)

File build.gradle

+buildscript {
+    repositories {
+        mavenCentral()
+        maven { url "http://clojars.org/repo" }
+    }
+
+    dependencies {
+        classpath "de.kotka.gradle:gradle-plugin:1.1.0"
+    }
+}
+
+apply plugin: 'idea'
+
+subprojects {
+    group = 'clojuresque'
+    version = '1.6.0-annadale-5'
+
+    ext.kotka = [
+        repository:     "clojuresque/clojuresque",
+        wrapperVersion: "1.8"
+    ]
+
+    apply {
+        plugin 'java'
+        plugin 'kotka'
+        plugin 'idea'
+    }
+
+    repositories {
+        mavenCentral()
+    }
+
+    apply plugin: "maven-publish"
+
+    task sourceJar (type : Jar) {
+        classifier = 'sources'
+        from sourceSets.main.allSource
+    }
+
+    publishing {
+        publications {
+            jar(MavenPublication) {
+                from components.java
+
+                artifact (sourceJar) { // (2)
+                    classifier = 'sources'
+                }
+            }
+        }
+        repositories {
+            maven {
+                url "https://mvn.annadaletech.com/nexus/content/repositories/${project.version.endsWith('-SNAPSHOT') ? 'snapshots' : 'releases'}"
+                credentials {
+                    username = mavenUser
+                    password = mavenPassword
+                }
+            }
+        }
+    }
+
+
+}
+
+project(':clojuresque') {
+    description = "A Clojure compilation/execution plugin"
+
+    apply {
+        plugin 'groovy'
+    }
+
+    dependencies {
+        compile gradleApi()
+        compile localGroovy()
+
+        compile "de.kotka.gradle:gradle-utils:0.1.1"
+
+        testCompile('org.spockframework:spock-core:0.7-groovy-1.8') {
+            exclude group: 'org.codehaus.groovy', module: 'groovy-all'
+        }
+    }
+
+    compileJava {
+        sourceCompatibility = "1.6"
+        targetCompatibility = "1.6"
+    }
+
+    compileGroovy {
+        sourceCompatibility = "1.6"
+        targetCompatibility = "1.6"
+    }
+
+    processResources {
+        inputs.property "version", {-> project.version}
+        from(sourceSets.main.resources.srcDirs) {
+            expand("version": project.version)
+        }
+    }
+}
+
+project(':clojuresque-runtime') {
+    description = "Clojure compilation/execution runtime support"
+
+    repositories {
+        mavenRepo name: 'clojars', url: 'http://clojars.org/repo'
+    }
+
+    configurations {
+        provided
+    }
+
+    dependencies {
+        provided 'org.clojure:clojure:1.6.0'
+        compile 'io.aviso:pretty:0.1.12'
+    }
+
+    idea.module {
+        scopes.COMPILE.plus += configurations.provided
+    }
+
+    compileJava {
+        sourceCompatibility = "1.6"
+        targetCompatibility = "1.6"
+    }
+
+}
+
+task wrapper(type: Wrapper) {
+    gradleVersion = "1.8"
+}