clojuresque / build.gradle

The default branch has multiple heads

subprojects {
    group = 'clojuresque'
    version = '1.5.4-SNAPSHOT'

    ext.isReleaseVersion = !version.endsWith("SNAPSHOT")

    apply {
        plugin 'signing'
        plugin 'maven'
    }

    repositories {
        maven { url "http://127.0.0.1:8080/repository/internal" }
        mavenCentral()
    }
}

project(':clojuresque') {
    apply {
        plugin 'groovy'
    }

    dependencies {
        compile gradleApi()
        // Workaround for milestone4
        compile fileTree(dir: "${gradle.gradleHomeDir}/lib/plugins", include: '**/*.jar')
        groovy localGroovy()
    }

    processResources {
        from(sourceSets.main.resources.srcDirs) {
            expand("version": project.version)
        }
    }
}

project(':runtime') {
    apply {
        plugin 'java'
    }

    dependencies {
        compile 'org.clojure:clojure:[1.2,1.5)'
    }
}

subprojects {
    configurations {
        deployerJars
    }

    dependencies {
        deployerJars 'org.apache.maven.wagon:wagon-http-lightweight:2.2'
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                configuration = configurations.deployerJars
                repository(url: "https://clojars.org/repo") {
                    authentication(
                        userName: project.properties["clojuresque.clojars.username"],
                        password: project.properties["clojuresque.clojars.password"]
                    )
                }
                pom.project {
                    licenses {
                        license {
                            name 'MIT License'
                            url 'http://opensource.org/licenses/MIT'
                            distribution 'repo'
                        }
                    }
                    description "A Clojure plugin for the Gradle build system"
                    url "http://bitbucket.org/clojuresque/clojuresque"
                    scm {
                        connection 'scm:hg:hg@bitbucket.org:kotarak/clojuresque'
                        developerConnection 'scm:hg:hg@bitbucket.org:kotarak/clojuresque'
                        url 'hg@bitbucket.org:kotarak/clojuresque'
                    }
                }
                beforeDeployment { signing.signPom(it) }
            }
        }
    }

    signing {
        sign configurations.archives
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = "1.0"
}
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.