brainflak←{
   ⍝ set up stacks
   stks←(⌽⍺) ⍬

   ⍝ get the first command from a string
   getfst←{
      bgns←'([<{'
      ends←')]>}'
      cmd←⊃⍵
      idx←((+\cmd=⍵)-+\ends[bgns⍳cmd]=⍵)⍳0
      (⊂idx↑⍵), ⊂idx↓⍵
   }

   ⍝ evaluate list of commands
   evallst←{
      0=⍴⍵:0
      rest val←eval ⍵
      val+∇rest
   }

   ⍝ evaluate code
   eval←{

      ⍝ nilad?
      nilad←2↑⍵
      rest←2↓⍵

      '()'≡nilad:(⊂rest),1
      '[]'≡nilad:(⊂rest),¯1
      '{}'≡nilad:(⊂rest),{
          item←⊃⊃⊃stks
          stks[1]↓⍨←1
          item
      }⍬
      '<>'≡nilad:(⊂rest),0⊣stks⌽⍨←1

      ⍝ monads: get inner command
      cmd rest←getfst ⍵
      inner←1↓¯1↓cmd

      ⍝ evaluate command
      '('=⊃cmd:(⊂rest), stks[1],⍨←evallst inner
      '['=⊃cmd:(⊂rest), +⎕←evallst inner
      '{'=⊃cmd:(⊂rest), {0≠⊃⊃⊃stks:∇evallst inner⋄0}⍬
      '<':⊃cmd:(⊂rest), 0⊣evallst inner

      ⍝ error
      ('INVALID CMD: ',⊃cmd) ⎕SIGNAL 11
   }

   ⍝ evaluate all the commands in order
   _←evallst ⍵

   ⍝ print active stack
   ⎕←⍪⊃stks
}