Source

ocaml-lib / dcg / dcg.ml

Full commit
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467

let trace = ref false

let get_trace () = !trace
let set_trace b = trace := b

let union_msgs msgs1 msgs2 = LSet.union msgs1 msgs2

module Locator = Msg.Locator
type  msg = {exn : exn; loc : Locator.t}

type ('cursor, 'ctx, 'res) result = Parsed of 'ctx * 'res * 'cursor | Failed of msg LSet.t

let msgs_exn exn cursor =
  [{exn; loc = Locator.Point cursor#coord}]

let msgs_failure str cursor =
  if str = ""
  then []
  else msgs_exn (Failure str) cursor


class type ['ctx, 'res, 'cursor] p =
  object
    method next : ('cursor, 'ctx, 'res) result
  end

type ('ctx, 'res, 'cursor) parse = 'ctx -> 'cursor -> ('ctx, 'res, 'cursor) p

class ['ctx,'res,'cursor] fail (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    method next : ('cursor, 'ctx, 'res) result = Failed []
  end

let fail = new fail

class ['ctx,'res,'cursor] raise_exn (exn : exn) (ctx : 'ctx) (cursor : 'cursor) =
object (self)
  method next : ('cursor,'ctx,'res) result = Failed (msgs_exn exn cursor)
end

let raise_exn exn = new raise_exn exn

class ['ctx, 'cursor] rise (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  Parsed (ctx, cursor, cursor)
      | `End ->
	  Failed []
  end

let rise = new rise

class ['ctx, 'res0, 'res, 'cursor] map (parse : ('ctx, 'res0, 'cursor) parse) (f : 'res0 -> 'res) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin (parse ctx cursor)

    method next =
      match state with
      | `Begin p ->
	  ( match p # next with
	  | Parsed (ctx1, res0, cursor') ->
	      Parsed (ctx1, f res0, cursor')
	  | Failed msgs ->
	      state <- `End msgs;
	      self#next)
      | `End msgs -> Failed msgs
  end

let map = new map
let (-->) = map

class ['ctx, 'res, 'cursor] ret (res : 'res) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next : ('cursor,'ctx,'res) result =
      match state with
      | `Begin ->
	  state <- `End;
	  Parsed (ctx, res, cursor)
      | `End ->
	  Failed []
  end

let ret = new ret

(* syntaxe ideale
   param = p --> expr ==> map p (fun param -> expr)
   --> expr ==> ret expr
*)

class ['ctx, 'res, 'cursor] alt (parse1 : ('ctx, 'res, 'cursor) parse) (parse2 : ('ctx, 'res, 'cursor) parse) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `First (parse1 ctx cursor)

    method next =
      match state with
      | `First p1 ->
	  ( match p1 # next with
	  | Parsed _ as x -> x
	  | Failed msgs1 ->
	      state <- `Second (msgs1, parse2 ctx cursor);
	      self # next)
      | `Second (msgs, p2) ->
	  ( match p2 # next with
	  | Parsed _ as x -> x
	  | Failed msgs2 ->
	      state <- `End (union_msgs msgs2 msgs);
	      self # next)
      | `End msgs -> Failed msgs
  end

let alt = new alt
let (<|>) = alt

(* syntaxe ideale
   p1 | p2 ==> alt p1 p2
*)

class ['ctx, 'res1, 'res, 'cursor] seq (parse1 : ('ctx,'res1,'cursor) parse) (parse2 : 'res1 -> ('ctx,'res,'cursor) parse) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `First ([], parse1 ctx cursor)

    method next =
      match state with
      | `First (msgs, p1) ->
	  ( match p1 # next with
	  | Parsed (ctx1, res1, cursor1) ->
	      state <- `Second (msgs, p1, parse2 res1 ctx1 cursor1);
	      self # next
	  | Failed msgs1 ->
	      state <- `End (union_msgs msgs1 msgs);
	      self # next)
      | `Second (msgs, p1,p2) ->
	  ( match p2 # next with
	  | Parsed _ as x -> x
	  | Failed msgs2 ->
	      state <- `First (union_msgs msgs2 msgs, p1);
	      self # next)
      | `End msgs -> Failed msgs
  end

let seq = new seq
let (|>) = seq
let (|>>) parse1 parse2 = parse1 |> fun _ -> parse2

(* syntaxe ideale
   p1; p2 ==> seq p1 (fun _ -> p2)
   param = p1; p2 ==> seq p1 (fun param -> p2)
*)

class ['ctx,'res1,'res,'cursor] cut (parse1 : ('ctx,'res1,'cursor) parse) (parse2 : 'res1 -> ('ctx,'res,'cursor) parse) (parse3 : ('ctx,'res,'cursor) parse) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `First (parse1 ctx cursor)

    method next =
      match state with
      | `First p1 ->
	  ( match p1 # next with
	  | Parsed (ctx1, res1, cursor1) ->
	      if cursor#at_init then cursor1#init; (* forgetting the past *)
	      state <- `Second (parse2 res1 ctx1 cursor1);
	      self # next
	  | Failed msgs1 ->
	      state <- `Third (msgs1, parse3 ctx cursor);
	      self # next)
      | `Second p2 ->
	  ( match p2 # next with
	  | Parsed _ as x -> x
	  | Failed msgs2 ->
	      state <- `End msgs2;
	      self#next)
      | `Third (msgs, p3) ->
	  ( match p3 # next with
	  | Parsed _ as x -> x
	  | Failed msgs3 ->
	      state <- `End (union_msgs msgs3 msgs);
	      self#next)
      | `End msgs -> Failed msgs
  end

let cut = new cut
let (<!>) = cut
let (<!>>) parse1 parse2 parse3 = cut parse1 (fun _ -> parse2) parse3
let (</>) f x = f x
    (* parse1 <!> fun _ -> parse2 </> parse3 *)
    (* parse1 <!>> parse2 </> parse3 *)

(* syntaxe ideale
   if param = p1 then p2 else p3 ==> cut p1 (fun param -> p2) p3
   if p1 then p2 else p3 ==> cut p1 (fun _ -> p2) p3
*)

class ['ctx,'res,'cursor] guard (parse1 : ('ctx,'res,'cursor) parse) (name : string) (pred : 'res -> bool) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin ([], parse1 ctx cursor)

    method next =
      match state with
      | `Begin (msgs, p1) ->
	  ( match p1 # next with
	  | Parsed (ctx1, res1, cursor1) as x ->
	      if pred res1
	      then x
	      else begin
		let msgs1 = msgs_failure name cursor in
		state <- `Begin (union_msgs msgs1 msgs, p1);
		self # next
	      end
	  | Failed msgs1 ->
	      state <- `End (union_msgs msgs1 msgs);
	      self#next)
      | `End msgs -> Failed msgs
  end

let guard = new guard
let (<&>) = guard
    (* parse <&> name </> pred *)

(* syntaxe ideale
   param = p1 when expr_bool else expr_string ==> guard p1 expr_string (fun param -> expr_bool)
*)

class ['ctx,'cursor] check (name : string) (pred : 'ctx -> 'cursor -> bool) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  if pred ctx cursor
	  then
	    Parsed (ctx, (), cursor)
	  else
	    Failed (msgs_failure name cursor)
      | `End -> Failed []
  end

let check = new check

class ['ctx,'res,'cursor] trial (f : unit -> 'res) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  begin
	    try
	      let x = f () in
	      Parsed (ctx, x, cursor)
	    with exn ->
	      Failed (msgs_exn exn cursor)
	  end
      | `End -> Failed []
  end

let trial = new trial

class ['ctx,'res,'cursor] enum (name : string) (f : unit -> 'res list) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state : 'res list option = None

    method next =
      match state with
      | None ->
	  state <- Some (f ());
	  if state = Some []
	  then Failed (msgs_failure name cursor)
	  else self#next
      | Some (x::xs) ->
	  state <- Some xs;
	  Parsed (ctx, x, cursor)
      | Some [] -> Failed []
  end

let enum = new enum

class ['ctx,'cursor] get_context (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  Parsed (ctx, ctx, cursor)
      | `End -> Failed []
  end

let get_context = new get_context

class ['ctx,'cursor] set_context (ctx1 : 'ctx) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  Parsed (ctx1, (), cursor)
      | `End -> Failed []
  end

let set_context = new set_context

class ['ctx,'cursor] check_context (name : string) (pred : 'ctx -> bool) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Begin

    method next =
      match state with
      | `Begin ->
	  state <- `End;
	  if pred ctx
	  then
	    Parsed (ctx, ctx, cursor)
	  else
	    Failed (msgs_failure name cursor)
      | `End -> Failed []
  end

let check_context = new check_context

class ['ctx,'cursor] enum_context (name : string) (f : 'ctx -> 'ctx list) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state : 'ctx list option = None

    method next =
      match state with
      | None ->
	  state <- Some (f ctx);
	  if state = Some []
	  then Failed (msgs_failure name cursor)
	  else self#next
      | Some (ctx1::l1) ->
	  state <- Some l1;
	  Parsed (ctx1, (), cursor)
      | Some [] -> Failed []
  end
  
let enum_context = new enum_context

(* repetitions, favoring longest ones *)
class ['ctx, 'elt, 'cursor] many (parse : ('ctx,'elt,'cursor) parse) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Loop (ctx, cursor, [], parse ctx cursor, `End)

    method next =
      match state with
	| `Loop (ctx, cursor, rev_le, p, state1) ->
	  ( match p # next with
	    | Parsed (ctx1, elt, cursor1) ->
	        state <- `Loop (ctx1, cursor1, elt::rev_le, parse ctx1 cursor1, state);
	        self # next
	    | Failed _msgs ->
	        state <- state1;
	        Parsed (ctx, List.rev rev_le, cursor) )
	| `End -> Failed []
  end

let many = new many
let some parse = parse |> fun x -> many parse --> (fun xs -> x::xs)

(* non-empty repetitions with separators, favoring longest repetitions *)
class ['ctx, 'elt, 'sep, 'cursor] list1 (p_elt : ('ctx,'elt,'cursor) parse) (p_sep : ('ctx,'sep,'cursor) parse) (ctx : 'ctx) (cursor : 'cursor) =
  object (self)
    val mutable state = `Elt (ctx, cursor, [], p_elt ctx cursor, `End)

    method next =
      match state with
	| `Elt (ctx, cursor, rev_le, p, state1) ->
	  ( match p # next with
	    | Parsed (ctx1, e, cursor1) ->
	        state <- `Sep (ctx1, cursor1, e::rev_le, p_sep ctx1 cursor1, state);
	        self # next
	    | Failed _msgs ->
	        state <- state1;
	        self # next )
	| `Sep (ctx, cursor, rev_le, p, state1) ->
	  ( match p # next with
	    | Parsed (ctx1, _, cursor1) ->
	        state <- `Elt (ctx1, cursor1, rev_le, p_elt ctx1 cursor1, state);
	        self # next
	    | Failed _msgs ->
	        state <- state1;
	        Parsed (ctx, List.rev rev_le, cursor) )
	| `End -> Failed []
  end

let list1 p_elt p_sep = new list1 p_elt p_sep (* p_elt |> fun x -> list1_aux p_elt p_sep --> (fun xs -> x::xs) *)
let list0 p_elt p_sep = (list1 p_elt p_sep) <|> (ret [])


(* combinators *)

let opt parse x = parse <|> (ret x)
let (<?>) = opt

(* syntaxe ideale
   p ? ==> opt p
*)

let rec star parse = (parse |> fun x -> star parse --> (fun xs -> x::xs)) <|> (ret [])
let (<*>) = star

(* syntaxe ideale
   p * ==> star p
*)

let plus parse = parse |> fun x -> star parse --> (fun xs -> x::xs)
let (<+>) = plus

(* syntaxe ideale
   p + ==> some p
*)

(*
let rec list1 p_elt p_sep =
  p_elt |> fun x -> list1_aux p_elt p_sep --> fun xs -> x::xs
and list1_aux p_elt p_sep =
  (p_sep |>> p_elt |> fun x -> list1_aux p_elt p_sep --> fun xs -> x::xs) <|> (ret [])

let list0 p_elt p_sep =
  (list1 p_elt p_sep) <|> (ret [])
*)

exception SyntaxError of int * int * exn list
    (* line, column, exceptions *)

(* returns one parsing result *)
let once parse ctx cursor = Common.prof "Dcg.once" (fun () ->
  let p = parse ctx cursor in
  match p # next with
  | Parsed (ctx, x, _) -> ctx, x
  | Failed [] ->
      raise (SyntaxError (1,1,[]))
  | Failed (msg::msgs) ->
      let (line, col), best_exns =
	List.fold_left
	  (fun (best_coord, best_exns) msg ->
	    let coord = Locator.start msg.loc in
	    if best_coord < coord then (coord, [msg.exn])
	    else if best_coord = coord then (best_coord, (msg.exn :: best_exns))
	    else (best_coord, best_exns))
	  (Locator.start msg.loc, [msg.exn])
	  msgs in
      raise (SyntaxError (line, col, best_exns)))

(* returns all parsing results *)
let all parse ctx cursor = Common.prof "Dcg.all" (fun () ->
  let p = parse ctx cursor in
  let res = ref [] in
  begin try while true do
    match p # next with
    | Parsed (ctx, x, _) -> res := (ctx, x) :: !res
    | Failed _ -> raise Not_found
  done with Not_found -> () end;
  !res)