Source

javafx-gradle / gradle-javafx-plugin / src / main / groovy / org / bitbucket / shemnon / javafxplugin / JavaFXPlugin.groovy

Full commit
shemnon 664e698 

























shemnon 3887373 
shemnon 664e698 
shemnon bbe9d6e 
shemnon 4b4ff7c 
shemnon 664e698 

shemnon 3887373 

shemnon 664e698 


shemnon edb42ec 
shemnon 664e698 


shemnon 3887373 


shemnon 4dd2ff6 

shemnon 6787d20 
shemnon 664e698 






shemnon 6787d20 














shemnon bbe9d6e 
shemnon 24116ec 
shemnon 6787d20 


shemnon bbe9d6e 
shemnon 24a7c26 

shemnon 6787d20 
shemnon 35ae1bb 
shemnon 6787d20 





shemnon 24a7c26 
shemnon 4b2222c 










shemnon 58d8835 
shemnon 4b2222c 



shemnon 24a7c26 

shemnon 664e698 

shemnon bbe9d6e 

shemnon 664e698 
shemnon 800809b 

shemnon 664e698 

shemnon 3ba7b63 
shemnon 800809b 

shemnon 3ba7b63 
shemnon 800809b 

shemnon 35ae1bb 
shemnon 800809b 
shemnon b499614 
shemnon 664e698 



shemnon bfbe011 

shemnon 15a98b6 
shemnon 3ef71ca 
shemnon 15a98b6 
shemnon bfbe011 

shemnon 664e698 
shemnon 15a98b6 
shemnon 1206789 


shemnon c15d40f 
shemnon 1206789 
shemnon 4dd2ff6 
shemnon edb42ec 
shemnon 3c9a1ab 
shemnon d96b22b 
shemnon 664e698 


shemnon 1206789 
shemnon ff9d1b6 


shemnon 664e698 
shemnon 4b2222c 
shemnon 664e698 

shemnon 4b2222c 
shemnon 664e698 

shemnon 7266871 

shemnon 664e698 


shemnon ff9d1b6 



shemnon 8a812a6 

shemnon dd3e8b9 
shemnon 8a812a6 
shemnon 664e698 
shemnon 24a7c26 



shemnon 664e698 
shemnon 4b2222c 

shemnon 8a812a6 
shemnon dd3e8b9 
shemnon 8a812a6 
shemnon 728914f 
shemnon 4b2222c 
shemnon 664e698 
shemnon ff9d1b6 
shemnon 664e698 


shemnon 1206789 
shemnon ff9d1b6 


shemnon 1206789 
shemnon c15d40f 








shemnon 387e632 

shemnon 1206789 


shemnon ff9d1b6 




shemnon 8a812a6 

shemnon c15d40f 
shemnon 8a812a6 
shemnon 15a98b6 
shemnon 5df3dae 
shemnon 1206789 
shemnon 800809b 
shemnon 7bd7773 

shemnon cb41da2 
shemnon 1206789 

shemnon 5df3dae 
shemnon 800809b 
shemnon 7bd7773 

shemnon 5df3dae 
shemnon e347280 
shemnon 7bd7773 
shemnon 1206789 
shemnon 8a812a6 
shemnon 15a98b6 

shemnon 4b2222c 
shemnon 1206789 
shemnon 8a812a6 
shemnon 15a98b6 

shemnon 1206789 
shemnon c15d40f 


shemnon ff9d1b6 
shemnon c15d40f 

shemnon 4b2222c 
shemnon c15d40f 

shemnon eb119b2 
shemnon c15d40f 










shemnon 1206789 


shemnon ff9d1b6 


shemnon 1206789 
shemnon 92164fe 











shemnon 3cbfd91 
shemnon 92164fe 
shemnon 200ffa4 
shemnon 92164fe 









shemnon 24a7c26 
shemnon 1206789 
shemnon 06ca0b3 
shemnon 4b2222c 
shemnon 1206789 

shemnon 8a812a6 
shemnon 1206789 
shemnon 3ef71ca 
shemnon fefa70f 


shemnon 3ef71ca 
shemnon 1206789 
shemnon 800809b 
shemnon 1206789 
shemnon c15d40f 
shemnon 3ef71ca 

shemnon 1206789 
shemnon 15a98b6 
shemnon edb42ec 

shemnon ff9d1b6 


shemnon 4dd2ff6 
shemnon 24116ec 
shemnon 24a7c26 

shemnon 24116ec 
shemnon 4b2222c 




shemnon 599ee04 
shemnon 24a7c26 


shemnon 599ee04 
shemnon edb42ec 
shemnon 15a98b6 
shemnon 3c9a1ab 
shemnon ff9d1b6 


shemnon 4dd2ff6 
shemnon 24116ec 
shemnon 4dd2ff6 



shemnon ff9d1b6 


shemnon 4dd2ff6 




shemnon e341859 














shemnon 4b4ff7c 

shemnon 4dd2ff6 







shemnon 3c9a1ab 

shemnon 664e698 
shemnon ff9d1b6 


shemnon 664e698 
shemnon ff9d1b6 
shemnon 664e698 



shemnon 4b2222c 





shemnon f944414 








shemnon 75d469d 
shemnon fd31aa5 







shemnon f944414 
shemnon bbe9d6e 

shemnon f944414 
shemnon 3ba7b63 
shemnon 75d469d 


shemnon 664e698 


shemnon f944414 





shemnon 8ff21be 
shemnon f944414 

shemnon bbe9d6e 
shemnon f944414 





shemnon a0145e1 
shemnon f944414 
shemnon 664e698 
shemnon 1206789 
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
/*
 * Copyright (c) 2012, Danno Ferrin
 *   All rights reserved.
 *
 *   Redistribution and use in source and binary forms, with or without
 *   modification, are permitted provided that the following conditions are met:
 *       * Redistributions of source code must retain the above copyright
 *         notice, this list of conditions and the following disclaimer.
 *       * Redistributions in binary form must reproduce the above copyright
 *         notice, this list of conditions and the following disclaimer in the
 *         documentation and/or other materials provided with the distribution.
 *       * Neither the name of Danno Ferrin nor the
 *         names of contributors may be used to endorse or promote products
 *         derived from this software without specific prior written permission.
 *
 *   THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 *   ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 *   WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 *   DISCLAIMED. IN NO EVENT SHALL <COPYRIGHT HOLDER> BE LIABLE FOR ANY
 *   DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 *   (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 *   LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 *   ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 *   (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 *   SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */
package org.bitbucket.shemnon.javafxplugin

import org.gradle.api.GradleException
import org.gradle.api.JavaVersion
import org.gradle.api.Project
import org.gradle.api.Plugin
import org.bitbucket.shemnon.javafxplugin.tasks.JavaFXDeployTask
import org.bitbucket.shemnon.javafxplugin.tasks.JavaFXJarTask
import org.gradle.api.plugins.JavaPluginConvention
import org.gradle.api.file.FileCollection
import org.gradle.api.tasks.SourceSet
import org.gradle.api.tasks.JavaExec
import org.gradle.api.artifacts.ConfigurationContainer
import org.gradle.api.artifacts.Configuration
import org.gradle.api.plugins.JavaPlugin
import org.bitbucket.shemnon.javafxplugin.tasks.JavaFXCSSToBinTask
import org.bitbucket.shemnon.javafxplugin.tasks.JavaFXSignJarTask
import org.bitbucket.shemnon.javafxplugin.tasks.GenKeyTask
import org.gradle.api.DefaultTask
import org.gradle.api.artifacts.ResolvedArtifact
import org.gradle.internal.os.OperatingSystem


class JavaFXPlugin implements Plugin<Project> {

    public static final String PROVIDED_COMPILE_CONFIGURATION_NAME = "providedCompile";
    public static final String PROVIDED_RUNTIME_CONFIGURATION_NAME = "providedRuntime";

    static String getOSProfileName() {
        def currentOS = OperatingSystem.current();
        if (currentOS.isWindows()) {
            return 'windows'
        }
        if (currentOS.isLinux()) {
            return 'linux'
        }
        if (currentOS.isMacOsX()) {
            return 'macosx'
        }

        return null;
    }

    private Project project
    
    @Lazy private String[] profiles = ([] + project.getProperties().profiles?.split(',') + getOSProfileName()).flatten().findAll {
            project.javafx.getProfile(it) != null
        }

    protected basicExtensionMapping = {prop, convention = null, aware = null ->
        JavaFXPluginExtension ext = project.javafx;
        for (profile in profiles) {
            Map override = ext.getProfile(profile)
            def val = override[prop]
            if (val != null) {
                return val;
            }
        }
        return ext[prop]
    }
    
    protected mainClassConvention = {convention, aware ->
        if (!project.javafx.mainClass) { 
            def mains = []
            sourceSet(project).allJava.visit {
                if (it.relativePath.lastName == 'Main.java') {
                    mains.add(it.relativePath.replaceLastName('Main').pathString.replace('/', '.'))
                }
            }
    
            if (mains.size() == 1) {
                project.javafx.mainClass = mains[0]
            }
        }
        return project.javafx.mainClass
    }


    @Override
    void apply(Project project) {
        this.project = project

        project.getPlugins().apply(JavaPlugin)
        project.extensions.create('javafx', JavaFXPluginExtension)

        configureConfigurations(project.configurations)

        def jfxrtJarFile = project.javafx.jfxrtJar ?: project.files(findJFXJar())
        project.javafx {
            jfxrtJar = jfxrtJarFile
            antJavaFXJar = antJavaFXJar ?: project.files(findAntJavaFXJar())
            appName = project.name //FIXME capatalize
            packaging = 'all'
            signingMode = 'release'
        }


        project.dependencies {
            providedCompile jfxrtJarFile
        }
        project.sourceSets {
            'package' {
                resources {
                    srcDir 'src/deploy/package'
                }
            }
        }

        configureJavaFXCSSToBinTask(project)
        configureJavaFXJarTask(project)
        configureGenerateDebugKeyTask(project)
        configureJavaFXSignJarTask(project)
        configureJFXCopyLibsTask(project)
        configureJFXDeployTask(project)
        configureScenicViewTask(project)
        configureRunTask(project)
        configureDebugTask(project)

    }


    private configureJavaFXCSSToBinTask(Project project) {
        def task = project.tasks.replace("cssToBin", JavaFXCSSToBinTask)
        task.description =  "Converts CSS to Binary CSS."
        task.group =  'Build'

        task.conventionMapping.distsDir = {convention, aware -> sourceSet(project).output.resourcesDir}

        task.conventionMapping.inputFiles = {convention, aware ->
            sourceSet(project).resources
        }

        project.tasks.getByName("classes").dependsOn(task)
        task.dependsOn(project.tasks.getByName("processResources"))
    }

    private configureJavaFXJarTask(Project project) {
        def task = project.tasks.replace("jfxJar", JavaFXJarTask)
        task.description = "Adds JavaFX specific packaging to the jar."
        task.group = 'Build'
        
        project.afterEvaluate {
            project.configurations.archives.artifacts*.builtBy task
            task.dependsOn = [sourceSet(project).jarTaskName]
        }

        [
                'embedLauncher',
                'arguments'
        ].each {prop -> task.conventionMapping[prop] = basicExtensionMapping.curry(prop) }

        task.conventionMapping.mainClass = mainClassConvention

        task.conventionMapping.jarFile = {convention, aware ->
            project.tasks.getByName(sourceSet(project).jarTaskName).archivePath
        }
        task.conventionMapping.classpath = {convention, aware ->
            FileCollection compileClasspath = sourceSet(project).compileClasspath;
            Configuration providedCompile = project.configurations[PROVIDED_COMPILE_CONFIGURATION_NAME];
            return compileClasspath - providedCompile;
        }
    }

    private configureGenerateDebugKeyTask(Project project) {
        def task = project.tasks.replace("generateDebugKey", GenKeyTask)
        task.description = "Generates the JavaFX Debug Key."
        task.group = 'Build'

        project.afterEvaluate {
            task.enabled = task.enabled && project.javafx.debugKey != null
        }

        task.conventionMapping.alias     = {convention, aware -> project.javafx.debugKey?.alias }
        task.conventionMapping.keyPass   = {convention, aware -> project.javafx.debugKey?.keyPass }
        task.conventionMapping.keyStore  = {convention, aware -> project.javafx.debugKey?.keyStore }
        task.conventionMapping.storePass = {convention, aware -> project.javafx.debugKey?.storePass }
        task.conventionMapping.storeType = {convention, aware -> project.javafx.debugKey?.storeType }
        task.conventionMapping.dname     = {convention, aware -> 'CN=JavaFX Gradle Plugin Default Debug Key, O=JavaFX Debug' }
        task.conventionMapping.validity  = {convention, aware -> ((365.25) * 25 as int) /* 25 years */ }
    }

    private configureJavaFXSignJarTask(Project project) {
        def task = project.tasks.replace("jfxSignJar", JavaFXSignJarTask)
        task.description = "Signs the JavaFX jars the JavaFX way."
        task.group = 'Build'
        task.dependsOn = ['jfxJar']
        
        project.afterEvaluate {
            project.configurations.archives.artifacts*.builtBy task
            task.enabled = task.enabled && (project.javafx.debugKey != null || project.javafx.releaseKey != null)
        }

        ['alias', 'keyPass', 'storePass', 'storeType'].each { prop ->
            task.conventionMapping[prop]  = {convention, aware ->
                def jfxc = project.javafx;
                def props = project.properties
                def mode = props['javafx.signingMode']  ?: jfxc.signingMode
                return props?."javafx.${mode}Key.$prop" ?: jfxc?."${mode}Key"?."$prop"
            }
        }
        task.conventionMapping.keyStore  = {convention, aware ->
            def jfxc = project.javafx;
            def props = project.properties
            def mode = props['javafx.signingMode']  ?: jfxc.signingMode
            String keyFile = props?."javafx.${mode}Key.keyStore"
            return keyFile == null ? jfxc?."${mode}Key"?.keyStore : new File(project.projectDir, keyFile)
        }

        task.conventionMapping.outdir = {convention, aware -> project.libsDir}

        task.conventionMapping.inputFiles = {convention, aware ->
            FileCollection runtimeClasspath = sourceSet(project).runtimeClasspath;
            Configuration providedRuntime = project.configurations[PROVIDED_RUNTIME_CONFIGURATION_NAME];
            project.files(runtimeClasspath - providedRuntime, project.configurations.archives.artifacts.files.collect{it})
        }

        task.dependsOn(project.tasks.getByName("jfxJar"))
    }

    private configureJFXCopyLibsTask(Project project) {
        def task = project.tasks.replace("jfxCopyLibs")

        task.doLast {
            FileCollection runtimeClasspath = sourceSet(project).runtimeClasspath;
            Configuration providedRuntime = project.configurations[PROVIDED_RUNTIME_CONFIGURATION_NAME];
            project.files(runtimeClasspath - providedRuntime, project.configurations.archives.artifacts.files.collect{it}).
                    findAll {File f -> f.exists() && !f.directory}.
                    each {
                        ant.copy(
                                file: it,
                                toDir: project.libsDir,
                                overwrite: false
                        )
                    }
        }

        task.dependsOn(project.tasks.getByName("jfxSignJar"))
        task.dependsOn(project.tasks.getByName("jfxJar"))
    }

    private configureJFXDeployTask(Project project) {
        def task = project.tasks.replace("jfxDeploy", JavaFXDeployTask)
        task.description = "Processes the JavaFX jars and generates webstart and native packages."
        task.group = 'Build'

        [
                'antJavaFXJar',
                'appID',
                'appName',
                'arguments',
                'category',
                'codebase',
                'copyright',
                'description',
                'embedJNLP',
                'height',
                'iconInfos',
                'id',
                'installSystemWide',
                'javaRuntime',
                'jvmArgs',
                'licenseType',
                'menu',
                'offlineAllowed',
                'packaging',
                'shortcut',
                'systemProperties',
                'updateMode',
                'vendor',
                'width',
        ].each {prop -> task.conventionMapping[prop] = basicExtensionMapping.curry(prop) }

        task.conventionMapping.version = {convention, aware -> ('unspecified' == project.version) ? '0.0.0' : project.version }
        task.conventionMapping.mainClass = mainClassConvention

        task.conventionMapping.inputFiles = {convention, aware ->
            project.fileTree(project.libsDir).include("*.jar")
        }
        task.conventionMapping.resourcesDir = { convention, aware ->
            def rd = project.sourceSets['package'].output.resourcesDir
            if (!rd.exists()) rd.mkdirs()
            rd
        }

        task.conventionMapping.distsDir = {convention, aware -> project.distsDir }

        task.dependsOn(project.tasks.getByName("jfxCopyLibs"))
        task.dependsOn(project.tasks.getByName("packageClasses"))

        project.tasks.getByName("assemble").dependsOn(task)
    }
    
    private void configureRunTask(Project project) {
        JavaExec task = project.tasks.replace("run", JavaExec)
        task.description = 'Runs the application.'
        task.group = 'Execution'

        configureRunParams(task)
    }

    protected void configureRunParams(JavaExec task) {
        task.conventionMapping.main = mainClassConvention
        project.afterEvaluate({project ->
            task.classpath = sourceSet(project).runtimeClasspath
        })

        task.doFirst {
            task.jvmArgs basicExtensionMapping('jvmArgs')
            task.systemProperties basicExtensionMapping('systemProperties')
            if (!task.args) task.args = basicExtensionMapping('arguments')
        }
    }

    private void configureDebugTask(Project project) {
        JavaExec task = project.tasks.replace("debug", JavaExec)
        task.description = 'Runs the applicaiton and sets up debugging on port 5005.'
        task.group = 'Execution'

        configureRunParams(task)
        task.debug = true
    }

    private void configureScenicViewTask(Project project) {
        def task = project.tasks.replace("scenicview", DefaultTask)
        task.description = 'Adds the ScenicView agent to all Execution Tasks.'
        task.group = 'Tools'

        task.doLast {
            project.configurations {
                scenicview
            }

            if (JavaVersion.current().java8Compatible) {
                project.repositories {
                    maven  { url 'http://dl.bintray.com/scenic-view/scenic-view' }
                }
                project.dependencies {
                    scenicview('org.scenic-view:scenic-view:8.0.0-dp3') {
                        exclude group: 'org.fxconnector'
                    }
                }
            } else {
                project.repositories {
                    ivy  { url 'https://repository-javafx-gradle-plugin.forge.cloudbees.com/release' }
                }
                project.dependencies {
                    scenicview 'com.fxexperience.scenicview:scenicview:1.3.0'
                }
            }

            project.tasks.findAll {it.group == 'Execution' && it instanceof JavaExec}.each {JavaExec execTask ->
                project.configurations.getByName('scenicview').resolvedConfiguration.resolvedArtifacts.each { ResolvedArtifact ra ->
                    execTask.jvmArgs = ["-javaagent:$ra.file.canonicalPath"] + execTask.jvmArgs
                }
            }
        }
    }

    public void configureConfigurations(ConfigurationContainer configurationContainer) {
        Configuration provideCompileConfiguration = configurationContainer.create(PROVIDED_COMPILE_CONFIGURATION_NAME).setVisible(false).
                setDescription("Additional compile classpath for libraries that should not be part of the bundle.");
        Configuration provideRuntimeConfiguration = configurationContainer.create(PROVIDED_RUNTIME_CONFIGURATION_NAME).setVisible(false).
                extendsFrom(provideCompileConfiguration).
                setDescription("Additional runtime classpath for libraries that should not be part of the bundle.");
        configurationContainer.getByName(JavaPlugin.COMPILE_CONFIGURATION_NAME).extendsFrom(provideCompileConfiguration);
        configurationContainer.getByName(JavaPlugin.RUNTIME_CONFIGURATION_NAME).extendsFrom(provideRuntimeConfiguration);
    }

    public sourceSet(Project project) {
        return project.javafx.getSourceSet('sourceSet', project)
    }



    private File searchFile(Map<String, Closure> places, List<String> searchPaths, String searchID) {
        File result = null;
        places.each { k, v ->
            if (result != null) return;
            project.logger.debug("Looking for $searchID in $k")
            def dir = v()
            if (dir == null) {
                project.logger.debug("$k not set")
            } else {
                project.logger.debug("$k is $dir")
                searchPaths.each { s ->
                    if (result != null) return;
                    File f = new File(dir, s);
                    project.logger.debug("Trying $f.path")
                    if (f.exists() && f.file) {
                        project.logger.debug("found $searchID as $result")
                        result = f; 
                    }
                }
            }
        }
        if (!result?.file) {
            throw new GradleException("Could not find $searchID, please set one of ${places.keySet()}");
        } else {
            project.logger.info("$searchID: ${result}")
            return result
        }
    }

    public File findJFXJar() {
        return searchFile([
                    'JFXRT_HOME in System Environment': {System.env['JFXRT_HOME']},
                    'JAVA_HOME in System Environment': {System.env['JAVA_HOME']},
                    'java.home in JVM properties': {System.properties['java.home']}
                ],
                ['jfxrt.jar', 'lib/jfxrt.jar', 'lib/ext/jfxrt.jar', 'jre/lib/jfxrt.jar', 'jre/lib/ext/jfxrt.jar'],
                'JavaFX Runtime Jar')
    }

    public File findAntJavaFXJar() {
        return searchFile([
                    'JFXRT_HOME in System Environment': {System.env['JFXRT_HOME']},
                    'JAVA_HOME in System Environment': {System.env['JAVA_HOME']},
                    'java.home in JVM properties': {System.properties['java.home']}
                 ],
                ['lib/ant-javafx.jar', '../lib/ant-javafx.jar'],
                'JavaFX Packager Tools')
    }
}