Source

pkgbuild / pure-hg / PKGBUILD

# Maintainer: Alastair Pharo  asppsa at gmail dot com

pkgname=pure-hg
pkgver=5092.686ece85287b
pkgrel=1
pkgdesc="Pure is a modern-style functional programming language based on term rewriting."
arch=("i686" "x86_64")
license=('LGPL3')
url="http://purelang.bitbucket.org/"
depends=('llvm' 'gmp' 'mpfr' 'readline')
makedepends=('autoconf' 'automake' 'bison' 'flex' 'gcc' 'make' 'mercurial')
optdepends=("pure-docs-hg: online documentation"
            "w3m: access to help in interactive mode"
            "emacs-pure-mode: editing Pure files from Emacs"
            "texmacs-pure: embedding Pure sessions in TeXmacs")
provides=('pure=0.58')
conflicts=('pure')
source=("hg+https://bitbucket.org/purelang/pure-lang")
md5sums=(SKIP)

pkgver() {
  cd $srcdir/pure-lang
  echo $(hg identify -n).$(hg identify -i)
}

build() {
  cd $srcdir/pure-lang/pure
  autoreconf
  ./configure --enable-release --prefix=/usr --without-elisp --without-texmacs
  make || return 1
}

package() {
  cd "$srcdir/pure-lang/pure"
  make DESTDIR=$pkgdir install || return 1
}

# vim:set ts=2 sw=2 et: