Source

LWJGL Shader Tutorials / src / main / java / com / ra4king / opengl / arcsynthesis / gl33 / chapter11 / example1 / example11.1.NoPhong.frag

Full commit
Roi Atalla d1fc402 


































#version 330

in vec4 diffuseColor;
in vec3 vertexNormal;
in vec3 cameraSpacePosition;

out vec4 outputColor;

uniform vec3 modelSpaceLightPos;

uniform vec4 lightIntensity;
uniform vec4 ambientIntensity;

uniform vec3 cameraSpaceLightPos;

uniform float lightAttenuation;

vec4 ApplyLightIntensity(in vec3 cameraSpacePosition, out vec3 lightDirection)
{
	vec3 lightDifference = cameraSpaceLightPos - cameraSpacePosition;
	float lightDistanceSqr = dot(lightDifference, lightDifference);
	lightDirection = lightDifference * inversesqrt(lightDistanceSqr);
	
	return lightIntensity / (1 + lightAttenuation * sqrt(lightDistanceSqr));
}

void main()
{
	vec3 lightDir = vec3(0);
	vec4 attenIntensity = ApplyLightIntensity(cameraSpacePosition, lightDir);
	
	float cosAngIncidence = dot(normalize(vertexNormal), lightDir);
	cosAngIncidence = clamp(cosAngIncidence, 0, 1);
	
	outputColor = diffuseColor * attenIntensity * cosAngIncidence + diffuseColor * ambientIntensity;
}