Source

petsc / src / ts / examples / tutorials / ex22f.F

Full commit
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
! Time-dependent advection-reaction PDE in 1d. Demonstrates IMEX methods
!
!   u_t + a1*u_x = -k1*u + k2*v + s1
!   v_t + a2*v_x = k1*u - k2*v + s2
!   0 < x < 1;
!   a1 = 1, k1 = 10^6, s1 = 0,
!   a2 = 0, k2 = 2*k1, s2 = 1
!
!   Initial conditions:
!   u(x,0) = 1 + s2*x
!   v(x,0) = k0/k1*u(x,0) + s1/k1
!
!   Upstream boundary conditions:
!   u(0,t) = 1-sin(12*t)^4
!

      program main
      implicit none
#include <finclude/petscsys.h>
#include <finclude/petscvec.h>
#include <finclude/petscmat.h>
#include <finclude/petscsnes.h>
#include <finclude/petscts.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
!
!  Create an application context to contain data needed by the
!  application-provided call-back routines, FormJacobian() and
!  FormFunction(). We use a double precision array with six
!  entries, two for each problem parameter a, k, s.
!
      PetscReal user(6)
      integer user_a,user_k,user_s
      parameter (user_a = 0,user_k = 2,user_s = 4)

      external FormRHSFunction,FormIFunction,FormIJacobian
      external FormInitialSolution

      TS             ts
      SNES           snes
      SNESLineSearch linesearch
      Vec            X
      Mat            J
      PetscInt       steps,maxsteps,mx
      PetscErrorCode ierr
      DM             da
      PetscReal      ftime,dt
      PetscReal      zero,one,pone
      PetscInt       im11,i2
      PetscBool      flg

      im11 = -11
      i2   = 2
      zero = 0.0
      one = 1.0
      pone = one / 10

      call PetscInitialize(PETSC_NULL_CHARACTER,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  Create distributed array (DMDA) to manage parallel grid and vectors
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call DMDACreate1d(PETSC_COMM_WORLD,DM_BOUNDARY_NONE,im11,i2,i2,   &
     &     PETSC_NULL_INTEGER,da,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!    Extract global vectors from DMDA;
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call DMCreateGlobalVector(da,X,ierr)

! Initialize user application context
! Use zero-based indexing for command line parameters to match ex22.c
      user(user_a+1) = 1.0
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-a0',              &
     &     user(user_a+1),flg,ierr)
      user(user_a+2) = 0.0
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-a1',              &
     &     user(user_a+2),flg,ierr)
      user(user_k+1) = 1000000.0
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-k0',              &
     &     user(user_k+1),flg,ierr)
      user(user_k+2) = 2*user(user_k+1)
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-k1',              &
     &     user(user_k+2),flg,ierr)
      user(user_s+1) = 0.0
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-s0',              &
     &     user(user_s+1),flg,ierr)
      user(user_s+2) = 1.0
      call PetscOptionsGetReal(PETSC_NULL_CHARACTER,'-s1',              &
     &     user(user_s+2),flg,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!    Create timestepping solver context
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call TSCreate(PETSC_COMM_WORLD,ts,ierr)
      call TSSetDM(ts,da,ierr)
      call TSSetType(ts,TSARKIMEX,ierr)
      call TSSetRHSFunction(ts,PETSC_NULL_OBJECT,FormRHSFunction,       &
     &     user,ierr)
      call TSSetIFunction(ts,PETSC_NULL_OBJECT,FormIFunction,user,ierr)
      call DMSetMatType(da,MATAIJ,ierr)
      call DMCreateMatrix(da,J,ierr)
      call TSSetIJacobian(ts,J,J,FormIJacobian,user,ierr)

      call TSGetSNES(ts,snes,ierr)
      call SNESGetLineSearch(snes,linesearch,ierr)
      call SNESLineSearchSetType(linesearch,SNESLINESEARCHBASIC,ierr)

      ftime = 1.0
      maxsteps = 10000
      call TSSetDuration(ts,maxsteps,ftime,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  Set initial conditions
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call FormInitialSolution(ts,X,user,ierr)
      call TSSetSolution(ts,X,ierr)
      call VecGetSize(X,mx,ierr)
!  Advective CFL, I don't know why it needs so much safety factor.
      dt = pone * max(user(user_a+1),user(user_a+2)) / mx;
      call TSSetInitialTimeStep(ts,zero,dt,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!   Set runtime options
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call TSSetFromOptions(ts,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  Solve nonlinear system
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call TSSolve(ts,X,ierr)

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  Free work space.
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
      call MatDestroy(J,ierr)
      call VecDestroy(X,ierr)
      call TSDestroy(ts,ierr)
      call DMDestroy(da,ierr)
      call PetscFinalize(ierr)
      end program

! Small helper to extract the layout, result uses 1-based indexing.
      subroutine GetLayout(da,mx,xs,xe,gxs,gxe,ierr)
      implicit none
#include <finclude/petscsys.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
      DM da
      PetscInt mx,xs,xe,gxs,gxe
      PetscErrorCode ierr
      PetscInt xm,gxm
            call DMDAGetInfo(da,PETSC_NULL_INTEGER,                     &
     &     mx,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,                    &
     &     PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,    &
     &     PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,                       &
     &     PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,    &
     &     PETSC_NULL_INTEGER,ierr)
      call DMDAGetCorners(da,xs,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,  &
     &     xm,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,ierr)
      call DMDAGetGhostCorners(da,                                      &
     &     gxs,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,                   &
     &     gxm,PETSC_NULL_INTEGER,PETSC_NULL_INTEGER,ierr)
      xs = xs + 1
      gxs = gxs + 1
      xe = xs + xm - 1
      gxe = gxs + gxm - 1
      end subroutine

      subroutine FormIFunctionLocal(mx,xs,xe,gxs,gxe,x,xdot,f,          &
     &     a,k,s,ierr)
      implicit none
      PetscInt mx,xs,xe,gxs,gxe
      PetscScalar x(2,xs:xe)
      PetscScalar xdot(2,xs:xe)
      PetscScalar f(2,xs:xe)
      PetscReal a(2),k(2),s(2)
      PetscErrorCode ierr
      PetscInt i
      do 10 i = xs,xe
         f(1,i) = xdot(1,i) + k(1)*x(1,i) - k(2)*x(2,i) - s(1)
         f(2,i) = xdot(2,i) - k(1)*x(1,i) + k(2)*x(2,i) - s(2)
 10   continue
      end subroutine

      subroutine FormIFunction(ts,t,X,Xdot,F,user,ierr)
      implicit none
#include <finclude/petscsys.h>
#include <finclude/petscvec.h>
#include <finclude/petscmat.h>
#include <finclude/petscsnes.h>
#include <finclude/petscts.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
      TS ts
      PetscReal t
      Vec X,Xdot,F
      PetscReal user(6)
      PetscErrorCode ierr
      integer user_a,user_k,user_s
      parameter (user_a = 1,user_k = 3,user_s = 5)

      DM             da
      PetscInt       mx,xs,xe,gxs,gxe
      PetscOffset    ixx,ixxdot,iff
      PetscScalar    xx(0:1),xxdot(0:1),ff(0:1)

      call TSGetDM(ts,da,ierr)
      call GetLayout(da,mx,xs,xe,gxs,gxe,ierr)

! Get access to vector data
      call VecGetArray(X,xx,ixx,ierr)
      call VecGetArray(Xdot,xxdot,ixxdot,ierr)
      call VecGetArray(F,ff,iff,ierr)

      call FormIFunctionLocal(mx,xs,xe,gxs,gxe,                         &
     &     xx(ixx),xxdot(ixxdot),ff(iff),                               &
     &     user(user_a),user(user_k),user(user_s),ierr)

      call VecRestoreArray(X,xx,ixx,ierr)
      call VecRestoreArray(Xdot,xxdot,ixxdot,ierr)
      call VecRestoreArray(F,ff,iff,ierr)
      end subroutine

      subroutine FormRHSFunctionLocal(mx,xs,xe,gxs,gxe,t,x,f,           &
     &     a,k,s,ierr)
      implicit none
      PetscInt mx,xs,xe,gxs,gxe
      PetscReal t
      PetscScalar x(2,gxs:gxe),f(2,xs:xe)
      PetscReal a(2),k(2),s(2)
      PetscErrorCode ierr
      PetscInt i,j
      PetscReal hx,u0t(2)
      PetscReal one,two,three,four,six,twelve
      PetscReal half,third,twothird,sixth
      PetscReal twelfth

      one = 1.0
      two = 2.0
      three = 3.0
      four = 4.0
      six = 6.0
      twelve = 12.0
      hx = one / mx
      u0t(1) = one - sin(twelve*t)**four
      u0t(2) = 0.0
      half = one/two
      third = one / three
      twothird = two / three
      sixth = one / six
      twelfth = one / twelve
      do 20 i = xs,xe
         do 10 j = 1,2
            if (i .eq. 1) then
               f(j,i) = a(j)/hx*(third*u0t(j) + half*x(j,i) - x(j,i+1)  &
     &              + sixth*x(j,i+2))
            else if (i .eq. 2) then
               f(j,i) = a(j)/hx*(-twelfth*u0t(j) + twothird*x(j,i-1)    &
     &              - twothird*x(j,i+1) + twelfth*x(j,i+2))
            else if (i .eq. mx-1) then
               f(j,i) = a(j)/hx*(-sixth*x(j,i-2) + x(j,i-1)             &
     &         - half*x(j,i) -third*x(j,i+1))
            else if (i .eq. mx) then
               f(j,i) = a(j)/hx*(-x(j,i) + x(j,i-1))
            else
               f(j,i) = a(j)/hx*(-twelfth*x(j,i-2)                      &
     &              + twothird*x(j,i-1)                                 &
     &              - twothird*x(j,i+1) + twelfth*x(j,i+2))
            end if
 10      continue
 20   continue
      end subroutine

      subroutine FormRHSFunction(ts,t,X,F,user,ierr)
      implicit none
#include <finclude/petscsys.h>
#include <finclude/petscvec.h>
#include <finclude/petscmat.h>
#include <finclude/petscsnes.h>
#include <finclude/petscts.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
      TS ts
      PetscReal t
      Vec X,F
      PetscReal user(6)
      PetscErrorCode ierr
      integer user_a,user_k,user_s
      parameter (user_a = 1,user_k = 3,user_s = 5)
      DM             da
      Vec            Xloc
      PetscInt       mx,xs,xe,gxs,gxe
      PetscOffset    ixx,iff
      PetscScalar    xx(0:1),ff(0:1)

      call TSGetDM(ts,da,ierr)
      call GetLayout(da,mx,xs,xe,gxs,gxe,ierr)

!     Scatter ghost points to local vector,using the 2-step process
!        DMGlobalToLocalBegin(),DMGlobalToLocalEnd().
!     By placing code between these two statements, computations can be
!     done while messages are in transition.
      call DMGetLocalVector(da,Xloc,ierr)
      call DMGlobalToLocalBegin(da,X,INSERT_VALUES,Xloc,ierr)
      call DMGlobalToLocalEnd(da,X,INSERT_VALUES,Xloc,ierr)

! Get access to vector data
      call VecGetArray(Xloc,xx,ixx,ierr)
      call VecGetArray(F,ff,iff,ierr)

      call FormRHSFunctionLocal(mx,xs,xe,gxs,gxe,                       &
     &     t,xx(ixx),ff(iff),                                           &
     &     user(user_a),user(user_k),user(user_s),ierr)

      call VecRestoreArray(Xloc,xx,ixx,ierr)
      call VecRestoreArray(F,ff,iff,ierr)
      call DMRestoreLocalVector(da,Xloc,ierr)
      end subroutine

! ---------------------------------------------------------------------
!
!  IJacobian - Compute IJacobian = dF/dU + shift*dF/dUdot
!
      subroutine FormIJacobian(ts,t,X,Xdot,shift,J,Jpre,mstr,user,ierr)
      implicit none
#include <finclude/petscsys.h>
#include <finclude/petscvec.h>
#include <finclude/petscmat.h>
#include <finclude/petscsnes.h>
#include <finclude/petscts.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
      TS ts
      PetscReal t,shift
      Vec X,Xdot
      Mat J,Jpre
      MatStructure mstr
      PetscReal user(6)
      PetscErrorCode ierr
      integer user_a,user_k,user_s
      parameter (user_a = 0,user_k = 2,user_s = 4)

      DM             da
      PetscInt       mx,xs,xe,gxs,gxe
      PetscInt       i,i1,row,col
      PetscReal      k1,k2;
      PetscScalar    val(4)

      call TSGetDM(ts,da,ierr)
      call GetLayout(da,mx,xs,xe,gxs,gxe,ierr)

      i1 = 1
      k1 = user(user_k+1)
      k2 = user(user_k+2)
      do 10 i = xs,xe
         row = i-gxs
         col = i-gxs
         val(1) = shift + k1
         val(2) = -k2
         val(3) = -k1
         val(4) = shift + k2
         call MatSetValuesBlockedLocal(Jpre,i1,row,i1,col,val,          &
     &        INSERT_VALUES,ierr)
 10   continue
      call MatAssemblyBegin(Jpre,MAT_FINAL_ASSEMBLY,ierr)
      call MatAssemblyEnd(Jpre,MAT_FINAL_ASSEMBLY,ierr)
      if (J /= Jpre) then
         call MatAssemblyBegin(J,MAT_FINAL_ASSEMBLY,ierr)
         call MatAssemblyEnd(J,MAT_FINAL_ASSEMBLY,ierr)
      end if
      mstr = SAME_NONZERO_PATTERN
      end subroutine

      subroutine FormInitialSolutionLocal(mx,xs,xe,gxs,gxe,x,a,k,s,ierr)
      implicit none
      PetscInt mx,xs,xe,gxs,gxe
      PetscScalar x(2,xs:xe)
      PetscReal a(2),k(2),s(2)
      PetscErrorCode ierr

      PetscInt i
      PetscReal one,hx,r,ik
      one = 1.0
      hx = one / mx
      do 10 i=xs,xe
         r = i*hx
         if (k(2) .ne. 0.0) then
            ik = one/k(2)
         else
            ik = one
         end if
         x(1,i) = one + s(2)*r
         x(2,i) = k(1)*ik*x(1,i) + s(2)*ik
 10   continue
      end subroutine

      subroutine FormInitialSolution(ts,X,user,ierr)
      implicit none
#include <finclude/petscsys.h>
#include <finclude/petscvec.h>
#include <finclude/petscmat.h>
#include <finclude/petscsnes.h>
#include <finclude/petscts.h>
#include <petscdm.h>
#include <finclude/petscdmda.h>
      TS ts
      Vec X
      PetscReal user(6)
      PetscErrorCode ierr
      integer user_a,user_k,user_s
      parameter (user_a = 1,user_k = 3,user_s = 5)

      DM             da
      PetscInt       mx,xs,xe,gxs,gxe
      PetscOffset    ixx
      PetscScalar    xx(0:1)

      call TSGetDM(ts,da,ierr)
      call GetLayout(da,mx,xs,xe,gxs,gxe,ierr)

! Get access to vector data
      call VecGetArray(X,xx,ixx,ierr)

      call FormInitialSolutionLocal(mx,xs,xe,gxs,gxe,                       &
     &     xx(ixx),user(user_a),user(user_k),user(user_s),ierr)

      call VecRestoreArray(X,xx,ixx,ierr)
      end subroutine