Source

Ogre3D-d3d11 / Scripts / makesourcerelease.bat

@echo off
if "%1" == "" goto paramErr

set tag=%1
set foldername=ogre_src_%tag%

rem You can set OGRE_RELEASE_CLONE_SOURCE to a local repo if you want to speed things up
if "%OGRE_RELEASE_CLONE_SOURCE%" == "" SET OGRE_RELEASE_CLONE_SOURCE=http://bitbucket.org/sinbad/ogre

rem Clean down existing snapshot area
echo Cleaning up %foldername%...
rmdir /S/Q %foldername%
rem Clone ogre from local copy (you should make sure this includes the tag)
echo Cloning...
hg clone -r %tag% %OGRE_RELEASE_CLONE_SOURCE% %foldername%
rem Build configure
pushd %foldername%
rem delete repo, we only want working copy
echo Remove repository...
rmdir /S/Q .hg
rem Gen docs
cd Docs\src
doxygen html.cfg
rem remove unnecessary files
cd ..\api\html
del /Q/F *.hhk *.hhc *.map *.md5 *.dot *.hhp *.plist ..\*.tmp
popd

rem Make self-extracting zip
del /Q/F %foldername%.exe
rem create self-extracting 7zip archive
7z a -r -y -sfx7z.sfx %foldername%.exe %foldername%

goto end

:paramErr
echo You must supply a tag name

:end
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.