Snippets
Created by
Stefan Glienke
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 | program RangeDemo;
uses
SysUtils;
type
// see https://docs.python.org/3/library/stdtypes.html#range
TRange = record
private
fStart, fStop, fStep: Integer;
type
TEnumerator = record
private
fStop, fStep: Integer;
fCurrent: Integer;
public
function MoveNext: Boolean; inline;
property Current: Integer read fCurrent;
end;
public
constructor Create(stop: Integer); overload;
constructor Create(start, stop: Integer; step: Integer = 1); overload;
function Equals(const other: TRange): Boolean;
function GetEnumerator: TEnumerator; inline;
class operator Equal(const left, right: TRange): Boolean; inline;
class operator NotEqual(const left, right: TRange): Boolean; inline;
end;
function Range(stop: Integer): TRange; overload; inline;
begin
Result := TRange.Create(stop);
end;
function Range(start, stop: Integer; step: Integer = 1): TRange; overload; inline;
begin
Result := TRange.Create(start, stop, step);
end;
{ TRange }
constructor TRange.Create(stop: Integer);
begin
fStart := 0;
fStop := stop;
fStep := 1;
end;
constructor TRange.Create(start, stop, step: Integer);
begin
fStart := start;
fStop := stop;
fStep := step;
end;
class operator TRange.Equal(const left, right: TRange): Boolean;
begin
Result := left.Equals(right);
end;
function TRange.Equals(const other: TRange): Boolean;
var
left, right: TEnumerator;
begin
left := GetEnumerator;
right := other.GetEnumerator;
while left.MoveNext do
if not (right.MoveNext and (left.Current = right.Current)) then
Exit(False);
Result := not right.MoveNext;
end;
function TRange.GetEnumerator: TEnumerator;
begin
Result.fStop := fStop;
Result.fStep := fStep;
Result.fCurrent := fStart - fStep;
end;
class operator TRange.NotEqual(const left, right: TRange): Boolean;
begin
Result := not left.Equals(right);
end;
{ TRange.TEnumerator }
function TRange.TEnumerator.MoveNext: Boolean;
begin
Inc(fCurrent, fStep);
if fStep > 0 then
Result := fCurrent < fStop
else
Result := fCurrent > fStop;
end;
procedure List(const r: TRange);
var
s: string;
i: Integer;
begin
for i in r do
begin
if s <> '' then
s := s + ', ';
s := s + IntToStr(i);
end;
s := '[' + s + ']';
Writeln(s);
end;
begin
List(Range(10));
List(Range(1, 11));
List(Range(0, 30, 5));
List(Range(0, 10, 3));
List(range(0, -10, -1));
List(Range(0));
List(Range(1, 0));
Assert(Range(0) = Range(2, 1, 3));
Assert(Range(0, 3, 2) = Range(0, 4, 2));
ReadLn;
end.
|
Comments (0)
You can clone a snippet to your computer for local editing. Learn more.