pcl-cvs / pcl-cvs-info.el

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
;;; pcl-cvs-info.el

(defconst rcsid-pcl-cvs-info "$Id$")

;; Copyright (C) 1991-1999  Per Cederqvist
;;
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2 of the License, or
;; (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this program; if not, write to the Free Software
;; Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.

;;;; The cvs-fileinfo data structure:
;;;;
;;;; When the `cvs update' is ready we parse the output.  Every file
;;;; that is affected in some way is added to the cookie collection as
;;;; a "fileinfo" (as defined below in cvs-create-fileinfo).

(require 'cl)
(require 'pcl-cvs-util)
(require 'pcl-cvs-defs)
(require 'pcl-cvs-compat)

;;;
;;; config variables
;;;

(defcustom cvs-display-full-path t
  "*Specifies how the filenames should look like in the listing.
If t, their full path name will be displayed, else only the filename."
  :group 'pcl-cvs
  :type '(boolean))

(defvar global-font-lock-mode)
(defcustom cvs-highlight (and (boundp 'global-font-lock-mode) global-font-lock-mode)
  "*Whether to use text highlighting (� la font-lock) or not."
  :group 'pcl-cvs
  :type '(boolean))

(defcustom cvs-allow-dir-commit nil
  "*Allow `commit' on directories.
If you commit without any marked file and with the cursor positioned
on a directory entry, cvs would commit the whole directory.  This seems
to confuse some users sometimes."
  :group 'pcl-cvs
  :type '(boolean))


;;;
;;; Faces for fontification
;;;

(defface cvs-header-face
  '((((class color) (background dark))
     (:foreground "lightyellow" :bold t))
    (((class color) (background light))
     (:foreground "blue4" :bold t))
    (t (:bold t)))
  "PCL-CVS face used to highlight directory changes."
  :group 'pcl-cvs)

(defface cvs-filename-face
  '((((class color) (background dark))
     (:foreground "lightblue"))
    (((class color) (background light))
     (:foreground "blue4"))
    (t ()))
  "PCL-CVS face used to highlight file names."
  :group 'pcl-cvs)

(defface cvs-unknown-face
  '((((class color) (background dark))
     (:foreground "red"))
    (((class color) (background light))
     (:foreground "red"))
    (t (:italic t)))
  "PCL-CVS face used to highlight unknown file status."
  :group 'pcl-cvs)

(defface cvs-handled-face
  '((((class color) (background dark))
     (:foreground "pink"))
    (((class color) (background light))
     (:foreground "pink"))
    (t ()))
  "PCL-CVS face used to highlight handled file status."
  :group 'pcl-cvs)

(defface cvs-need-action-face
  '((((class color) (background dark))
     (:foreground "orange"))
    (((class color) (background light))
     (:foreground "orange"))
    (t (:italic t)))
  "PCL-CVS face used to highlight status of files needing action."
  :group 'pcl-cvs)

(defface cvs-marked-face
  '((((class color) (background dark))
     (:foreground "green" :bold t))
    (((class color) (background light))
     (:foreground "green3" :bold t))
    (t (:bold t)))
  "PCL-CVS face used to highlight marked file indicator."
  :group 'pcl-cvs)

(defface cvs-action-face
  '((((class color) (background dark))
     (:foreground "lightblue" :bold t))
    (((class color) (background light))
     (:foreground "blue4"))
    (t ()))
  "PCL-CVS face used to highlight the default action indicator."
  :group 'pcl-cvs)



;;; There is normally no need to alter the following variables, but if
;;; your site has installed CVS in a non-standard way you might have
;;; to change them.

(defun cvs-make-keymap (parent)
  (let ((map (make-sparse-keymap)))
    (set-keymap-parent map parent)
    map))

(defvar cvs-bakprefix ".#"
  "The prefix that CVS prepends to files when rcsmerge'ing.")

(defvar cvs-filename-map
  (let ((map (cvs-make-keymap cvs-mode-map)))
    (define-key map [(mouse-2)] 'cvs-mouse-find-file)
    map)
  "Local keymap for text properties of file names")

(defvar cvs-status-map
  (let ((map (cvs-make-keymap cvs-mode-map)))
    (define-key map [(mouse-2)] 'cvs-mouse-toggle-mark)
    map)
  "Local keymap for text properties of status")

(defvar cvs-dirname-map
  (let ((map (cvs-make-keymap cvs-mode-map)))
    (define-key map [(mouse-2)] 'cvs-mouse-find-file)
    map)
  "Local keymap for text properties of directory names")

(defvar cvs-action-map
  (let ((map (cvs-make-keymap cvs-mode-map)))
    map)
  "Local keymap for text properties of default actions")

;;; Constructor:

(defstruct (cvs-fileinfo
	    (:constructor nil)
	    (:copier nil)
	    (:constructor -cvs-create-fileinfo (type dir file full-log
						     &key marked subtype
						     merge
						     base-rev
						     head-rev))
	    (:conc-name cvs-fileinfo->))
  marked	;; t/nil.
  type		;; See below
  subtype	;; See below
  dir		;; Relative directory the file resides in.
                ;; (concat dir file) should give a valid path.
  file	     	;; The file name sans the directory.
  base-rev      ;; During status: This is the revision that the
                ;; working file is based on.
  head-rev      ;; During status: This is the highest revision in
                ;; the repository.
  merge		;; A cons cell containing the (ancestor . head) revisions
		;; of the merge that resulted in the current file.
  ;;removed	;; t if the file no longer exists.
  full-log	;; The output from cvs, unparsed.
  ;;mod-time	;; Not used.

  ;; In addition to the above, the following values can be extracted:

  ;; handled    ;; t if this file doesn't require further action.
  ;; full-path  ;; The complete relative filename.
  ;; pp-name    ;; The printed file name
  ;; backup-file;; For MERGED and CONFLICT files after a \"cvs update\",
                ;; this is a full path to the backup file where the
                ;; untouched version resides.

  ;; The meaning of the type field:
  
  ;; Value	      ---Used by---	Explanation
  ;; 		      update status
  ;; NEED-UPDATE		x	file needs update
  ;; MODIFIED		x	x	modified by you, unchanged in repository
  ;;   MERGED		x	x	successful merge
  ;; ADDED		x	x	added by you, not yet committed
  ;; NEED-REMOVE		x	rm'd, but not yet `cvs remove'd
  ;; REMOVED		x	x	removed by you, not yet committed
  ;; NEED-MERGE			x	need merge
  ;; CONFLICT		x		conflict when merging
  ;; MOD-CONFLICT	x		removed locally, changed in repository.
  ;; DIRCHANGE		x	x	A change of directory.
  ;; UNKNOWN		x		An unknown file.
  ;; UP-TO-DATE			x	The file is up-to-date.
  ;;   UPDATED		x	x	file copied from repository
  ;;   PATCHED		x	x	diff applied from repository
  ;;   COMMITTED		x	x	cvs commit'd
  ;; DEAD				An entry that should be removed
  ;; MESSAGE		x	x	This is a special fileinfo that is used
  ;;					  to display a text that should be in
  ;;					  full-log."
  ;;   TEMP	A temporary message that should be removed
  )
(defun cvs-create-fileinfo (type dir file msg &rest keys)
  (cvs-check-fileinfo (apply #'-cvs-create-fileinfo type dir file msg keys)))

;;; Fake selectors:

(defun cvs-fileinfo->full-path (fileinfo)
  "Return the full path for the file that is described in FILEINFO."
  (let ((dir (cvs-fileinfo->dir fileinfo)))
    (if (eq (cvs-fileinfo->type fileinfo) 'DIRCHANGE)
	(if (string= dir "") "." (directory-file-name dir))
      ;; Here, I use `concat' rather than `expand-file-name' because I want
      ;; the resulting path to stay relative if `dir' is relative.
      (concat dir (cvs-fileinfo->file fileinfo)))))

(defun cvs-fileinfo->pp-name (fi)
  "returns the filename as it should be displayed"
  (if cvs-display-full-path
      (cvs-fileinfo->full-path fi)
    (cvs-fileinfo->file fi)))

(defun cvs-fileinfo->backup-file (fileinfo)
  "Construct the file name of the backup file for FILEINFO."
  (let* ((dir (cvs-fileinfo->dir fileinfo))
	 (file (cvs-fileinfo->file fileinfo))
	 (files (directory-files dir nil
				 (concat "^" (regexp-quote cvs-bakprefix)
					 (regexp-quote file) "\\.")))
	 (default-directory dir)
	 bf)
    (dolist (f files bf)
      (when (and (file-readable-p f)
		 (or (null bf) (file-newer-than-file-p f bf)))
	(setq bf (concat dir f))))))

(defun cvs-fileinfo->handled (fileinfo)
  "Tell if this requires further action"
  (memq (cvs-fileinfo->type fileinfo) '(UP-TO-DATE DEAD)))


;;; Predicate:

(defun boolp (x) (or (eq t x) (null x)))
(defun cvs-check-fileinfo (fi)
  "check FI's conformance to some conventions."
  (let ((check 'none)
	(type (cvs-fileinfo->type fi))
	(subtype (cvs-fileinfo->subtype fi))
	(marked (cvs-fileinfo->marked fi))
	(dir (cvs-fileinfo->dir fi))
	(file (cvs-fileinfo->file fi))
	(base-rev (cvs-fileinfo->base-rev fi))
	(head-rev (cvs-fileinfo->head-rev fi))
	(full-log (cvs-fileinfo->full-log fi)))
    (if (and (setq check 'marked)	(boolp marked)
	     (setq check 'base-rev)	(or (null base-rev) (stringp base-rev))
	     (setq check 'head-rev)	(or (null head-rev) (stringp head-rev))
	     (setq check 'full-log)	(stringp full-log)
	     (setq check 'dir)
	     (and (stringp dir)
		  (not (file-name-absolute-p dir))
		  (or (string= dir "")
		      (string= dir (file-name-as-directory dir))))
	     (setq check 'file)
	     (and (stringp file)
		  (string= file (file-name-nondirectory file)))
	     (setq check 'type)		(symbolp type)
	     (setq check 'consistency)
	     (case type
	       (UP-TO-DATE
		(or (memq subtype '(UPDATED ADDED COMMITTED PATCHED RESURRECTED))
		    (null subtype)))
	       (MODIFIED
		(or (null subtype) (memq subtype '(MERGED))))
	       (MESSAGE
		(or (null subtype) (memq subtype '(TEMP))))
	       (DIRCHANGE (and (null subtype) (string= "." file)))
	       (DEAD t)
	       ((NEED-UPDATE ADDED NEED-REMOVE
			     REMOVED NEED-MERGE CONFLICT
			     MOD-CONFLICT UNKNOWN MESSAGE)
		(null subtype))))
	fi
      (error "invalid :%s in cvs-fileinfo %s" check fi))))


;;;; State table
;;;;
;;;; This state table holds information about what you can do.
;;;;
;;;; See the doc string for format.
;;;
;;; FIXME: currently there's no way for the user to see the
;;; applicable help string at a time when it would be useful.
;;;
;;; FIXME: this thing is very inconsistent and needs a good going
;;; over.

;; Poor man's attempt at expressing the `subtyping' among filters
(defconst removed '(removed safe-rm))

(defconst cvs-states
  `((NEED-UPDATE	update diff tag)
    (UP-TO-DATE		update nil remove diff safe-rm tag)
    (MODIFIED		update commit undo remove diff merge tag)
    (ADDED		update commit remove tag)
    (NEED-REMOVE     	remove undo ,@removed tag)
    (REMOVED     	commit add undo ,@removed tag)
    (NEED-MERGE     	update undo diff tag)
    (CONFLICT		merge remove undo commit diff tag)
    (MOD-CONFLICT	undo ,@removed tag)
    (DIRCHANGE		update diff ,(if cvs-allow-dir-commit 'commit) tag)
    (UNKNOWN		ignore add remove tag)
    (DEAD		)
    (MESSAGE))
  "Fileinfo state descriptions for pcl-cvs.
This is an assoc list.  Each element consists of (STATE . FUNS)
- STATE (described in cvs-create-fileinfo) is the key
- FUNS is the list of applicable operations.
  The first one (if any) should be the default action.
Most of the actions have the obvious meaning.
`safe-rm' indicates that the file can be removed without losing any information.
`removed' says that the file is already absent.")

(defconst cvs-states-description
  '((NEED-UPDATE 
     "A newer revision of the file exists in the repository.")
;;     (UPDATED
;;      "The newest revision of the file has been retrieved from the repository.")
;;     (PATCHED
;;      "The newest revision of the file has been retrieved from the repository by
;; means of a diff applied by the local patch program.")
    (MODIFIED
     "You have modified the file locally.")
    (ADDED
     "You have added the file, but not yet committed it.")
    (NEED-REMOVE
     "You have removed the file from your working copy, but not yet 
told CVS that you really want to remove the file.
\\[cvs-moderemove-file]  Tell CVS to remove the file from the repository.
    (You will have to commit the removal before anybody else sees it).
\\[cvs-mode-add]  Retrieve the latest revision from the repository.")
    (REMOVED
     "The file is removed, but you need to commit the removal to the repository.")
    (NEED-MERGE
     "The file is modified by you and a new revision is present in the repository.
You need to merge the changes into your working copy.  You can use
\\[cvs-update]  to update an entire work area, but you cannot (yet)
merge a single file from within pcl-cvs yet.  Sorry.")
;;     (MERGED
;;      "Changes from the repository have been merged into your working copy of
;; the file.  No conflicts were found.  You need to commit your changes.")
    (CONFLICT
     "Conflicts were found while merging changes made in the repository with
your copy of the file.  You have to resolve those conflicts manually,
and then commit the file.")
;;     (UNRES-CONFLICT
;;      "Unresolved conflicts still exists in the file.  You have to fix
;; them before attempting to commit the file.")
    (MOD-CONFLICT
     "You have removed the file, but somebody has committed a newer
revision than the one you are trying to remove.  Use
\\[cvs-mode-undo]  to cancel your removal of the file and get the
latest revision.  You can then try to remove the file again.")
    (DIRCHANGE
     "This line represents a directory.  Several operations can be performed on
the directory as a whole; they will be applied to all of the files in the
directory where it makes sense.  Other files will be ignored.
\\[cvs-mode-find-file] and \\[cvs-mode-find-file-other-window] will run dired.")
    (UNKNOWN
     "CVS doesn't know what to make of this file.  You can add it to the
repository, tell CVS to ignore it, or remove the file.")
    (UP-TO-DATE
     "The file is up-to-date (that is, the latest revision in the
repository is identical to your working copy).")
    (MESSAGE
     "Either this is a status message that you can ignore, or something
went wrong.  Anyhow, pcl-cvs is not smart enough to handle
this case.  You might have to fix this situation manually.")))

;;;;
;;;; Utility functions
;;;;

;;----------
(defun cvs-applicable-p (fileinfo func)
  "Check if FUNC is applicable on FILEINFO.
If FUNC is `nil', always return t."
  (eq (car (memq func (cdr (assq (cvs-fileinfo->type fileinfo) cvs-states))))
      func))

(defun cvs-default-action (fileinfo)
  "Return some kind of \"default\" action to be performed."
  (second (assq (cvs-fileinfo->type fileinfo) cvs-states)))

;;; fileinfo pretty-printers:

(defun cvs-add-face (str face &optional keymap)
  (when cvs-highlight
    (add-text-properties 0 (length str)
			 (list* 'face face
				(when keymap
				  (list 'mouse-face 'highlight
					'local-map keymap)))
			 str))
  str)

;;----------
(defun cvs-fileinfo-pp (fileinfo)
  "Pretty print FILEINFO.  Insert a printed representation in current buffer.
For use by the cookie package."
  (cvs-check-fileinfo fileinfo)
  (let ((type (cvs-fileinfo->type fileinfo)))
    (insert
     (case type
       (DIRCHANGE (concat "In directory "
			  (cvs-add-face (cvs-fileinfo->full-path fileinfo)
					'cvs-header-face cvs-dirname-map)
			  ":"))
       (MESSAGE (format "Message: %s"
			(cvs-fileinfo->full-log fileinfo)))
       (t
	(let* ((status (if (cvs-fileinfo->marked fileinfo)
			   (cvs-add-face "*" 'cvs-marked-face)
			 " "))
	       (file (cvs-add-face (cvs-fileinfo->pp-name fileinfo)
				   'cvs-filename-face cvs-filename-map))
	       (base (or (cvs-fileinfo->base-rev fileinfo) ""))
	       (head (cvs-fileinfo->head-rev fileinfo))
	       (type
		(multiple-value-bind (str face)
		    (case type
		      (UP-TO-DATE (values "Up-to-date" 'cvs-handled-face))
		      (UNKNOWN (values "Unknown" 'cvs-unknown-face))
		      (t (values
			  (case type
			    (NEED-UPDATE  "Need update")
			    (MODIFIED	  "Modified")
			    (NEED-MERGE	  "Need merge")
			    (CONFLICT	  "Conflict")
			    (MOD-CONFLICT "Not removed")
			    (REMOVED	  "Removed")
			    (ADDED	  "Added")
			    (NEED-REMOVE  "Need remove")
			    (DEAD	  ""))
			  'cvs-need-action-face)))
		  (cvs-add-face str face cvs-status-map)))
	       (side (or
		      ;; maybe a subtype
		      (case (cvs-fileinfo->subtype fileinfo)
			(ADDED		"added")
			(UPDATED	"updated")
			(PATCHED	"patched")
			(COMMITTED	"committed")
			(RESURRECTED	"resurrected")
			(MERGED		"merged"))
		      ;; or the head-rev
		      (when (and head (not (string= head base))) head)
		      ;; or nothing
		      ""))
	       (action (cvs-add-face (case (cvs-default-action fileinfo)
				       (commit "com")
				       (update "upd")
				       (undo   "udo")
				       (t      "   "))
				     'cvs-action-face
				     cvs-action-map)))
	  (concat (string-fill side 11) " "
		  status " "
		  (string-fill type 11) " "
		  action " "
		  (string-fill base 11) " "
		  file)))))))
;; 	  (format "%-9s %s %-11s %s %-8s %s"
;; 	  	  side status type action base file)))))))


(defun cvs-fileinfo-update (fi fi-new)
  "Update FI with the information provided in FI-NEW."
  (let ((type (cvs-fileinfo->type fi-new))
	(merge (cvs-fileinfo->merge fi-new)))
    (setf (cvs-fileinfo->type fi) type)
    (setf (cvs-fileinfo->subtype fi) (cvs-fileinfo->subtype fi-new))
    (setf (cvs-fileinfo->full-log fi) (cvs-fileinfo->full-log fi-new))
    (setf (cvs-fileinfo->base-rev fi) (cvs-fileinfo->base-rev fi-new))
    (setf (cvs-fileinfo->head-rev fi) (cvs-fileinfo->head-rev fi-new))
    (cond
     (merge (setf (cvs-fileinfo->merge fi) merge))
     ((memq type '(UP-TO-DATE NEED-UPDATE))
      (setf (cvs-fileinfo->merge fi) nil)))))

;;----------
(defun cvs-compare-fileinfos (a b)
  "Compare fileinfo A with fileinfo B and return t if A is `less'.
The ordering defined by this function is such that directories are
sorted alphabetically, and inside every directory the DIRCHANGE
fileinfo will appear first, followed by all files (alphabetically)."
  (cond
   ;; Sort according to directories.
   ((string< (cvs-fileinfo->dir a) (cvs-fileinfo->dir b)) t)
   ((not (string= (cvs-fileinfo->dir a) (cvs-fileinfo->dir b))) nil)
   
   ;; The DIRCHANGE entry is always first within the directory.
   ((eq (cvs-fileinfo->type a) 'DIRCHANGE) t)
   ((eq (cvs-fileinfo->type b) 'DIRCHANGE) nil)

   ;; All files are sorted by file name.
   ((string< (cvs-fileinfo->file a) (cvs-fileinfo->file b)))))

;;----------
;; (defun cvs-mode-debug-fileinfo ()
;;   "View the selected fileinfos in a temporary buffer."
;;   (interactive)
;;   (let ((marked (cvs-get-marked (cvs-ignore-marks-p
;;                                  cvs-default-ignore-marks))))
;;     (with-output-to-temp-buffer "*cvs-debug*"
;;       (dolist (tin marked)
;;         (let ((fh (tin-cookie cvs-cookie-handle tin)))
;;           (princ (format "subtype:   %s\n" (cvs-fileinfo->subtype fh)))
;;           (princ (format "marked:    %s\n" (cvs-fileinfo->marked fh)))
;;           (princ (format "type:      %s\n" (cvs-fileinfo->type fh)))
;;           (princ (format "directory: %s\n" (cvs-fileinfo->dir fh)))
;;           (princ (format "filename:  %s\n" (cvs-fileinfo->file fh)))
;;           (princ (format "base-rev:  %s\n" (cvs-fileinfo->base-rev fh)))
;;           (princ (format "head-rev:  %s\n" (cvs-fileinfo->head-rev fh)))
;;           (princ (format "full-log:  %s\n" (cvs-fileinfo->full-log fh)))
;;           (princ "\n"))))))

;;;; End of the cvs-fileinfo type.


(provide 'pcl-cvs-info)
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.