Home

Welcome

Welcome! This repository is a Mercurial mirror of the official Far Manager's Subversion repository.

Conversion script

I used the following script in order to get the original Subversion repository converted into Mercurial (it is also used to get updates as well):

@ECHO OFF
SETLOCAL

SET sourceRepo=http://farmanager.com/svn/
SET destRepoName=FarManager
SET repoName=%destRepoName%-svn

:: Mirror Subversion repository
SET mirrorUri=%~dp0
:: replace '\' with '/'
SET mirrorUri=file:///%mirrorUri:\=/%%repoName%

:: Initialize local Subversion repository
IF EXIST %repoName% GOTO skipInit
ECHO Initializing %mirrorUri%...
svnadmin create "%repoName%" > NUL
ECHO @EXIT 0 > "%repoName%/hooks/pre-revprop-change.bat"
svnsync init "%mirrorUri%" %sourceRepo% > NUL

:skipInit
:: Synchronize local Subversion mirror
ECHO Synchronising %mirrorUri%...
svnsync sync "%mirrorUri%"
ECHO.
IF ERRORLEVEL 1 GOTO cleanup

:: Convert local trunk of the Subversion mirror to Mercurial
ECHO Converting to Mercurial...
hg --config extensions.convert= convert "%mirrorUri%/trunk" %destRepoName%
ECHO.

:cleanup
ENDLOCAL

Utilities used

The conversion script require following utilities installed (or their alternatives):

Updated

Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.