Commits

Nikolaj Sjujskij committed d022a44

New vifm (shamelessly stolen from bugzilla)

  • Participants
  • Parent commits a220ba6

Comments (0)

Files changed (2)

File app-misc/vifm/Manifest

+DIST vifm-0.7.4a.tar.bz2 556144 SHA256 fe9b8bcd992f4f34ad83dd3de46064e5d3d8d4a0c468dbd11869f9790f3dcd1f SHA512 7ece768a12ed6837a5713ce41f849ed56120f3d4db17740d83c1e92d26183604dabbf975755353dfe4382d9cb9b01075e3c86b6e6afcf87168960f523cf46dee WHIRLPOOL d740b06efbd720374237645d84cd54e0200013abf7d99220c81d1deb34bece1447bc0fc0aa57e03f7b7920c572a914737fd5a4e67b4bc233444ea084cf648422
+EBUILD vifm-0.7.4a.ebuild 1678 SHA256 e49a4b36bf10a981dbf63951e72d599f248cca3f3b08d21c93cab40b66739724 SHA512 218f09ac3607660a35dbca6e37a96f8682ec83828ee604a070ac8b85085f737eed0fb40920757009d848dca2e0ed196d68272fa932f13f0e3b08f8e894d8a834 WHIRLPOOL 2837490aec288b118a0e7bc5e135aae7d45eb1a890e62b1217f184b071b621e77ce6e89f44d3fae0107cb76cf856491a3e5369bdbc5e5326afb226c60d7be368

File app-misc/vifm/vifm-0.7.4a.ebuild

+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vifm/vifm-0.7.2.ebuild,v 1.5 2012/09/16 14:26:42 armin76 Exp $
+
+EAPI=4
+inherit base
+
+DESCRIPTION="Console file manager with vi(m)-like keybindings"
+HOMEPAGE="http://vifm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/vifm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~s390 ~x86"
+IUSE="+X +extended-keys +magic +gtk vim-plugin vim-syntax"
+
+DEPEND="
+	>=sys-libs/ncurses-5.7-r7
+	magic? ( sys-apps/file )
+	gtk? ( x11-libs/gtk+:2 )
+	X? ( x11-libs/libX11 )
+"
+RDEPEND="
+	${DEPEND}
+	vim-plugin? ( >=app-editors/vim-7.3 )
+	vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
+"
+
+DOCS=( AUTHORS TODO README )
+
+src_configure() {
+	econf \
+		$(use_enable extended-keys) \
+		$(use_with magic libmagic) \
+		$(use_with gtk) \
+		$(use_with X X11)
+}
+
+src_install() {
+	base_src_install
+	insinto /usr/share/${PN}
+	doins "${S}"/data/vim/doc/vifm.txt
+
+	if use vim-syntax; then
+		local t
+		for t in ftdetect ftplugin syntax; do
+			insinto /usr/share/vim/vimfiles/"${t}"
+			doins "${S}"/data/vim/"${t}"/"${PN}".vim
+		done
+	fi
+	if use vim-plugin; then
+		local t
+		for t in doc plugin; do
+			insinto /usr/share/vim/vimfiles/"${t}"
+			doins "${S}"/data/vim/"${t}"/"${PN}".*
+		done
+	fi
+}
+
+pkg_postinst() {
+	elog "To use vim to view the vifm help, copy /usr/share/${PN}/vifm.txt"
+	elog "	to ~/.vim/doc/ and run ':helptags ~/.vim/doc' in vim,"
+	elog "then edit ~/.vifm/vifmrc and set vimhelp instead of novimhelp"
+	elog ""
+	elog "To use the vifm plugin in vim, copy /usr/share/vim/vimfiles/vifm.vim to"
+	elog "	/usr/share/vim/vimXX/"
+}