Source

aur / gauche / PKGBUILD

Full commit
# Maintainer: Taylor Venable <taylor@metasyntax.net>

pkgname='gauche'
pkgver='0.9.3.3'
pkgrel=1
url='http://practical-scheme.net/gauche/index.html'
pkgdesc='R5RS Scheme implementation developed to be a handy script interpreter'
depends=('gcc-libs' 'gdbm' 'zlib' 'slib')
makedepends=('texi2html')
license=('BSD')
arch=('i686' 'x86_64')
source=("http://downloads.sourceforge.net/gauche/Gauche-$pkgver.tgz"
        'makefile_slib.diff'
        'doc-makefile.patch')
md5sums=('5090ddccd8aa4d9995a73c20e7a355e8'
         '1ddf7c6dbfc61780bf5118e80d45cb1d'
         '56072e401c3e5aafefa46824f52f79c9')
install="$pkgname.install"

build() {
  cd "${srcdir}/Gauche-${pkgver}"
  patch -p0 < "${srcdir}/doc-makefile.patch"
  ./configure --prefix=/usr \
      --enable-multibyte=utf-8 \
      --enable-threads=pthreads
  patch lib/Makefile "$srcdir/makefile_slib.diff"
  make
  cd doc && make htmls && cd ..
}
package() {
  cd "${srcdir}/Gauche-${pkgver}"
  make DESTDIR="$pkgdir" install
  mkdir -p "${pkgdir}/usr/share/doc"
  cp -R "doc/gauche-refe" "${pkgdir}/usr/share/doc/gauche"
  install -D -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}