Source

XEmacs / configure.in

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
1001
1002
1003
1004
1005
1006
1007
1008
1009
1010
1011
1012
1013
1014
1015
1016
1017
1018
1019
1020
1021
1022
1023
1024
1025
1026
1027
1028
1029
1030
1031
1032
1033
1034
1035
1036
1037
1038
1039
1040
1041
1042
1043
1044
1045
1046
1047
1048
1049
1050
1051
1052
1053
1054
1055
1056
1057
1058
1059
1060
1061
1062
1063
1064
1065
1066
1067
1068
1069
1070
1071
1072
1073
1074
1075
1076
1077
1078
1079
1080
1081
1082
1083
1084
1085
1086
1087
1088
1089
1090
1091
1092
1093
1094
1095
1096
1097
1098
1099
1100
1101
1102
1103
1104
1105
1106
1107
1108
1109
1110
1111
1112
1113
1114
1115
1116
1117
1118
1119
1120
1121
1122
1123
1124
1125
1126
1127
1128
1129
1130
1131
1132
1133
1134
1135
1136
1137
1138
1139
1140
1141
1142
1143
1144
1145
1146
1147
1148
1149
1150
1151
1152
1153
1154
1155
1156
1157
1158
1159
1160
1161
1162
1163
1164
1165
1166
1167
1168
1169
1170
1171
1172
1173
1174
1175
1176
1177
1178
1179
1180
1181
1182
1183
1184
1185
1186
1187
1188
1189
1190
1191
1192
1193
1194
1195
1196
1197
1198
1199
1200
1201
1202
1203
1204
1205
1206
1207
1208
1209
1210
1211
1212
1213
1214
1215
1216
1217
1218
1219
1220
1221
1222
1223
1224
1225
1226
1227
1228
1229
1230
1231
1232
1233
1234
1235
1236
1237
1238
1239
1240
1241
1242
1243
1244
1245
1246
1247
1248
1249
1250
1251
1252
1253
1254
1255
1256
1257
1258
1259
1260
1261
1262
1263
1264
1265
1266
1267
1268
1269
1270
1271
1272
1273
1274
1275
1276
1277
1278
1279
1280
1281
1282
1283
1284
1285
1286
1287
1288
1289
1290
1291
1292
1293
1294
1295
1296
1297
1298
1299
1300
1301
1302
1303
1304
1305
1306
1307
1308
1309
1310
1311
1312
1313
1314
1315
1316
1317
1318
1319
1320
1321
1322
1323
1324
1325
1326
1327
1328
1329
1330
1331
1332
1333
1334
1335
1336
1337
1338
1339
1340
1341
1342
1343
1344
1345
1346
1347
1348
1349
1350
1351
1352
1353
1354
1355
1356
1357
1358
1359
1360
1361
1362
1363
1364
1365
1366
1367
1368
1369
1370
1371
1372
1373
1374
1375
1376
1377
1378
1379
1380
1381
1382
1383
1384
1385
1386
1387
1388
1389
1390
1391
1392
1393
1394
1395
1396
1397
1398
1399
1400
1401
1402
1403
1404
1405
1406
1407
1408
1409
1410
1411
1412
1413
1414
1415
1416
1417
1418
1419
1420
1421
1422
1423
1424
1425
1426
1427
1428
1429
1430
1431
1432
1433
1434
1435
1436
1437
1438
1439
1440
1441
1442
1443
1444
1445
1446
1447
1448
1449
1450
1451
1452
1453
1454
1455
1456
1457
1458
1459
1460
1461
1462
1463
1464
1465
1466
1467
1468
1469
1470
1471
1472
1473
1474
1475
1476
1477
1478
1479
1480
1481
1482
1483
1484
1485
1486
1487
1488
1489
1490
1491
1492
1493
1494
1495
1496
1497
1498
1499
1500
1501
1502
1503
1504
1505
1506
1507
1508
1509
1510
1511
1512
1513
1514
1515
1516
1517
1518
1519
1520
1521
1522
1523
1524
1525
1526
1527
1528
1529
1530
1531
1532
1533
1534
1535
1536
1537
1538
1539
1540
1541
1542
1543
1544
1545
1546
1547
1548
1549
1550
1551
1552
1553
1554
1555
1556
1557
1558
1559
1560
1561
1562
1563
1564
1565
1566
1567
1568
1569
1570
1571
1572
1573
1574
1575
1576
1577
1578
1579
1580
1581
1582
1583
1584
1585
1586
1587
1588
1589
1590
1591
1592
1593
1594
1595
1596
1597
1598
1599
1600
1601
1602
1603
1604
1605
1606
1607
1608
1609
1610
1611
1612
1613
1614
1615
1616
1617
1618
1619
1620
1621
1622
1623
1624
1625
1626
1627
1628
1629
1630
1631
1632
1633
1634
1635
1636
1637
1638
1639
1640
1641
1642
1643
1644
1645
1646
1647
1648
1649
1650
1651
1652
1653
1654
1655
1656
1657
1658
1659
1660
1661
1662
1663
1664
1665
1666
1667
1668
1669
1670
1671
1672
1673
1674
1675
1676
1677
1678
1679
1680
1681
1682
1683
1684
1685
1686
1687
1688
1689
1690
1691
1692
1693
1694
1695
1696
1697
1698
1699
1700
1701
1702
1703
1704
1705
1706
1707
1708
1709
1710
1711
1712
1713
1714
1715
1716
1717
1718
1719
1720
1721
1722
1723
1724
1725
1726
1727
1728
1729
1730
1731
1732
1733
1734
1735
1736
1737
1738
1739
1740
1741
1742
1743
1744
1745
1746
1747
1748
1749
1750
1751
1752
1753
1754
1755
1756
1757
1758
1759
1760
1761
1762
1763
1764
1765
1766
1767
1768
1769
1770
1771
1772
1773
1774
1775
1776
1777
1778
1779
1780
1781
1782
1783
1784
1785
1786
1787
1788
1789
1790
1791
1792
1793
1794
1795
1796
1797
1798
1799
1800
1801
1802
1803
1804
1805
1806
1807
1808
1809
1810
1811
1812
1813
1814
1815
1816
1817
1818
1819
1820
1821
1822
1823
1824
1825
1826
1827
1828
1829
1830
1831
1832
1833
1834
1835
1836
1837
1838
1839
1840
1841
1842
1843
1844
1845
1846
1847
1848
1849
1850
1851
1852
1853
1854
1855
1856
1857
1858
1859
1860
1861
1862
1863
1864
1865
1866
1867
1868
1869
1870
1871
1872
1873
1874
1875
1876
1877
1878
1879
1880
1881
1882
1883
1884
1885
1886
1887
1888
1889
1890
1891
1892
1893
1894
1895
1896
1897
1898
1899
1900
1901
1902
1903
1904
1905
1906
1907
1908
1909
1910
1911
1912
1913
1914
1915
1916
1917
1918
1919
1920
1921
1922
1923
1924
1925
1926
1927
1928
1929
1930
1931
1932
1933
1934
1935
1936
1937
1938
1939
1940
1941
1942
1943
1944
1945
1946
1947
1948
1949
1950
1951
1952
1953
1954
1955
1956
1957
1958
1959
1960
1961
1962
1963
1964
1965
1966
1967
1968
1969
1970
1971
1972
1973
1974
1975
1976
1977
1978
1979
1980
1981
1982
1983
1984
1985
1986
1987
1988
1989
1990
1991
1992
1993
1994
1995
1996
1997
1998
1999
2000
2001
2002
2003
2004
2005
2006
2007
2008
2009
2010
2011
2012
2013
2014
2015
2016
2017
2018
2019
2020
2021
2022
2023
2024
2025
2026
2027
2028
2029
2030
2031
2032
2033
2034
2035
2036
2037
2038
2039
2040
2041
2042
2043
2044
2045
2046
2047
2048
2049
2050
2051
2052
2053
2054
2055
2056
2057
2058
2059
2060
2061
2062
2063
2064
2065
2066
2067
2068
2069
2070
2071
2072
2073
2074
2075
2076
2077
2078
2079
2080
2081
2082
2083
2084
2085
2086
2087
2088
2089
2090
2091
2092
2093
2094
2095
2096
2097
2098
2099
2100
2101
2102
2103
2104
2105
2106
2107
2108
2109
2110
2111
2112
2113
2114
2115
2116
2117
2118
2119
2120
2121
2122
2123
2124
2125
2126
2127
2128
2129
2130
2131
2132
2133
2134
2135
2136
2137
2138
2139
2140
2141
2142
2143
2144
2145
2146
2147
2148
2149
2150
2151
2152
2153
2154
2155
2156
2157
2158
2159
2160
2161
2162
2163
2164
2165
2166
2167
2168
2169
2170
2171
2172
2173
2174
2175
2176
2177
2178
2179
2180
2181
2182
2183
2184
2185
2186
2187
2188
2189
2190
2191
2192
2193
2194
2195
2196
2197
2198
2199
2200
2201
2202
2203
2204
2205
2206
2207
2208
2209
2210
2211
2212
2213
2214
2215
2216
2217
2218
2219
2220
2221
2222
2223
2224
2225
2226
2227
2228
2229
2230
2231
2232
2233
2234
2235
2236
2237
2238
2239
2240
2241
2242
2243
2244
2245
2246
2247
2248
2249
2250
2251
2252
2253
2254
2255
2256
2257
2258
2259
2260
2261
2262
2263
2264
2265
2266
2267
2268
2269
2270
2271
2272
2273
2274
2275
2276
2277
2278
2279
2280
2281
2282
2283
2284
2285
2286
2287
2288
2289
2290
2291
2292
2293
2294
2295
2296
2297
2298
2299
2300
2301
2302
2303
2304
2305
2306
2307
2308
2309
2310
2311
2312
2313
2314
2315
2316
2317
2318
2319
2320
2321
2322
2323
2324
2325
2326
2327
2328
2329
2330
2331
2332
2333
2334
2335
2336
2337
2338
2339
2340
2341
2342
2343
2344
2345
2346
2347
2348
2349
2350
2351
2352
2353
2354
2355
2356
2357
2358
2359
2360
2361
2362
2363
2364
2365
2366
2367
2368
2369
2370
2371
2372
2373
2374
2375
2376
2377
2378
2379
2380
2381
2382
2383
2384
2385
2386
2387
2388
2389
2390
2391
2392
2393
2394
2395
2396
2397
2398
2399
2400
2401
2402
2403
2404
2405
2406
2407
2408
2409
2410
2411
2412
2413
2414
2415
2416
2417
2418
2419
2420
2421
2422
2423
2424
2425
2426
2427
2428
2429
2430
2431
2432
2433
2434
2435
2436
2437
2438
2439
2440
2441
2442
2443
2444
2445
2446
2447
2448
2449
2450
2451
2452
2453
2454
2455
2456
2457
2458
2459
2460
2461
2462
2463
2464
2465
2466
2467
2468
2469
2470
2471
2472
2473
2474
2475
2476
2477
2478
2479
2480
2481
2482
2483
2484
2485
2486
2487
2488
2489
2490
2491
2492
2493
2494
2495
2496
2497
2498
2499
2500
2501
2502
2503
2504
2505
2506
2507
2508
2509
2510
2511
2512
2513
2514
2515
2516
2517
2518
2519
2520
2521
2522
2523
2524
2525
2526
2527
2528
2529
2530
2531
2532
2533
2534
2535
2536
2537
2538
2539
2540
2541
2542
2543
2544
2545
2546
2547
2548
2549
2550
2551
2552
2553
2554
2555
2556
2557
2558
2559
2560
2561
2562
2563
2564
2565
2566
2567
2568
2569
2570
2571
2572
2573
2574
2575
2576
2577
2578
2579
2580
2581
2582
2583
2584
2585
2586
2587
2588
2589
2590
2591
2592
2593
2594
2595
2596
2597
2598
2599
2600
2601
2602
2603
2604
2605
2606
2607
2608
2609
2610
2611
2612
2613
2614
2615
2616
2617
2618
2619
2620
2621
2622
2623
2624
2625
2626
2627
2628
2629
2630
2631
2632
2633
2634
2635
2636
2637
2638
2639
2640
2641
2642
2643
2644
2645
2646
2647
2648
2649
2650
2651
2652
2653
2654
2655
2656
2657
2658
2659
2660
2661
2662
2663
2664
2665
2666
2667
2668
2669
2670
2671
2672
2673
2674
2675
2676
2677
2678
2679
2680
2681
2682
2683
2684
2685
2686
2687
2688
2689
2690
2691
2692
2693
2694
2695
2696
2697
2698
2699
2700
2701
2702
2703
2704
2705
2706
2707
2708
2709
2710
2711
2712
2713
2714
2715
2716
2717
2718
2719
2720
2721
2722
2723
2724
2725
2726
2727
2728
2729
2730
2731
2732
2733
2734
2735
2736
2737
2738
2739
2740
2741
2742
2743
2744
2745
2746
2747
2748
2749
2750
2751
2752
2753
2754
2755
2756
2757
2758
2759
2760
2761
2762
2763
2764
2765
2766
2767
2768
2769
2770
2771
2772
2773
2774
2775
2776
2777
2778
2779
2780
2781
2782
2783
2784
2785
2786
2787
2788
2789
2790
2791
2792
2793
2794
2795
2796
2797
2798
2799
2800
2801
2802
2803
2804
2805
2806
2807
2808
2809
2810
2811
2812
2813
2814
2815
2816
2817
2818
2819
2820
2821
2822
2823
2824
2825
2826
2827
2828
2829
2830
2831
2832
2833
2834
2835
2836
2837
2838
2839
2840
2841
2842
2843
2844
2845
2846
2847
2848
2849
2850
2851
2852
2853
2854
2855
2856
2857
2858
2859
2860
2861
2862
2863
2864
2865
2866
2867
2868
2869
2870
2871
2872
2873
2874
2875
2876
2877
2878
2879
2880
2881
2882
2883
2884
2885
2886
2887
2888
2889
2890
2891
2892
2893
2894
2895
2896
2897
2898
2899
2900
2901
2902
2903
2904
2905
2906
2907
2908
2909
2910
2911
2912
2913
2914
2915
2916
2917
2918
2919
2920
2921
2922
2923
2924
2925
2926
2927
2928
2929
2930
2931
2932
2933
2934
2935
2936
2937
2938
2939
2940
2941
2942
2943
2944
2945
2946
2947
2948
2949
2950
2951
2952
2953
2954
2955
2956
2957
2958
2959
2960
2961
2962
2963
2964
2965
2966
2967
2968
2969
2970
2971
2972
2973
2974
2975
2976
2977
2978
2979
2980
2981
2982
2983
2984
2985
2986
2987
2988
2989
2990
2991
2992
2993
2994
2995
2996
2997
2998
2999
3000
3001
3002
3003
3004
3005
3006
3007
3008
3009
3010
3011
3012
3013
3014
3015
3016
3017
3018
3019
3020
3021
3022
3023
3024
3025
3026
3027
3028
3029
3030
3031
3032
3033
3034
3035
3036
3037
3038
3039
3040
3041
3042
3043
3044
3045
3046
3047
3048
3049
3050
3051
3052
3053
3054
3055
3056
3057
3058
3059
3060
3061
3062
3063
3064
3065
3066
3067
3068
3069
3070
3071
3072
3073
3074
3075
3076
3077
3078
3079
3080
3081
3082
3083
3084
3085
3086
3087
3088
3089
3090
3091
3092
3093
3094
3095
3096
3097
3098
3099
3100
3101
3102
3103
3104
3105
3106
3107
3108
3109
3110
3111
3112
3113
3114
3115
3116
3117
3118
3119
3120
3121
3122
3123
3124
3125
3126
3127
3128
3129
3130
3131
3132
3133
3134
3135
3136
3137
3138
3139
3140
3141
3142
3143
3144
3145
3146
3147
3148
3149
3150
3151
3152
3153
3154
3155
3156
3157
3158
3159
3160
3161
3162
3163
3164
3165
3166
3167
3168
3169
3170
3171
3172
3173
3174
3175
3176
3177
3178
3179
3180
3181
3182
3183
3184
3185
3186
3187
3188
3189
3190
3191
3192
3193
3194
3195
3196
3197
3198
3199
3200
3201
3202
3203
3204
3205
3206
3207
3208
3209
3210
3211
3212
3213
3214
3215
3216
3217
3218
3219
3220
3221
3222
3223
3224
3225
3226
3227
3228
3229
3230
3231
3232
3233
3234
3235
3236
3237
3238
3239
3240
3241
3242
3243
3244
3245
3246
3247
3248
3249
3250
3251
3252
3253
3254
3255
3256
3257
3258
3259
3260
3261
3262
3263
3264
3265
3266
3267
3268
3269
3270
3271
3272
3273
3274
3275
3276
3277
3278
3279
3280
3281
3282
3283
3284
3285
3286
3287
3288
3289
3290
3291
3292
3293
3294
3295
3296
3297
3298
3299
3300
3301
3302
3303
3304
3305
3306
3307
3308
3309
3310
3311
3312
3313
3314
3315
3316
3317
3318
3319
3320
3321
3322
3323
3324
3325
3326
3327
3328
3329
3330
3331
3332
3333
3334
3335
3336
3337
3338
3339
3340
3341
3342
3343
3344
3345
3346
3347
3348
3349
3350
3351
3352
3353
3354
3355
3356
3357
3358
3359
3360
3361
3362
3363
3364
3365
3366
3367
3368
3369
3370
3371
3372
3373
3374
3375
3376
3377
3378
3379
3380
3381
3382
3383
3384
3385
3386
3387
3388
3389
3390
3391
3392
3393
3394
3395
3396
3397
3398
3399
3400
3401
3402
3403
3404
3405
3406
3407
3408
3409
3410
3411
3412
3413
3414
3415
3416
3417
3418
3419
3420
3421
3422
3423
3424
3425
3426
3427
3428
3429
3430
3431
3432
3433
3434
3435
3436
3437
3438
3439
3440
3441
3442
3443
3444
3445
3446
3447
3448
3449
3450
3451
3452
3453
3454
3455
3456
3457
3458
3459
3460
3461
3462
3463
3464
3465
3466
3467
3468
3469
3470
3471
3472
3473
3474
3475
3476
3477
3478
3479
3480
3481
3482
3483
3484
3485
3486
3487
3488
3489
3490
3491
3492
3493
3494
3495
3496
3497
3498
3499
3500
3501
3502
3503
3504
3505
3506
3507
3508
3509
3510
3511
3512
3513
3514
3515
3516
3517
3518
3519
3520
3521
3522
3523
3524
3525
3526
3527
3528
3529
3530
3531
3532
3533
3534
3535
3536
3537
3538
3539
3540
3541
3542
3543
3544
3545
3546
3547
3548
3549
3550
3551
3552
3553
3554
3555
3556
3557
3558
3559
3560
3561
3562
3563
3564
3565
3566
3567
3568
3569
3570
3571
3572
dnl Define our own header notice with own copyrights
define([AC_INIT_NOTICE],
[#### Configuration script for XEmacs.  Largely divergent from FSF.
#### Guess values for system-dependent variables and create Makefiles.
#### Generated automatically using autoconf version] AC_ACVERSION [
#### Copyright (C) 1992, 93, 94, 95, 96 Free Software Foundation, Inc.
#### Copyright (C) 1993-1995 Board of Trustees, University of Illinois.
#### Copyright (C) 1996, 1997 Sun Microsystems, Inc.
#### Copyright (C) 1995, 1996 Ben Wing.

### Don't edit this script!
### This script was automatically generated by the `autoconf' program
### from the file `./configure.in'.
### To rebuild it, execute the command
###	autoconf
### in the this directory.  You must have autoconf version 2.12 or later.

### This file is part of XEmacs.

### XEmacs is free software; you can redistribute it and/or modify it
### under the terms of the GNU General Public License as published by
### the Free Software Foundation; either version 2, or (at your
### option) any later version.

### XEmacs is distributed in the hope that it will be useful, but
### WITHOUT ANY WARRANTY; without even the implied warranty of
### MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
### General Public License for more details.

### You should have received a copy of the GNU General Public License
### along with XEmacs; see the file COPYING.  If not, write to the Free
### Software Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
### 02111-1307, USA.

### For usage, run `./configure --help'
### For more detailed information on building and installing XEmacs,
### read the file `INSTALL'.
###
### If configure succeeds, it leaves its status in config.status.
### A log of configuration tests can be found in config.log.
### If configure fails after disturbing the status quo,
### 	config.status is removed.
])

dnl Since XEmacs has configuration requirements that autoconf cannot
dnl meet, this file is an unholy marriage of custom-baked
dnl configuration code and autoconf macros.

dnl We use the m4 quoting characters [ ] (as established by the
dnl autoconf system), so quote them like this: [[foo]]

AC_PREREQ(2.12)dnl
dnl Redefine some standard autoconf macros
dnl here is how XEmacs is different:
dnl - no cache file
dnl - non-standard options
dnl - suport for extra-verbosity
dnl - ordinary libs are handled separately from X libs (might be a mistake)
dnl - various random kludges (e.g. -with-dnet=no

dnl PRINT_VAR(var var ...)  prints values of shell variables
define([PRINT_VAR],[for var in patsubst([$1],[[
]+],[ ]); do eval "echo \"$var = '\$$var'\""; done])

dnl Disable cache files:
dnl This is controversial, but I am convinced this is the right way to go,
dnl at least by default.  Otherwise there are too many surprises.
define([AC_CACHE_LOAD], )dnl
define([AC_CACHE_SAVE], )dnl
define([AC_CACHE_VAL], [
$2
])dnl

dnl Redefine AC_TRY_RUN_NATIVE to not throw away stderr while running
dnl AC_TRY_RUN_NATIVE(PROGRAM, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
define([AC_TRY_RUN_NATIVE],
[cat > conftest.$ac_ext <<EOF
[#]line __oline__ "configure"
#include "confdefs.h"
[$1]
EOF
if AC_TRY_EVAL(ac_link) && test -s conftest && (./conftest; exit) 2>&AC_FD_CC
then
dnl Do not remove the temporary files here, so they can be examined.
  ifelse([$2], , :, [$2])
else
  echo "configure: failed program was:" >&AC_FD_CC
  cat conftest.$ac_ext >&AC_FD_CC
ifelse([$3], , , [  rm -fr conftest*
  $3
])dnl
fi
rm -fr conftest*])


dnl Avoid spurious cross-compiling warnings from AC_TRY_RUN
dnl XEmacs is unlikely to ever cross-compile
define([AC_TRY_RUN],[AC_TRY_RUN_NATIVE([$1], [$2], [$3])])dnl


dnl Redefine AC_DEFINE* to provide more output if extra_verbose
dnl Set VARIABLE to VALUE, verbatim, or 1.
dnl AC_DEFINE(VARIABLE [, VALUE])
define([AC_DEFINE],
[{ test "$extra_verbose" = "yes" && cat << \EOF
    Defining $1[]ifelse($#, 2, [ = $2],)
EOF
cat >> confdefs.h <<\EOF
[#define] $1 ifelse($#, 2, [$2], 1)
EOF
}
])

define([AC_DEFINE_UNQUOTED],
[{ test "$extra_verbose" = "yes" && cat << EOF
    Defining $1[]ifelse($#, 2, [ = $2],)
EOF
cat >> confdefs.h <<EOF
[#define] $1 ifelse($#, 2, [$2], 1)
EOF
}
])


dnl redefine AC_CHECK_LIB in accordance with our own value of ac_link
dnl Add in extra kludgy check to support with_dnet=no
dnl Add in extra LDFLAGS arg, which PRECEDE libs
dnl Support --with-dnet=no

dnl AC_CHECK_LIB(LIBRARY, FUNCTION [, ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND
dnl             [, OTHER-LIBRARIES] [, LDFLAGS]]]])
define([AC_CHECK_LIB],
[ifelse([$1],dnet, [if test "$with_dnet" = "no" ; then
ac_cv_lib_dnet_dnet_ntoa=no
ifelse([$4], , , [$4]
)dnl
else
])]
AC_CHECK_LIB_ORIG_HACKED([$1],[$2],[$3],[$4],[$5], [$6])
[ifelse([$1],dnet,[fi
])]dnl
)

define([AC_CHECK_LIB_ORIG_HACKED],
[ifelse([$5],,AC_MSG_CHECKING([for $2 in -l$1]),
xe_msg_checking="for [$2] in -l[$1]"
test -n "[$5]" && xe_msg_checking="$xe_msg_checking using extra libs [$5]"
AC_MSG_CHECKING("$xe_msg_checking"))
dnl Use a cache variable name containing both the library and function name,
dnl because the test really is for library $1 defining function $2, not
dnl just for library $1.  Separate tests with the same $1 and different $2s
dnl may have different results.
ac_lib_var=`echo $1['_']$2 | sed 'y%./+-%__p_%'`
AC_CACHE_VAL(ac_cv_lib_$ac_lib_var,
[xe_check_libs="$6 -l$1 $5"
AC_TRY_LINK(dnl
ifelse([$2], [main], , dnl Avoid conflicting decl of main.
[/* Override any gcc2 internal prototype to avoid an error.  */
]ifelse(AC_LANG, CPLUSPLUS, [#ifdef __cplusplus
extern "C"
#endif
])dnl
[/* We use char because int might match the return type of a gcc2
    builtin and then its argument prototype would still apply.  */
char $2();
]),
	    [$2()],
	    eval "ac_cv_lib_$ac_lib_var=yes",
	    eval "ac_cv_lib_$ac_lib_var=no")
xe_check_libs=""
])dnl
if eval "test \"`echo '$ac_cv_lib_'$ac_lib_var`\" = yes" ; then
  AC_MSG_RESULT(yes)
  ifelse([$3], ,
[changequote(, )dnl
  ac_tr_lib=HAVE_LIB`echo $1 | sed -e 's/[^a-zA-Z0-9_]/_/g' \
    -e 'y/abcdefghijklmnopqrstuvwxyz/ABCDEFGHIJKLMNOPQRSTUVWXYZ/'`
changequote([, ])dnl
  AC_DEFINE_UNQUOTED($ac_tr_lib)
  XE_PREPEND([-l$1], LIBS)
], [$3])
else
  AC_MSG_RESULT(no)
ifelse([$4], , , [$4
])dnl
fi
])


dnl AC_LANG_C()
define([AC_LANG_C],
[define([AC_LANG], [C])dnl
ac_ext=c
dnl CFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
dnl ac_cpp='$CPP $CPPFLAGS'
dnl ac_compile='${CC-cc} -c $CFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC'
dnl ac_link='${CC-cc} -o conftest $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC'
dnl # $c_switch_x_machine  $c_switch_x_system
dnl # $ld_switch_x_machine $ld_switch_x_system
xe_cppflags='$CPPFLAGS $c_switch_site $c_switch_machine $c_switch_system $c_switch_x_site $X_CFLAGS'
xe_ldflags='$LDFLAGS $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_x_site $ld_switch_run'
xe_libs='$ld_call_shared $xe_check_libs $X_EXTRA_LIBS $libs_x $X_PRE_LIBS $LIBS $libs_machine $libs_system $libs_standard'
ac_cpp='$CPP '"$xe_cppflags"
ac_compile='${CC-cc} -c $CFLAGS '"$xe_cppflags"' conftest.$ac_ext 1>&AC_FD_CC'
ac_link='${CC-cc} -o conftest $CFLAGS '"$xe_cppflags $xe_ldflags"' conftest.$ac_ext '"$xe_libs"' 1>&AC_FD_CC'
cross_compiling=no
])

dnl The construct foo=`echo $w1 $w2 $w3` fails on some systems if $w1 = -e or -n
dnl So we use the following instead.
dnl XE_SPACE(var, words)
define([XE_SPACE],[
T=""
for W in $2; do if test -z "$T"; then T="$W"; else T="$T $W"; fi; done
$1="$T"
])dnl

dnl XE_ADD_OBJS(foo.o ...)
define([XE_ADD_OBJS],
[extra_objs="$extra_objs [$1]" && dnl
 if test "$extra_verbose" = "yes"; then
   echo "    xemacs will be linked with \"[$1]\""
 fi])

dnl XE_APPEND(value, varname)
define([XE_APPEND],
[[$2]="$[$2] [$1]" && dnl
 if test "$extra_verbose" = "yes"; then echo "    Appending \"[$1]\" to \$[$2]"; fi])

dnl XE_PREPEND(value, varname)
define([XE_PREPEND],
[[$2]="[$1] $[$2]" && dnl
 if test "$extra_verbose" = "yes"; then echo "    Prepending \"[$1]\" to \$[$2]"; fi])


dnl Initialize some variables set by options.
dnl The variables have the same names as the options, with
dnl dashes changed to underlines.

define([AC_INIT_PARSE_ARGS],[
dnl Initialize some variables set by options.
dnl The variables have the same names as the options, with
dnl dashes changed to underlines.
build=NONE
exec_prefix=NONE
host=NONE
no_create=
nonopt=NONE
no_recursion=
prefix=NONE
program_prefix=NONE
program_suffix=NONE
program_transform_name=s,x,x,
silent=
site=
srcdir=
target=NONE
verbose=
x_includes=NONE
x_libraries=NONE
CDPATH=.; export CDPATH

dnl Allow this script to work with zsh, by setting sh emulation options
if test -n "$ZSH_VERSION"; then
  setopt NO_BAD_PATTERN NO_BANG_HIST NO_BG_NICE NO_EQUALS NO_FUNCTION_ARGZERO
  setopt GLOB_SUBST NO_HUP INTERACTIVE_COMMENTS KSH_ARRAYS NO_MULTIOS NO_NOMATCH
  setopt RM_STAR_SILENT POSIX_BUILTINS SH_FILE_EXPANSION SH_GLOB SH_OPTION_LETTERS
  setopt SH_WORD_SPLIT BSD_ECHO IGNORE_BRACES
fi

dnl Installation directory options.
dnl These are left unexpanded so users can "make install exec_prefix=/foo"
dnl and all the variables that are supposed to be based on exec_prefix
dnl by default will actually change.
dnl Use braces instead of parens because sh, perl, etc. also accept them.
bindir='${exec_prefix}/bin'
sbindir='${exec_prefix}/sbin'
libexecdir='${exec_prefix}/libexec'
datadir='${prefix}/share'
sysconfdir='${prefix}/etc'
sharedstatedir='${prefix}/com'
localstatedir='${prefix}/var'
libdir='${{exec_prefix}}/lib'
includedir='${prefix}/include'
oldincludedir='/usr/include'
infodir='${prefix}/info'
mandir='${prefix}/man'

dnl Initialize some other variables.
subdirs=
MFLAGS= MAKEFLAGS=
dnl Maximum number of lines to put in a shell here document.
ac_max_here_lines=12
])dnl
AC_INIT(src/lisp.h)dnl
AC_CONFIG_HEADER(src/config.h lwlib/config.h)
dnl Remove any more than one leading "." element from the path name.
dnl If we do not remove them, then another "./" will be prepended to
dnl the file name each time we use config.status, and the program name
dnl will get larger and larger.  This would not be a problem, except
dnl that since progname gets recorded in all the Makefiles this script
dnl produces, move-if-change thinks they're different when they're
dnl not.
dnl
dnl It would be nice if we could put the ./ in a \( \) group and then
dnl apply the * operator to that, so we remove as many leading './././'s
dnl as are present, but some seds (like Ultrix's sed) don't allow you to
dnl apply * to a \( \) group.  Bleah.
progname="`echo $0 | sed 's:^\./\./:\./:'`"

dnl -----------------------------
dnl Establish some default values
dnl -----------------------------

XE_APPEND(lib-src, MAKE_SUBDIR)
XE_APPEND(lib-src, INSTALL_ARCH_DEP_SUBDIR)

dnl run_in_place='no'
prefix='/usr/local'
exec_prefix='${prefix}'
bindir='${exec_prefix}/bin'
dnl FSF 19.29 changes to:
dnl datadir='${prefix}/share'
dnl sharedstatedir='${prefix}/com'
dnl libexecdir='${exec_prefix}/libexec'
datadir='${prefix}/lib'
statedir='${prefix}/lib'
libdir='${exec_prefix}/lib'
mandir='${prefix}/man/man1'
infodir='${prefix}/lib/xemacs-${version}/info'
infodir_user_defined='no'
lispdir='${datadir}/xemacs-${version}/lisp'
lispdir_user_defined='no'
sitelispdir='${datadir}/xemacs/site-lisp'
etcdir='${datadir}/xemacs-${version}/etc'
etcdir_user_defined='no'
lockdir='${statedir}/xemacs/lock'
lockdir_user_defined='no'
archlibdir='${libdir}/xemacs-${version}/${configuration}'
archlibdir_user_defined='no'
with_menubars=''
with_scrollbars=''
with_dialogs=''
const_is_losing='yes'
puresize=''
cflags='UNSPECIFIED'
dynamic=''
with_x11=''
rel_alloc='default'
use_system_malloc='default'
energize_version=''
native_sound_lib=''
dnl use-assertions should be 'yes' by default.  Too many people in this
dnl world have core dumps turned off by default or \"cannot find where the
dnl core file went\".  At least we should get some useful output ...
use_assertions="yes"
dnl the following is set to yes or no later.
with_gif=""
dnl the following is set to yes or no later.
with_toolbars=""
with_tty=""
use_union_type="no"
with_dnet=""

dnl Usage message (get it via -help)
usage="Usage: $progname CONFIGURATION [[-OPTION[=VALUE] ...]]

Set compilation and installation parameters for XEmacs, and report.
CONFIGURATION specifies the machine and operating system to build for.

Note that for most of the following options, you can explicitly enable
them using \`--OPTION=yes' and explicitly disable them using \`--OPTION=no'.
This is especially useful for auto-detected options.

Options marked with a (*) are autodetected.


General options:

--help			Issue this usage message.
--verbose		Display the results of configure tests.
--extra-verbose		Display even more information, useful for debugging.


Compilation options:

--compiler=XXXX		Specify compiler.  Overrides environment variable CC.
--with-gcc (*)		Use GCC to compile XEmacs.
--with-gcc=no		Don't use GCC to compile XEmacs.
--with-gnu-make		Write the Makefiles to take advantage of
			special features of GNU Make. (GNU Make
			works fine on the Makefiles even without this
			option.  This just allows for simultaneous
			in-place and --srcdir building.)
--cflags=FLAGS		Compiler flags. Overrides environment variable CFLAGS.
--site-includes=DIR	Other header file directories.  Separate multiple
			dirs with spaces and use quotes to enclose.
--site-libraries=DIR	Other library directories.
--site-runtime-libraries=DIR
			Paths to add with -R flag.
--dynamic=yes		Link dynamically if supported by system.
--dynamic=no		Force static linking on systems where dynamic
			linking is the default.
--srcdir=DIR		Look for the XEmacs source files in DIR.
			See also --with-gnu-make.
--const-is-losing=no	Allow the use of const in the source code.


Installation options:

--prefix=DIR		Install files below DIR.  Defaults to \`$prefix'.


Window-system options:

--with-x (*)		Support the X Window System.
--with-x=no		Don't support X.
--x-includes=DIR 	Search for X header files in DIR.
--x-libraries=DIR	Search for X libraries in DIR.
--with-toolbars=no	Don't compile with any toolbar support.
--with-menubars=TYPE	Use TYPE menubars (lucid, motif, or no).  The Lucid
			widgets emulate Motif (mostly) but are faster.
			*WARNING*  The Motif menubar is currently broken.
--with-scrollbars=TYPE	Use TYPE scrollbars
			(lucid, motif, athena, athena3d, or no).
--with-dialogs=TYPE	Use TYPE dialog boxes (motif, athena, athena3d, or no).
			(Lucid menubars and scrollbars are the default.
			 Motif dialog boxes will be used if Motif can be
			 found.)
--with-cde (*)		Compile in support for CDE drag and drop.
--with-offix (*)	Compile in support for OffiX drag and drop.
--with-xmu=no (*)	For those unfortunates whose vendors don't ship Xmu.
--external-widget	Compile with external widget support.
--with-gif		Compile with support for GIF image conversion.
			This support is built-in and defaults to \`yes'.
--with-xpm (*)		Compile with support for XPM files.
			It is highly recommended that you obtain XPM
			(version 3.4h or better) if you don't already
			have it.  Get it from the XEmacs FTP site.
--with-xface (*)	Compile with support for X-Face mail header
	  		conversion.  Requires the compface library.
			Get it from the XEmacs FTP site.
--with-jpeg (*)		Compile with support for JPEG image conversion.
			Requires libjpeg from the Independent JPEG Group.
			Get it from the XEmacs FTP site.
--with-png (*)		Compile with support for PNG image conversion.
			Requires libpng.  Get it from the XEmacs FTP site.
--with-tiff		Compile with support for TIFF image conversion
			(not yet implemented).


TTY options:

--with-tty=no		Don't support TTY-s.
--with-ncurses (*)	Use the ncurses library for tty support.
--with-gpm (*) 		Compile in support for General Purpose Mouse.


Additional features:

--with-tooltalk (*)	Support the ToolTalk IPC protocol.
--with-workshop		Support the Sun WorkShop (formerly Sparcworks)
			development environment.
--with-energize		Support the Lucid Energize development environment.
			This doesn't currently work.
--with-socks		Compile with support for SOCKS (an Internet proxy).
--with-term		Compile with support for TERM (a way to multiplex
			serial lines and provide vaguely Internet-like
			functionality over a simple dialup connection,
			used on Linux and other systems.  NOTE: We can't
			guarantee that our TERM support coexists well
			with standard Internet connections).
--with-database=type (*) Compile with database support.  Valid types are
			\`no' or a comma-separated list of one or more
			of \`dbm', \`gnudbm', or \`berkdb'.
--with-sound=native (*)	Compile with native sound support.
--with-sound=nas	Compile with network sound support.
--with-sound=both	Compile with native and network sound support.
--native-sound-lib=LIB	Native sound support library.  Needed on Suns
			with --with-sound=both because both sound libraries
			are called libaudio.
--with-pop		support POP for mail retrieval
--with-kerberos		support Kerberos-authenticated POP
--with-hesiod		support Hesiod to get the POP server host
--with-dnet (*)		Compile with support for DECnet.
--mail-locking=TYPE (*)	Specify the locking to be used by movemail to prevent
			concurrent updates of mail spool files. Valid types
			are \`lockf', \`flock', and \`file'.

Internationalization options:

--with-mule		Compile with Mule (MUlti-Lingual Emacs) support,
			needed to suport non-Latin-1 (including Asian) languages.
--with-xim=xlib		Compile with support for X input methods,
--with-xim=motif (*)	Used in conjunction with Mule support.
			Use either raw Xlib to provide XIM support, or
			the Motif XmIm* routines (when available).
			NOTE:  On some systems bugs in X11's XIM support
			will cause XEmacs to crash, so by default,
			no XIM support is compiled in, unless running
			on Solaris and the XmIm* routines are detected.
--with-canna (*)	Compile with support for Canna (a Japanese input method
			used in conjunction with Mule support).
--with-wnn (*)		Compile with support for WNN (a multi-language input method
			used in conjunction with Mule support).
			This is beta level code.
--with-wnn6 (*)		Compile with support for WNN version 6
			This is alpha level code.
--with-i18n3		Compile with I18N level 3 (support for message
			translation).  This doesn't currently work.


Debugging options:

--debug			Compile with support for debugging XEmacs.
			(Causes code-size increase and little loss of speed.)
--error-checking=TYPE[[,TYPE]]...
			Compile with internal error-checking added.
			Causes noticeable loss of speed.  Valid types
			are extents, bufpos, malloc, gc, typecheck.
--error-checking=none	Disable all internal error-checking (the default).
--error-checking=all	Enable all internal error-checking.
--memory-usage-stats 	Compile with additional code to allow you to
			determine what XEmacs's memory is being used
		        for.  Causes a small code increase but no loss
			of speed.  Normally enabled when --debug is given.
--no-doc-file		Don't rebuild the DOC file unless it's explicitly
			deleted.  Only use during development. (It speeds
			up the compile-run-test cycle.)
--use-union-type	Enable or disable use of a union, instead of an
			int, for the fundamental Lisp_Object type; this
			provides stricter type-checking.  Only works with
			some systems and compilers.


Other options:

--puresize=VALUE	Override default amount of space for pure Lisp code.
--rel-alloc		Use the relocating allocator (default for this option
  			is system-dependent).
--with-clash-detection	Use lock files to detect multiple edits of the same file.
			The default is to not do clash detection.
--use-system-malloc	Force use of the system malloc, rather than GNU
			malloc.

You may also specify any of the \`path' variables found in
Makefile.in, including --bindir, --libdir, --lispdir, --datadir, and
so on.  Note that we recommend against explicitly setting any of these
variables.  See the INSTALL file for a complete list plus the reasons
we advise not changing them.

If successful, $progname leaves its status in config.status.  If
unsuccessful after disturbing the status quo, it removes config.status.

The configure build process also used the following environment variables:
CC        C compiler to use (but configure flags take precedence)
CPP       C preprocessor to use (such as /usr/ccs/lib/cpp or cc -E)
CFLAGS    C compiler compilation flags (such as -O)
CPPFLAGS  Additional compilation flags (such as -I/foo) used only by the preprocessor
LDFLAGS   Additional linker flags (such as -L/foo)
LIBS      Additional libraries (such as -lfoo)

For more details on the install process, consult the INSTALL file.
"

dnl ------------------
dnl Options Processing
dnl ------------------

define([USAGE_ERROR],
[(echo "$progname: Usage error:"
echo " " $1
echo "  Use \`$progname --help' to show usage.") >&2 && exit 1])

dnl Record all the arguments, so we can save them in config.status.
arguments="$@"

dnl Shell Magic: Quote the quoted arguments in ARGUMENTS.  At a later date,
dnl in order to get the arguments back in $@, we have to do an
dnl 'eval set x "$quoted_arguments"; shift'
dnl # We use sed to turn embedded ' into '"'"'.  I truly hate sh quoting.
quoted_sed_magic=s/"'"/"'"'"'"'"'"'"'"/g
quoted_arguments=
for i in "$@"; do
   case "$i" in
   -no-create | --no-create | --no-creat | --no-crea | --no-cre \
   | --no-cr | --no-c) ;;
   -no-recursion | --no-recursion | --no-recursio | --no-recursi \
   | --no-recurs | --no-recur | --no-recu | --no-rec | --no-re | --no-r) ;;
   *)
   quoted_i="`echo '' $i | sed -e 's:^ ::' -e $quoted_sed_magic`"
   quoted_arguments="$quoted_arguments '$quoted_i'" ;;
   esac
done

dnl Do not use shift -- that destroys the argument list, which autoconf needs
dnl to produce config.status.  It turns out that "set - $arguments" does not
dnl work portably.
dnl However, it also turns out that many shells cannot expand ${10} at all.
dnl So using an index variable does not work either.  It is possible to use
dnl some shell magic to make 'set x "$arguments"; shift' work portably.
while test $# != 0; do
  arg="$1"; shift
  case "$arg" in
    --no-create|--no-recursion) ;;
    dnl Anything starting with a hyphen we assume is an option.
    -* )
      dnl Separate the switch name from the value it is being given.
      case "$arg" in
        -*=*)
	  opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\([[^=]]*\)=.*$:\1:'`
	  val=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*[[^=]]*=\(.*\)$:\1:'`
	  valomitted=no
	;;
           dnl special case these strings since echo may silently eat them:
           dnl --help ) opt=help val=yes valomitted=yes ;;
           dnl --version ) opt=version val=yes valomitted=yes ;;
           dnl -e ) opt=e val=yes valomitted=yes ;;
           dnl -E ) opt=E val=yes valomitted=yes ;;
           dnl -n ) opt=n val=yes valomitted=yes ;;
        -*)
           dnl If FOO is a boolean argument, --FOO is equivalent to
           dnl --FOO=yes.  Otherwise, the value comes from the next
           dnl argument - see below.
	  opt=`echo '' $arg | sed -e 's:^ ::' -e 's:^-*\(.*\)$:\1:'`
          val="yes"
          valomitted=yes
        ;;
      esac

      dnl translate "-" in option string to "_"
      optname="$opt"
      opt="`echo '' $opt | sed -e 's:^ ::' | tr - _`"

      dnl Process the option.
      case "$opt" in

      dnl Process (many) boolean options
	run_in_place	| \
	with_x		| \
	with_x11	| \
	with_gcc	| \
	with_gnu_make	| \
	dynamic		| \
	with_ncurses	| \
	with_dnet	| \
	with_term	| \
	with_socks	| \
	with_cde	| \
	with_offix	| \
	with_gpm	| \
	with_gif	| \
	with_xpm	| \
	with_xface	| \
	with_jpeg	| \
	with_png	| \
	with_tiff	| \
	with_xmu	| \
	with_quantify	| \
	with_toolbars	| \
	with_tty	| \
	with_i18n3	| \
	with_mule	| \
	with_canna	| \
	with_wnn	| \
	with_wnn6	| \
	with_energize	| \
	with_workshop	| \
	with_sparcworks | \
	with_tooltalk   | \
	with_pop	| \
	with_kerberos	| \
	with_hesiod	| \
	with_dnet	| \
	external_widget | \
	verbose		| \
	extra_verbose	| \
	const_is_losing | \
	usage_tracking  | \
	use_union_type  | \
	debug		| \
	use_assertions	| \
	memory_usage_stats | \
	with_clash_detection | \
	no_doc_file )
	  dnl Make sure the value given was either "yes" or "no".
	  case "$val" in
	    y | ye | yes )	val=yes ;;
	    n | no )		val=no  ;;
	    * ) USAGE_ERROR("The \`--$optname' option requires a boolean value: \`yes' or \`no'.") ;;
	  esac
          eval "$opt=\"$val\"" ;;


	dnl Options that take a user-supplied value, as in --puresize=8000000
	dnl The cache-file option is ignored (for compatibility with other configures)
	srcdir		| \
	compiler	| \
	cflags		| \
	puresize	| \
	cache_file	| \
	native_sound_lib | \
	package_path	| \
	x_includes	| \
	x_libraries	| \
	site_includes	| \
	site_libraries	| \
	site_runtime_libraries )
	  dnl If the value was omitted, get it from the next argument.
	  if test "$valomitted" = "yes" ; then
	    dnl Get the next argument from the argument list, if there is one.
	    if test "$#" = 0 ; then
	      USAGE_ERROR("The \`--$optname' option requires a value.");
	    fi
	    val="$1"; shift
	  fi
          eval "$opt=\"$val\""
	;;

	dnl Options that take "yes", "no", or "default" values
	rel_alloc | \
	use_system_malloc )
	  case "$val" in
	    y | ye | yes )	val=yes ;;
	    n | no )		val=no  ;;
	    d | de | def | defa | defau | defaul | default )
				val=default ;;
	    * ) USAGE_ERROR(["The \`--$optname' option requires one of these values:
  \`yes', \`no', or \`default'."]) ;;
	  esac
          eval "$opt=\"$val\""
        ;;

        dnl Has the user requested database support?
        "with_database" )
	  with_database_berkdb=no
	  with_database_dbm=no
	  with_database_gnudbm=no
	  for x in `echo "$val" | sed -e 's/,/ /'` ; do
	    case "$x" in
		no ) ;;
		b | be | ber | berk | berkd | berkdb )  with_database_berkdb=yes ;;
		d | db | dbm )				with_database_dbm=yes    ;;
		g | gn | gnu | gnud | gnudb | gnudbm )  with_database_gnudbm=yes ;;
		* ) USAGE_ERROR(["The \`--$optname' option value
  must be either \`no' or a comma-separated list
  of one or more of \`berkdb', \`dbm', or \`gnudbm'."]) ;;
            esac
	  done
	  if test "$with_database_dbm"    = "yes" -a \
	          "$with_database_gnudbm" = "yes"; then
	  USAGE_ERROR("Only one of \`dbm' and \`gnudbm' may be specified
  with the \`--$optname' option.")
	  fi
        ;;

        dnl Has the user requested sound support?
	"with_sound" )
	  dnl value can be native, nas or both. yes is allowed
	  dnl as a backwards compatible synonym for native
	  case "$val" in
	    y | ye | yes )			val=native ;;
	    n | no | non | none )		val=no;;
	    na | nat | nati | nativ | native )	val=native  ;;
	    ne | net | neta | netau | netaud | netaudi | netaudio | nas ) val=nas  ;;
	    b | bo | bot | both )		val=both;;
	    * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
  \`native', \`nas', \`both', or \`none'."]) ;;
	  esac
          eval "$opt=\"$val\""
        ;;

        dnl Has the user requested XIM support?
	"with_xim" )
	  case "$val" in
	    y | ye | yes )		  val=yes   ;;
	    n | no | non | none )	  val=no    ;;
	    x | xl | xli | xlib )	  val=xlib  ;;
	    m | mo | mot | moti | motif ) val=motif ;;
	    * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
  \`motif', \`xlib', \`yes', or \`no'."]) ;;
	  esac
          eval "$opt=\"$val\""
        ;;

        dnl Mail locking specification
	"mail_locking" )
	  case "$val" in
	    lockf )	val=lockf ;;
	    flock )	val=flock ;;
	    file )	val=file  ;;
	    * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
  \`lockf', \`flock', or \`file'."]) ;;
	  esac
          eval "$opt=\"$val\""
        ;;

        dnl Has the user requested error-checking?
	"error_checking" )
	  dnl value can be all, none, and/or a list of categories to check.
	  dnl Example: --error-checking=all,noextents,nobufpos
	  dnl Example: --error-checking=none,malloc,gc

	  for x in `echo "$val" | sed -e 's/,/ /'` ; do
	    case "$x" in
	      dnl all and none are only permitted as the first in the list.
	      n | no | non | none ) new_default=no ;;
	      a | al | all )	    new_default=yes ;;

	      extents )       error_check_extents=yes ;;
	      noextents )     error_check_extents=no ;;

	      typecheck )     error_check_typecheck=yes ;;
	      notypecheck )   error_check_typecheck=no ;;

	      bufpos )	      error_check_bufpos=yes ;;
	      nobufpos )      error_check_bufpos=no ;;

	      gc )	      error_check_gc=yes ;;
	      nogc )          error_check_gc=no ;;

	      malloc )	      error_check_malloc=yes ;;
	      nomalloc )      error_check_malloc=no ;;

	      * ) bogus_error_check=yes ;;
	    esac
	    if test "$bogus_error_check" -o \
	         \( -n "$new_default" -a -n "$echeck_notfirst" \) ; then
		if test $error_check_default = yes ; then
		  types="\`all' (default), \`none', \`noextents', \`notypecheck', \`nobufpos', \`nogc', and \`nomalloc'."
		else
		  types="\`all', \`none' (default), \`extents', \`typecheck', \`bufpos', \`gc', and \`malloc'."
		fi
		USAGE_ERROR(["Valid types for the \`--$optname' option are:
  $types."])
	    elif test -n "$new_default" ; then
		error_check_extents=$new_default
		error_check_typecheck=$new_default
		error_check_bufpos=$new_default
		error_check_gc=$new_default
		error_check_malloc=$new_default
		new_default=	# reset this
	    fi
	    echeck_notfirst=true
	  done
	;;

	dnl Has the user tried to tell us where the X files are?
	dnl I think these are dopey, but no less than three alpha
	dnl testers, at large sites, have said they have their X files
	dnl installed in odd places.

	dnl Has the user specified one of the path options?
	prefix | exec_prefix | bindir | datadir | statedir | libdir | \
	mandir | infodir | lispdir | etcdir | lockdir | pkgdir | archlibdir | \
	sitelispdir | docdir )
	   dnl If the value was omitted, get it from the next argument.
	   if test "$valomitted" = "yes"; then
	     if test "$#" = 0; then
		 USAGE_ERROR("The \`--$optname' option requires a value.");
	     fi
	     val="$1"; shift
	   fi
	   eval "$opt=\"$val\""

           dnl Changing exec_prefix or libdir will change the default value
           dnl of archlibdir.  Changing datadir will change the default value
           dnl of etcdir and lispdir.  Changing statedir will change the
           dnl default value of lockdir.
           case "$opt" in
             lispdir ) lispdir_user_defined=yes ;;
             etcdir  )  etcdir_user_defined=yes ;;
             infodir ) infodir_user_defined=yes ;;
             datadir ) lispdir_user_defined=yes etcdir_user_defined=yes ;;
             statedir | lockdir ) lockdir_user_defined=yes ;;
             exec_prefix | libdir | archlibdir ) archlibdir_user_defined=yes ;;
           esac
	;;

	dnl --no-create added by autoconf for use by config.status
	"no_create" ) ;;

	dnl Has the user asked for some help?
	"usage" | "help" ) echo "$usage" | ${PAGER-more}; exit 0 ;;

	dnl Has the user specified what toolkit to use for the menubars,
	dnl scrollbar or dialogs?
	"with_menubars" | "with_scrollbars" | "with_dialogs" )
	  case "$val" in
	    l | lu | luc | luci | lucid )		val=lucid  ;;
	    m | mo | mot | moti | motif )		val=motif  ;;
	    athena3d | athena-3d )			val=athena3d ;;
	    a | at | ath | athe | athen | athena )	val=athena ;;
	    n | no | non | none )			val=no ;;
	    * ) USAGE_ERROR(["The \`--$optname' option must have one of these values:
  \`lucid', \`motif', \`athena', \`athena3d', or \`no'."]) ;;
	  esac
	  eval "$opt=\"$val\""
	;;

        dnl Fail on unrecognized arguments.
	* ) USAGE_ERROR("Unrecognized option: $arg") ;;

      esac
    ;;

    dnl Anything not starting with a hyphen we assume is a
    dnl configuration name.
    *) configuration="$arg" ;;

  esac
done

dnl -------------------------
dnl Finish options processing
dnl -------------------------

dnl Get the arguments back.  See the diatribe on Shell Magic above.
eval set x "$quoted_arguments"; shift

dnl Argument interdependencies
if test "$with_energize" = "yes" ; then
  with_menubars=lucid with_scrollbars=motif with_dialogs=motif with_tooltalk=yes
  XE_APPEND(lwlib/energize, MAKE_SUBDIR)
fi

dnl --extra-verbose implies --verbose
test "$extra_verbose" = "yes" && verbose=yes

dnl Allow use of either ":" or spaces for lists of directories
define(COLON_TO_SPACE,
  [case "$[$1]" in *:* [)] [$1]="`echo '' $[$1] | sed -e 's:^ ::' -e 's/:/ /g'`";; esac])dnl
COLON_TO_SPACE(site_includes)
COLON_TO_SPACE(site_libraries)
COLON_TO_SPACE(site_runtime_libraries)

dnl with_x is obsolete synonym for with_x11
test -n "$with_x" && with_x11="$with_x"

dnl# Ignore useless run-in-place flag
if test "$run_in_place" = "yes"; then
  AC_MSG_WARN("The --run-in-place option is ignored because it is unnecessary.")
fi

dnl ###########################################################################
if test "$configuration" = "" ; then
  echo '- You did not tell me what kind of host system you want to configure.
- I will attempt to guess the kind of system this is.' 1>&2
  guesssys=`echo $progname | sed 's/configure$/config.guess/'`
  dnl Guess the configuration and remove 4th name component, if present.
  if configuration=`${CONFIG_SHELL-/bin/sh} $guesssys | \
      sed '[s/^\([^-][^-]*-[^-][^-]*-[^-][^-]*\)-.*$/\1/]'` ; then
    echo "- Looks like this is a $configuration" 1>&2
  else
    USAGE_ERROR("Failed to guess the system type.  You need to tell me.")
  fi
fi

dnl Find the source directory.
case "$srcdir" in

  dnl If srcdir is not specified, see if  "." or ".." might work.
  "" )
    for dir in "`echo $0 | sed 's|//|/|' | sed 's|/[[^/]]*$||'`" "." ".." ; do
      if test -f "$dir/src/lisp.h" -a \
	      -f "$dir/lisp/version.el" ; then
        srcdir="$dir"
        break
      fi
    done
    if test -z "$srcdir" ; then
      USAGE_ERROR(["Neither the current directory nor its parent seem to
  contain the XEmacs sources.  If you do not want to build XEmacs in its
  source tree, you should run \`$progname' in the directory in which
  you wish to build XEmacs, using the \`--srcdir' option to say where the
  sources may be found."])
    fi
  ;;

  dnl Otherwise, check if the directory they specified is okay.
  * )
    if test ! -d "$srcdir" -o \
	    ! -f "$srcdir/src/lisp.h" -o \
	    ! -f "$srcdir/lisp/version.el" ; then
      USAGE_ERROR(["The directory specified with the \`--srcdir' option,
  \`$srcdir', doesn't seem to contain the XEmacs sources.  You should
  either run the \`$progname' script at the top of the XEmacs source
  tree, or use the \`--srcdir' option to specify the XEmacs source directory."])
    fi
  ;;
esac

AC_PROG_LN_S

dnl Make symlinks for etc, lisp, and info directories while the path
dnl is still relative.  We do not symlink lock because someone may
dnl have stuck the source on a read-only partition.  Instead we
dnl create it as an actual directory later on if it does not already
dnl exist.
for dir in lisp etc man info site-lisp; do
  if test ! -d "$dir" ; then
    echo Making symbolic link to "$srcdir/$dir"
    ${LN_S} "$srcdir/$dir" "$dir"
  fi
done

dnl Make srcdir absolute, if not already.  It is important to
dnl avoid running the path through pwd unnecessary, since pwd can
dnl give you automounter prefixes, which can go away.
case "$srcdir" in
  /* ) ;;
  . )
    dnl We may be able to use the $PWD environment variable to make this
    dnl absolute.  But sometimes PWD is inaccurate.
    if test "$PWD" != "" -a "`(cd $PWD ; sh -c pwd)`" = "`pwd`"; then
      srcdir="$PWD"
    else
      srcdir="`(cd $srcdir && pwd)`"
    fi
  ;;
  *  ) srcdir="`(cd $srcdir && pwd)`" ;;
esac

dnl Check if the source directory already has a configured system in it.
if test `pwd` != `sh -c cd $srcdir && pwd`  \
   && test -f "$srcdir/src/config.h"; then
  (echo "$progname: WARNING: The directory tree \`$srcdir' is being used"
   echo "   as a build directory right now; it has been configured in its own"
   echo "   right.  To configure in another directory as well, you MUST"
   echo "   use GNU make.  If you do not have GNU make, then you must"
   echo "   now do \`make distclean' in $srcdir,"
   echo "   and then run $progname again.") >&2
  extrasub='/^VPATH[[	 ]]*=/c\
vpath %.c $(srcdir)\
vpath %.h $(srcdir)\
vpath %.y $(srcdir)\
vpath %.l $(srcdir)\
vpath %.s $(srcdir)\
vpath %.in $(srcdir)'
fi

dnl ----------------------------------------
dnl Find out which version of XEmacs this is
dnl ----------------------------------------
. "$srcdir/version.sh" || exit 1;
dnl Must do the following first to determine verbosity for AC_DEFINE
if test -n "$emacs_beta_version"; then beta=yes; else beta=no; fi
: "${extra_verbose=$beta}"
version="${emacs_major_version}.${emacs_minor_version}"
AC_DEFINE_UNQUOTED(EMACS_MAJOR_VERSION, $emacs_major_version)
AC_DEFINE_UNQUOTED(EMACS_MINOR_VERSION, $emacs_minor_version)
if test -n "$emacs_beta_version"; then
  version="${version}-b${emacs_beta_version}"
  AC_DEFINE_UNQUOTED(EMACS_BETA_VERSION, $emacs_beta_version)
fi
AC_DEFINE_UNQUOTED(XEMACS_CODENAME, "$xemacs_codename")
AC_DEFINE_UNQUOTED(EMACS_VERSION, "$version")

dnl ----------------------------------
dnl Error checking and debugging flags
dnl ----------------------------------
dnl Error checking default to "yes" in beta versions, to "no" in releases.
dnl Same goes for --debug and --extra-verbosity.
if test -n "$emacs_beta_version"; then beta=yes; else beta=no; fi
test "${error_check_extents=$beta}"   = yes && AC_DEFINE(ERROR_CHECK_EXTENTS)
test "${error_check_typecheck=$beta}" = yes && AC_DEFINE(ERROR_CHECK_TYPECHECK)
test "${error_check_bufpos=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_BUFPOS)
test "${error_check_gc=$beta}"        = yes && AC_DEFINE(ERROR_CHECK_GC)
test "${error_check_malloc=$beta}"    = yes && AC_DEFINE(ERROR_CHECK_MALLOC)
dnl debug=yes must be set when error checking is present.  This should be
dnl fixed up.
dnl debug implies other options
if test "${debug=beta}" = "yes"; then
  use_assertions=yes memory_usage_stats=yes
  XE_ADD_OBJS(debug.o)
  AC_DEFINE(DEBUG_XEMACS)
fi
test "$use_assertions"     = "yes" && AC_DEFINE(USE_ASSERTIONS)
test "$memory_usage_stats" = "yes" && AC_DEFINE(MEMORY_USAGE_STATS)

dnl ------------------------------
dnl Determine the s&m files to use
dnl ------------------------------
dnl Given the configuration name, set machfile and opsysfile to the
dnl names of the m/*.h and s/*.h files we should use.

dnl Canonicalize the configuration name.
AC_CHECKING("the configuration name")
dnl allow -energize or -workshop suffix on configuration name
internal_configuration=`echo $configuration | sed 's/-\(energize\|workshop\)//'`
if canonical=`$srcdir/config.sub "$internal_configuration"` ; then : ; else
  exit $?
fi

dnl If you add support for a new configuration, add code to this
dnl switch statement to recognize your configuration name and select
dnl the appropriate operating system and machine description files.

dnl You would hope that you could choose an m/*.h file pretty much
dnl based on the machine portion of the configuration name, and an s-
dnl file based on the operating system portion.  However, it turns out
dnl that each m/*.h file is pretty manufacturer-specific - for
dnl example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
dnl all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
dnl machines.  So we basically have to have a special case for each
dnl configuration name.

dnl As far as handling version numbers on operating systems is
dnl concerned, make sure things will fail in a fixable way.  If
dnl /etc/MACHINES says nothing about version numbers, be
dnl prepared to handle anything reasonably.  If version numbers
dnl matter, be sure /etc/MACHINES says something about it.

dnl Eric Raymond says we should accept strings like "sysvr4" to mean
dnl "System V Release 4"; he writes, "The old convention encouraged"
dnl "confusion between `system' and `release' levels'."

machine='' opsys=''

dnl Straightforward machine determination
case "$canonical" in
  sparc-*-*        ) machine=sparc ;;
  alpha-*-*        ) machine=alpha ;;
  vax-*-*          ) machine=vax ;;
  mips-dec-*       ) machine=pmax ;;
  mips-sgi-*       ) machine=iris4d ;;
  romp-ibm-*       ) machine=ibmrt ;;
  rs6000-ibm-aix*  ) machine=ibmrs6000 ;;
  powerpc-ibm-aix* ) machine=ibmrs6000 ;;
  powerpc*-*       ) machine=powerpc ;;
  hppa-*-*         ) machine=hp800 ;;
  m88k-dg-*        ) machine=aviion ;;
  m68*-sony-*      ) machine=news ;;
  mips-sony-*      ) machine=news-risc ;;
  clipper-*        ) machine=clipper ;;
esac

dnl Straightforward OS determination
case "$canonical" in
  *-*-linux*    ) opsys=linux ;;
  *-*-netbsd*   ) opsys=netbsd ;;
  *-*-nextstep* ) opsys=nextstep ;;
  *-*-vms       ) opsys=vms ;;

  dnl DEC OSF
  *-dec-osf1.3 | *-dec-osf2* ) opsys=decosf1-3 ;;
  *-dec-osf1.2 | *-dec-osf1* ) opsys=decosf1-2 ;;
  *-dec-osf3.[[2-9]]         ) opsys=decosf3-2 ;;
  *-dec-osf3*                ) opsys=decosf3-1 ;;
  *-dec-osf4*                ) opsys=decosf4-0 ;;

  dnl DEC Ultrix
  *-*-ultrix[[0-3]].* | *-*-ultrix4.0* ) opsys=bsd4-2 ;;
  *-*-ultrix4.[[12]]* ) opsys=bsd4-3 ;;
  *-*-ultrix* )         opsys=ultrix4-3 ;;

  dnl AIX
  *-*-aix3.1*  ) opsys=aix3-1	;;
  *-*-aix3.2.5 ) opsys=aix3-2-5	;;
  *-*-aix3*    ) opsys=aix3-2	;;
  *-*-aix4.2*  ) opsys=aix4-2	;;
  *-*-aix4.1*  ) opsys=aix4-1	;;
  *-*-aix4*    ) opsys=aix4	;;

  dnl Other generic OSes
  *-gnu* )			opsys=gnu    ;;
  *-*-bsd4.[[01]] )		opsys=bsd4-1 ;;
  *-*-bsd4.2 )			opsys=bsd4-2 ;;
  *-*-bsd4.3 )			opsys=bsd4-3 ;;
  *-*-aos4.2 )			opsys=bsd4-2 ;;
  *-*-aos*   )			opsys=bsd4-3 ;;
  *-*-sysv0    | *-*-sysvr0 )	opsys=usg5-0 ;;
  *-*-sysv2    | *-*-sysvr2 )	opsys=usg5-2 ;;
  *-*-sysv2.2  | *-*-sysvr2.2 )	opsys=usg5-2-2 ;;
  *-*-sysv3*   | *-*-sysvr3* )	opsys=usg5-3 ;;
  *-*-sysv4.1* | *-*-sysvr4.1* )opsys=usg5-4 NON_GNU_CPP=/usr/lib/cpp ;;
  *-*-sysv4.[[2-9]]* | *-sysvr4.[[2-9]]* )
	if test -z "$NON_GNU_CPP" ; then
	  for prog in "/usr/ccs/lib/cpp" "/lib/cpp"; do
	    if test -f "$prog"; then NON_GNU_CPP="$prog"; break; fi
	  done
	fi
	opsys=usg5-4-2 ;;
    *-sysv4* | *-sysvr4* )	opsys=usg5-4 ;;
    *-*-mach_bsd4.3* )          opsys=mach-bsd4-3 ;;
esac

case "$canonical" in

  dnl NetBSD ports
  *-*-netbsd* )
    case "$canonical" in
      i[[3-9]]86-*-netbsd*) machine=intel386 ;;
      hp300-*-netbsd* | amiga-*-netbsd* | sun3-*-netbsd* | mac68k-*-netbsd* | da30-*-netbsd* | m68k-*-netbsd* )
                      dnl Yes, this is somewhat bogus.
                      machine=hp9000s300 ;;
      pc532-*-netbsd* | ns32k-*-netbsd* )  machine=ns32000 ;;
      pmax-*-netbsd*  | mips-*-netbsd*  )  machine=pmax ;;
    esac
  ;;

  dnl Acorn RISCiX:
  arm-acorn-riscix1.1* ) machine=acorn opsys=riscix1-1 ;;
  arm-acorn-riscix1.2* | arm-acorn-riscix ) machine=acorn opsys=riscix1-2 ;;

  dnl Alliant machines
  fx80-alliant-* ) machine=alliant4     opsys=bsd4-2 ;;
  i860-alliant-* ) machine=alliant-2800 opsys=bsd4-3 ;;

  dnl Altos 3068
  m68*-altos-sysv* ) machine=altos opsys=usg5-2 ;;

  dnl Amdahl UTS
  580-amdahl-sysv* ) machine=amdahl opsys=usg5-2-2 ;;

  dnl Apollo, Domain/OS
  m68*-apollo-* ) machine=apollo opsys=bsd4-3 ;;

  dnl AT&T 3b2, 3b5, 3b15, 3b20
  we32k-att-sysv* ) machine=att3b opsys=usg5-2-2 ;;

  dnl AT&T 3b1 - The Mighty Unix PC!
  m68*-att-sysv* ) machine=7300 opsys=usg5-2-2 ;;

  dnl Bull machines
  rs6000-bull-bosx* ) machine=ibmrs6000 opsys=aix3-2 ;; # dpx20
  m68*-bull-sysv3*  ) machine=dpx2      opsys=usg5-3 ;; # dpx2
  m68*-bull-sysv2*  ) machine=sps7      opsys=usg5-2 ;; # sps7

  dnl CCI 5/32, 6/32 -- see "Tahoe".

  dnl Celerity
  celerity-celerity-bsd* ) machine=celerity opsys=bsd4-2 ;;

  dnl Convex
  *-convex-bsd* | *-convex-convexos* )
    machine=convex opsys=bsd4-3
    NON_GNU_CPP="cc -E -P"
  ;;

  dnl Cubix QBx/386
  i[[3-9]]86-cubix-sysv* ) machine=intel386 opsys=usg5-3 ;;

  dnl Data General AViiON Machines
  i586-dg-dgux*R4*   | i586-dg-dgux5.4.4* ) machine=aviion opsys=dgux5-4r4 ;;
  m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* ) opsys=dgux5-4r3 ;;
  m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* ) opsys=dgux5-4r2 ;;
  m88k-dg-dgux* 			  ) opsys=dgux	   ;;

  dnl Motorola Delta machines
  m68k-motorola-sysv* | m68000-motorola-sysv* ) machine=delta opsys=usg5-3 ;;
  m88k-motorola-sysv4* )
    dnl jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
    dnl needs POSIX_SIGNALS and therefore needs usg5-4-2.
    dnl I hope there are not other 4.0 versions for this machine
    dnl which really need usg5-4 instead.
    machine=delta88k opsys=usg5-4-2
  ;;
  m88k-motorola-sysv* | m88k-motorola-m88kbcs* ) machine=delta88k opsys=usg5-3 ;;

  dnl Dual machines
  m68*-dual-sysv*    ) machine=dual opsys=usg5-2   ;;
  m68*-dual-uniplus* ) machine=dual opsys=unipl5-2 ;;

  dnl Encore machines
  ns16k-encore-bsd* ) machine=ns16000 opsys=umax ;;

  dnl Gould Power Node and NP1
  pn-gould-bsd4.2* ) machine=gould     opsys=bsd4-2 ;;
  pn-gould-bsd4.3* ) machine=gould     opsys=bsd4-3 ;;
  np1-gould-bsd* )   machine=gould-np1 opsys=bsd4-3 ;;

  dnl Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
  dnl as far as XEmacs is concerned).
  m88k-harris-cxux* )
    dnl Build needs to be different on 7.0 and later releases
    case "`uname -r`" in
       [[56]].[[0-9]] ) machine=nh4000 opsys=cxux  ;;
       [[7]].[[0-9]]  ) machine=nh4000 opsys=cxux7 ;;
    esac
    NON_GNU_CPP="/lib/cpp"
  ;;
  dnl Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
  m68k-harris-cxux* ) machine=nh3000 opsys=cxux ;;
  dnl Harris power pc NightHawk running Power UNIX (Series 6000)
  powerpc-harris-powerunix ) machine=nh6000 opsys=powerunix NON_GNU_CPP="cc -Xo -E -P" ;;

  dnl Honeywell XPS100
  xps*-honeywell-sysv* ) machine=xps100 opsys=usg5-2 ;;

  dnl HP 9000 series 200 or 300
  m68*-hp-bsd* ) machine=hp9000s300 opsys=bsd4-3 ;;

  dnl HP-UX
  *-hp-hpux* )
    dnl Figure out machine and opsys orthogonally
    case "$canonical" in
      m68*  ) machine=hp9000s300 ;;
      hppa* ) machine=hp800      ;;
    esac

    case "$canonical" in
      *-hp-hpux7*  )  opsys=hpux   ;;
      *-hp-hpux8*  )  opsys=hpux8  ;;
      *-hp-hpux9*  )  opsys=hpux9  ;;
      *-hp-hpux10* )  opsys=hpux10 ;;
      *            )  opsys=hpux   ;;
    esac

    dnl HP has a broken "strcat"
    case "$opsys" in hpux9 | hpux10 ) XE_ADD_OBJS(strcat.o) ;; esac

    if test "$opsys" = "hpux10"; then ansi_flag="-Ae"; else ansi_flag="-Aa"; fi
    NON_GNU_CC="cc $ansi_flag" NON_GNU_CPP="cc $ansi_flag -E"

    case "$canonical" in *-hp-hpux*shr* ) opsys="${opsys}-shr" ;; esac
  ;;

  dnl Orion machines
  orion-orion-bsd*   ) machine=orion    opsys=bsd4-2 ;;
  clipper-orion-bsd* ) machine=orion105 opsys=bsd4-2 ;;

  dnl IBM machines
  i[[3-9]]86-ibm-aix1.1* ) machine=ibmps2-aix opsys=usg5-2-2 ;;
  i[[3-9]]86-ibm-aix1.[[23]]* | i[[3-9]]86-ibm-aix* ) machine=ibmps2-aix opsys=usg5-3 ;;
  i370-ibm-aix*) machine=ibm370aix opsys=usg5-3 ;;
  romp-ibm-aos*    ) opsys=bsd4-3 ;;
  romp-ibm-bsd*    ) opsys=bsd4-3 ;;
  romp-ibm-mach*   ) opsys=mach-bsd4-3 ;;

  dnl Integrated Solutions "Optimum V"
  m68*-isi-bsd4.2* ) machine=isi-ov opsys=bsd4-2 ;;
  m68*-isi-bsd4.3* ) machine=isi-ov opsys=bsd4-3 ;;

  dnl Intel 386 machines where we do care about the manufacturer
  i[[3-9]]86-intsys-sysv* ) machine=is386 opsys=usg5-2-2 ;;

  dnl Prime EXL
  i[[3-9]]86-prime-sysv* ) machine=i386 opsys=usg5-3 ;;

  dnl Sequent Symmetry running Dynix
  i[[3-9]]86-sequent-bsd* ) machine=symmetry opsys=bsd4-3 ;;

  dnl Sequent Symmetry running DYNIX/ptx
  i[[3-9]]86-sequent-ptx* ) machine=sequent-ptx opsys=ptx NON_GNU_CPP="/lib/cpp" ;;

  dnl Unspecified sysv on an ncr machine defaults to svr4.2.
  dnl (Plain usg5-4 does not turn on POSIX signals, which we need.)
  i[[3-9]]86-ncr-sysv* ) machine=ncr386 opsys=usg5-4-2 ;;

  dnl Intel Paragon OSF/1
  i860-intel-osf1* ) machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp ;;

  dnl Intel 860
  i860-*-sysv4* ) machine=i860 opsys=usg5-4 NON_GNU_CC="/bin/cc" NON_GNU_CPP="/usr/ccs/lib/cpp" ;;

  dnl Masscomp machines
  m68*-masscomp-rtu* ) machine=masscomp opsys=rtu ;;

  dnl Megatest machines
  m68*-megatest-bsd* ) machine=mega68 opsys=bsd4-2 ;;

  dnl Workstations sold by MIPS
  dnl This is not necessarily all workstations using the MIPS processor -
  dnl Irises are produced by SGI, and DECstations by DEC.
  mips-mips-usg* ) machine=mips4 ;;
  mips-mips-riscos4 )
    machine=mips4
    NON_GNU_CC="cc -systype bsd43"
    NON_GNU_CPP="cc -systype bsd43 -E"
    case "$canonical" in
      mips-mips-riscos4* ) opsys=bsd4-3  ;;
      mips-mips-riscos5* ) opsys=riscos5 ;;
    esac
  ;;
  mips-mips-bsd* ) machine=mips opsys=bsd4-3 ;;
  mips-mips-*    ) machine=mips opsys=usg5-2-2 ;;

  dnl NeXT
  m68*-next-* | m68k-*-nextstep* ) machine=m68k opsys=nextstep ;;

  dnl The complete machine from National Semiconductor
  ns32k-ns-genix* ) machine=ns32000 opsys=usg5-2 ;;

  dnl NCR machines
  m68*-ncr-sysv2* | m68*-ncr-sysvr2* ) machine=tower32   opsys=usg5-2-2 ;;
  m68*-ncr-sysv3* | m68*-ncr-sysvr3* ) machine=tower32v3 opsys=usg5-3 ;;

  dnl Nixdorf Targon 31
  m68*-nixdorf-sysv* ) machine=targon31 opsys=usg5-2-2 ;;

  dnl Nu (TI or LMI)
  m68*-nu-sysv* ) machine=nu opsys=usg5-2 ;;

  dnl Plexus
  m68*-plexus-sysv* ) machine=plexus opsys=usg5-2 ;;

  dnl Pyramid machines
  pyramid-pyramid-bsd* ) machine=pyramid opsys=bsd4-2 ;;

  dnl Sequent Balance
  ns32k-sequent-bsd4.2* ) machine=sequent opsys=bsd4-2 ;;
  ns32k-sequent-bsd4.3* ) machine=sequent opsys=bsd4-3 ;;

  dnl Siemens Nixdorf
  mips-siemens-sysv* | mips-sni-sysv*)
    machine=mips-siemens opsys=usg5-4
    NON_GNU_CC=/usr/ccs/bin/cc
    NON_GNU_CPP=/usr/ccs/lib/cpp
  ;;

  dnl Silicon Graphics machines
  dnl Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
  m68*-sgi-iris3.5* ) machine=irist opsys=iris3-5 ;;
  m68*-sgi-iris3.6* | m68*-sgi-iris*) machine=irist opsys=iris3-6 ;;
  dnl Iris 4D
  mips-sgi-irix3.*    ) opsys=irix3-3 ;;
  mips-sgi-irix4.*    ) opsys=irix4-0 ;;
  mips-sgi-irix6*     ) opsys=irix6-0 NON_GNU_CC="cc -Olimit 2000" ;;
  mips-sgi-irix5.1*   ) opsys=irix5-1 ;;
  mips-sgi-irix5.2*   ) opsys=irix5-2 ;;
  mips-sgi-irix5.*    ) opsys=irix5-3 ;;
  mips-sgi-irix*      ) opsys=irix5-0 ;;

  dnl SONY machines
  *-sony-newsos[[34]]* | *-sony-news[[34]]* ) opsys=bsd4-3 ;;
  *-sony-news* ) opsys=newsos5 ;;

  dnl Stride
  m68*-stride-sysv* ) machine=stride opsys=usg5-2 ;;

  dnl Suns
  *-*-solaris* | *-*-sunos* | *-sun-mach* | *-sun-bsd* )
    dnl Hardware type
    case "$canonical" in
      m68*-sunos1* )	         machine=sun1     ;;
      m68*-sunos2* )	         machine=sun2     ;;
      m68* )		         machine=sun3     ;;
      i*86*-sun-sunos[[34]]* )   machine=sun386   ;;
      i*86-*-* )	         machine=intel386 ;;
      rs6000* )                  machine=rs6000   ;;
    esac

    dnl Make $canonical even more so.
    case "$canonical" in *-sunos5*)
      canonical=`echo $canonical | sed -e s/sunos5/solaris2/`;;
    esac

    dnl On SunOS 4, use /usr/lib/cpp, sans dynodump, /bin/ranlib
    dnl On SunOS 5, use cc -E,        need dynodump, RANLIB not needed
    dnl But, SunOS 5.6 no longer needs dynodump because it has a similar
    dnl function integrated.
    case "$canonical" in
      *-sunos4* )
	#test -f /usr/lib/cpp     && NON_GNU_CPP=/usr/lib/cpp ;;
	: ;;
      *-solaris2* )
	#test -f /usr/ccs/lib/cpp && NON_GNU_CPP=/usr/ccs/lib/cpp
	RANLIB=':' ;;
    esac

    case "$canonical" in
      *-solaris*	  )
	opsys=sol2
	os_release=`uname -r | sed -e 's/^\([[0-9]]\)\.\([[0-9]]\).*/\1\2/'`
	AC_DEFINE_UNQUOTED(OS_RELEASE, $os_release) ;;

      dnl The last Sun386 ran 4.0.
      i*86-*-sunos4*      ) opsys=sunos4-0	;;
      *-sunos4.0*	  ) opsys=sunos4-0	;;
      *-sunos4.1.2*	  ) opsys=sunos4-1-2	;;
      *-sunos4.1.3*	  ) opsys=sunos4-1-3	;;
      *-sunos4.1.[[4-9]]* ) opsys=sunos4-1-4	;;
      *-sunos4* | *-sunos ) opsys=sunos4-1	;;
      *-mach*		  ) opsys=mach-bsd4-3	;;
      *			  ) opsys=bsd4-2	;;
    esac

    case "$canonical" in *-sunos4*shr* ) opsys="${opsys}-shr" ;; esac

    dnl Watch out for a compiler guaranteed not to work.
    test "$opsys $CC" = "sol2 /usr/ucb/cc" && CC=""
  ;;

  dnl Tadpole 68k
  m68*-tadpole-sysv* ) machine=tad68k opsys=usg5-3 ;;

  dnl Tahoe machines
  tahoe-tahoe-bsd4.2* ) machine=tahoe opsys=bsd4-2 ;;
  tahoe-tahoe-bsd4.3* ) machine=tahoe opsys=bsd4-3 ;;

  dnl Tandem Integrity S2
  mips-tandem-sysv* ) machine=tandem-s2 opsys=usg5-3 ;;

  dnl Tektronix XD88
  m88k-tektronix-sysv3* ) machine=tekxd88 opsys=usg5-3 ;;

  dnl Tektronix 16000 box (6130?)
  ns16k-tektronix-bsd* ) machine=ns16000 opsys=bsd4-2 ;;
  dnl Tektronix 4300
  dnl src/m/tek4300.h hints that this is a m68k machine.
  m68*-tektronix-bsd* ) machine=tek4300 opsys=bsd4-3 ;;

  dnl Titan P2 or P3
  titan-titan-sysv* ) machine=titan opsys=usg5-3 ;;

  dnl Ustation E30 (SS5E)
  m68*-unisys-uniplus* ) machine=ustation opsystem=unipl5-2 ;;

  dnl Vaxen.
  vax-dec-* )
    case "$canonical" in
      *-sysv[[01]]* | *-sysvr[[01]]* ) 	opsys=usg5-0 ;;
      *-sysv2* | *-sysvr2* )		opsys=usg5-2 ;;
      *-mach* )				opsys=mach-bsd4-3 ;;
    esac
  ;;

  dnl Whitechapel MG1
  ns16k-whitechapel-* ) machine=mg1 ;;

  dnl Wicat
  m68*-wicat-sysv* ) machine=wicat opsys=usg5-2 ;;

  dnl Intel 386 machines where we do not care about the manufacturer
  i[[3-9]]86-*-* )
    machine=intel386
    case "$canonical" in
      *-isc1.* | *-isc2.[[01]]* ) opsys=386-ix ;;
      *-isc2.2* )		opsys=isc2-2 ;;
      *-isc4.0* )		opsys=isc4-0 ;;
      *-isc4.* )		opsys=isc4-1
				GCC_TEST_OPTIONS=-posix
				NON_GCC_TEST_OPTIONS=-Xp
				;;
      *-isc* )			opsys=isc3-0 ;;
      *-esix5* )		opsys=esix5r4 NON_GNU_CPP=/usr/lib/cpp ;;
      *-esix* )			opsys=esix ;;
      *-mach* )			opsys=mach-bsd4-3 ;;
      *-xenix* )		opsys=xenix ;;
      *-sco3.2v4* )		opsys=sco4 NON_GNU_CPP=/lib/cpp  ;;
      *-bsd386* | *-bsdi1* )	opsys=bsd386 ;;
      *-bsdi3* )		opsys=bsdos3 ;;
      *-bsdi2.1* )		opsys=bsdos2-1 ;;
      *-bsdi2* )		opsys=bsdos2 ;;
      *-sco3.2v5* )		opsys=sco5 ;
	dnl This is a pain.  Like the current USL cc, SCO cc -E
	dnl tokenizes as it preprocesses, making configure very
	dnl unhappy.  Unfortunately, /lib/cpp does not understand
	dnl flags like "-b elf", so we have to cheat in order to
	dnl pick up the right defines for UNEXEC from the s-file.
	dnl 01/05/95 robertl@dgii.com
	if test "$dynamic" = "yes" ; then
		NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE -D_SCO_ELF"  ;
	else
		NON_GNU_CPP="/lib/cpp -D_XOPEN_SOURCE"  ;
	fi ;;
      *-386bsd* )	        opsys=386bsd ;;
      *-freebsd* )		opsys=freebsd ;;
      *-nextstep* )		opsys=nextstep ;;
      dnl Otherwise, we fall through to the generic opsys code at the bottom.
    esac
  ;;

  dnl Linux/68k
  m68k-*-linux* ) machine=m68k opsys=linux ;;

esac

if test -z "$machine" -o -z "$opsys"; then
  (echo "$progname: XEmacs hasn't been ported to \`$canonical' systems."
   echo "$progname: Check \`etc/MACHINES' for recognized configuration names."
  ) >&2
  exit 1
fi

if test -z "$dynamic"; then
  case "$opsys" in
    hpux* | sunos4* | sco5 ) dynamic=no ;;
    *) dynamic=yes ;;
  esac
fi
if test "$dynamic" = "yes"; then
  case "$opsys" in
    hpux* | sunos4* | sco5 ) opsys="${opsys}-shr" ;;
    decosf* ) ld_call_shared="-call_shared" ;;
  esac
else dnl "$dynamic" = "no"
  case "$opsys" in
    sol2 ) 
      echo "Static linking is not supported on Solaris 2."
      echo "Rerun configure without specifying --dynamic=no."
      exit 1 ;;
    linux   ) ld_call_shared="-Bstatic" ;;
    decosf* ) ld_call_shared="-non_shared" ;;
  esac
fi

canonical_version=`echo ${version}_${canonical} | sed 'y/.-/__/'`
AC_DEFINE_UNQUOTED(CANONICAL_VERSION, $canonical_version)

machfile="m/${machine}.h"
opsysfile="s/${opsys}.h"

dnl --------------------------------------------------
dnl Determine the compiler, set up for feature testing
dnl --------------------------------------------------

dnl Sun Development environment support
test "$with_sparcworks" = "yes" && with_workshop=yes # compatibility alias
if test "$with_workshop" = "yes"; then
  AC_DEFINE(SUNPRO)
  XE_ADD_OBJS(sunpro.o)
  with_tooltalk=yes
fi

if test "$with_clash_detection" = "yes"; then
  AC_DEFINE(CLASH_DETECTION)
  XE_ADD_OBJS(filelock.o)
fi

dnl Choose a compiler from (in order)
dnl --compiler, env var CC, with_gcc=no && ${NON_GNU_CC:-cc}, AC_PROG_CC
test -n "$compiler" && CC="$compiler"
if test "$with_gcc" = "no"; then dnl Try to find a non-gcc compiler
  case "$CC" in "" | *gcc* ) CC="${NON_GNU_CC-cc}" ;; esac
fi

dnl If we don't set CFLAGS here, AC_PROG_CC will set it.
dnl But we know better what's good for us, so we do our own
dnl computation of real CFLAGS later.
test "$cflags" != "UNSPECIFIED" && CFLAGS="$cflags"
xe_save_CFLAGS="$CFLAGS"

AC_PROG_CC dnl Autoconf has its own magic for compiler autodetection

dnl Retry using random guesswork if AC_PROG_CC got it wrong...
if   test "$with_gcc" = "no"  -a "$GCC" = "yes"; then
  CC=${NON_GNU_CC-cc}
  AC_PROG_CC
elif test "$with_gcc" = "yes" -a "$GCC" != "yes" ; then
  CC=gcc
  AC_PROG_CC
fi
CFLAGS="$xe_save_CFLAGS"

dnl Figure out what C preprocessor to use.

dnl On Sun systems, people sometimes set up the variable CPP
dnl with a value that is a directory, not an executable at all.
dnl Detect that case, and ignore that value.
test -n "$CPP" -a -d "$CPP" && CPP=

test -n "$NON_GNU_CPP" -a "$GCC" != "yes" -a -z "$CPP" && CPP="$NON_GNU_CPP"

AC_PROG_CPP

AC_AIX

AC_MSG_CHECKING(whether we are using SunPro C)
AC_TRY_COMPILE([],[#ifndef __SUNPRO_C
#error Not a  SunPro compiler :-(
******* ======= ******** &&&&&&&&
#endif
], __sunpro_c=yes, __sunpro_c=no)
AC_MSG_RESULT($__sunpro_c)

dnl case "$canonical" in
dnl   *-sun-sunos* ) test "$CPP" = "acc -E" && CPP="acc -E -Xs" ;;
dnl esac

dnl --------------------------------------------------------------------
dnl Extract some information from the operating system and machine files
dnl --------------------------------------------------------------------

echo "Extracting information from the machine- and system-dependent headers..."

dnl It is not important that this name contain the PID; you cannot run
dnl two configures in the same directory and have anything work
dnl anyway.
tempcname="conftest.c"

dnl CPP_to_sh(CPP_SYMBOL, SH_VAR, DEFAULT_VALUE)
define([CPP_to_sh],
[[#]ifndef [$1]
[#]define [$1]ifelse([$3],,, [ "$3"])
[#]endif
configure___ [$2]=[$1]
])

dnl CPP_boolean_to_sh(CPP_SYMBOL, SH_VAR)
define([CPP_boolean_to_sh],
[[#]ifdef [$1]
configure___ [$2]=yes
[#]else
configure___ [$2]=no
[#]endif
])


echo '
#define NOT_C_CODE
#define C_SWITCH_SITE
#define C_SWITCH_X_SITE
#define LD_SWITCH_SITE
#define LD_SWITCH_X_SITE
#define LD_SWITCH_X_SITE_AUX
#define OS_RELEASE '$os_release'
#include "'$srcdir'/src/'$opsysfile'"
#include "'$srcdir'/src/'$machfile'"

CPP_to_sh(LIBS_MACHINE, libs_machine)
CPP_to_sh(LIBS_SYSTEM,  libs_system)
CPP_to_sh(LIBS_TERMCAP, libs_termcap)
CPP_to_sh(LIB_STANDARD, libs_standard)

CPP_to_sh(OBJECTS_MACHINE, objects_machine)
CPP_to_sh(OBJECTS_SYSTEM,  objects_system)

CPP_to_sh(C_SWITCH_MACHINE,   c_switch_machine)
CPP_to_sh(C_SWITCH_SYSTEM,    c_switch_system)
CPP_to_sh(C_SWITCH_X_SYSTEM,  c_switch_x_system)

CPP_to_sh(LD_SWITCH_MACHINE,  ld_switch_machine)
CPP_to_sh(LD_SWITCH_SYSTEM,   ld_switch_system)
CPP_to_sh(LD_SWITCH_X_SYSTEM, ld_switch_x_system)

CPP_to_sh(UNEXEC, unexec, unexec.o)

CPP_to_sh(LD_SWITCH_SHARED, ld_switch_shared, -c)

#ifdef ORDINARY_LINK
#define LD "$(CC) $(CFLAGS)"
#else /* no ORDINARY LINK */
#ifdef COFF_ENCAPSULATE
#define LD "$(CC) -nostdlib"
#else /* not COFF_ENCAPSULATE */
#ifdef LINKER
#define LD LINKER
#else /* ! defined (LINKER) */
#define LD "ld"
#endif /* ! defined (LINKER) */
#endif /* ! defined (COFF_ENCAPSULATE) */
#endif /* not ORDINARY_LINK */
configure___ ld=LD

CPP_to_sh(LIB_GCC, lib_gcc)
CPP_to_sh(LD_TEXT_START_ADDR, ld_text_start_addr)

#if ! defined (ORDINARY_LINK) && !defined (START_FILES)
#ifdef NO_REMAP
#ifdef COFF_ENCAPSULATE
#define START_FILES "pre-crt0.o /usr/local/lib/gcc-crt0.o"
#else /* ! defined (COFF_ENCAPSULATE) */
#define START_FILES "pre-crt0.o /lib/crt0.o"
#endif /* ! defined (COFF_ENCAPSULATE) */
#else /* ! defined (NO_REMAP) */
#define START_FILES "ecrt0.o"
#endif /* ! defined (NO_REMAP) */
#endif /* no ORDINARY_LINK */
#ifndef START_FILES
#define START_FILES
#endif
configure___ start_files=START_FILES

CPP_boolean_to_sh(ORDINARY_LINK, ordinary_link)
CPP_boolean_to_sh(SYSTEM_MALLOC, system_malloc)
CPP_boolean_to_sh(TERMINFO, have_terminfo)
CPP_boolean_to_sh(MAIL_USE_FLOCK, mail_use_flock)
CPP_boolean_to_sh(MAIL_USE_LOCKF, mail_use_lockf)

#if 0
#ifdef THIS_IS_CONFIGURE

/* Get the CFLAGS for tests in configure.  */
CPP_to_sh(C_DEBUG_SWITCH, c_debug_switch, -g)
CPP_to_sh(C_OPTIMIZE_SWITCH, c_optimize_switch, -O)
#ifdef __GNUC__
configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '$SPECIFIED_CFLAGS'
#else
configure___ CFLAGS=C_DEBUG_SWITCH '$SPECIFIED_CFLAGS'
#endif

#else /* not THIS_IS_CONFIGURE */

/* Get the CFLAGS for real compilation.  */
#ifdef __GNUC__
configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '$SPECIFIED_CFLAGS'
#else
configure___ REAL_CFLAGS=C_DEBUG_SWITCH '$SPECIFIED_CFLAGS'
#endif

#endif /* not THIS_IS_CONFIGURE */
#endif /* 0 */
' > $tempcname
dnl The value of CPP is a quoted variable reference, so we need to do this
dnl to get its actual value...
CPP=`eval "echo $CPP"`
define(TAB, [	])dnl
changequote(, )dnl
eval `$CPP -Isrc $tempcname \
	| sed -n -e "s/[ TAB]*=[ TAB\"]*/='/" -e "s/[ TAB\"]*\$/'/" -e "s/^configure___//p"`
changequote([, ])dnl
dnl if test -z "$SPECIFIED_CFLAGS"; then
dnl   eval `$CPP -Isrc -DTHIS_IS_CONFIGURE $tempcname \
dnl 	| sed -n -e "s/ *=[[ \"]]*/='/" -e "s/[[ \"]]*\$/'/" -e "s/^configure___//p"`
dnl else
dnl   REAL_CFLAGS="$CFLAGS"
dnl fi

rm $tempcname

dnl For debugging...
test "$extra_verbose" = "yes" && \
  PRINT_VAR(libs_machine libs_system libs_termcap libs_standard
  objects_machine objects_system c_switch_machine c_switch_system
  c_switch_x_system ld_switch_machine ld_switch_system
  ld_switch_x_system unexec ld_switch_shared
  ld lib_gcc ld_text_start_addr start_files ordinary_link
  have_terminfo mail_use_flock mail_use_lockf) && echo ""

dnl Non-ordinary link usually requires -lc
test "$ordinary_link" = "no" -a -z "$libs_standard" && libs_standard="-lc"

dnl Calculalate value of CFLAGS:
dnl Use either command line flag, environment var, or autodetection
if test -z "$CFLAGS"; then
  dnl Following values of CFLAGS are known to work well.
  dnl Should we take debugging options into consideration?
  if   test "$GCC" = "yes"; then
    CFLAGS="-g -O2 -Wall -Wno-switch"
    test "$opsys" = "linux" -a "$machine" = "intel386" && \
      CFLAGS="$CFLAGS -fno-strength-reduce -malign-loops=2 -malign-jumps=2 -malign-functions=2"
  elif test "$__sunpro_c" = "yes"; then
    case "$opsys" in
      sol2    ) CFLAGS="-v -xO4" ;;
      sunos4* ) CFLAGS="-xO2";;
    esac
  else
    CFLAGS="-O" # The only POSIX-approved flag
  fi
fi

dnl Make sure linker flags not understood by GCC are properly wrapped.
if test "$GCC" = "yes"; then
  define([XE_GCC_WRAP_LDFLAGS],
  [[$1_tmp]="$[$1]"; [$1]=""
  for arg in $[$1_tmp]; do
    case "$arg" in
      -L* | -l* | -R* | -u* | -Wl* | -f* ) [$1]="$[$1] $arg" ;;
      -Xlinker* ) ;;
      * ) [$1]="$[$1] -Xlinker $arg" ;;
    esac
  done])dnl
  XE_GCC_WRAP_LDFLAGS(ld_switch_system)
  XE_GCC_WRAP_LDFLAGS(ld_switch_machine)
  XE_GCC_WRAP_LDFLAGS(LDFLAGS)
  XE_GCC_WRAP_LDFLAGS(ld_call_shared)
fi

dnl Add s&m-determined objects (including unexec) to link line
test -n "$objects_machine" && XE_ADD_OBJS($objects_machine)
test -n "$objects_system"  && XE_ADD_OBJS($objects_system)
test -n "$unexec"          && XE_ADD_OBJS($unexec)

dnl Dynodump (Solaris 2.x, x<6)
AC_MSG_CHECKING(for dynodump)
if test "$unexec" != "unexsol2.o"; then
  AC_MSG_RESULT(no)
else
  AC_MSG_RESULT(yes)
  AC_DEFINE(DYNODUMP)
  XE_APPEND(dynodump, MAKE_SUBDIR)
  XE_APPEND(dynodump, SRC_SUBDIR_DEPS)
  case "$machine" in
    sparc   ) dynodump_arch=sparc ;;
    *86*    ) dynodump_arch=i386  ;;
    powerpc ) dynodump_arch=ppc   ;;
  esac
  dnl Dynodump requires the system linker
  test "$GCC" = "yes" && XE_APPEND(-fno-gnu-linker, ld_switch_site)
fi

dnl Feed s&m crud to src/Makefile
AC_SUBST(ld_switch_shared)
AC_SUBST(start_files)
test -n "$ld_text_start_addr" && start_flags="-T $ld_text_start_addr -e __start"
AC_SUBST(start_flags)
if test "$ordinary_link" = "no" -a "$GCC" = "yes"; then
 test -z "$linker" &&  linker='$(CC) -nostdlib'
 test -z "$lib_gcc" && lib_gcc='`$(CC) -print-libgcc-file-name`'
fi
test "$GCC" != "yes" && lib_gcc=
AC_SUBST(ld)
AC_SUBST(lib_gcc)

dnl ---------------------------------------------------------------
dnl Add site and system specific flags to compile and link commands
dnl ---------------------------------------------------------------

dnl --site-libraries (multiple dirs)
if test -n "$site_libraries"; then
  for arg in $site_libraries; do
    case "$arg" in -* ) ;; * ) arg="-L${arg}" ;; esac
    XE_APPEND($arg, ld_switch_site)
  done
fi

dnl --site-includes (multiple dirs)
if test -n "$site_includes" ; then
  for arg in $site_includes; do
    case "$arg" in -* ) ;; * ) arg="-I${arg}" ;; esac
    XE_APPEND($arg, c_switch_site)
  done
fi

dnl GNU software installs by default into /usr/local/{include,lib}
dnl if test -d "/usr/local/include" -a -d "/usr/local/lib"; then
dnl   XE_APPEND("-L/usr/local/lib",    ld_switch_site)
dnl   XE_APPEND("-I/usr/local/include", c_switch_site)
dnl fi

dnl Extra system-specific library directories - please add to list
for dir in "/usr/ccs/lib"; do
  test -d "$dir" && XE_APPEND(-L${dir}, ld_switch_site)
done

dnl --site-runtime-libraries (multiple dirs)
if test -n "$site_runtime_libraries" ; then
  LD_RUN_PATH="`echo $site_runtime_libraries | sed -e 's/  */:/g'`"
  export LD_RUN_PATH
fi

dnl -------------------------------------
dnl Compute runtime library path
dnl -------------------------------------

if   test "$dynamic" = "no"; then add_runtime_path=no
elif test -n "$LD_RUN_PATH"; then add_runtime_path=yes
else case "$opsys" in
       sol2 | irix* | *bsd* ) add_runtime_path=yes ;;
       * ) add_runtime_path=no ;;
     esac
fi

if test "$add_runtime_path" = "yes"; then
  dnl Try to autodetect runtime library flag (usually -R),
  dnl and whether it works (or at least does no harm)
  AC_MSG_CHECKING("for runtime libraries flag")
  dash_r=""
  for try_dash_r in "-R" "-R " "-rpath "; do
    xe_check_libs="${try_dash_r}/no/such/file-or-directory"
    AC_TRY_LINK(, , dash_r="$try_dash_r")
    xe_check_libs=""
    test -n "$dash_r" && break
  done
  if test -n "$dash_r";
    then AC_MSG_RESULT("\"${dash_r}\"")
    else AC_MSG_RESULT(NONE)
  fi
fi

xe_add_unique_runpath_dir='
  xe_add_p=yes
  for xe_dir in $runpath_dirs; do   dnl Uniquify
    test "$xe_dir" = "$xe_runpath_dir" && xe_add_p=no
  done
  if test "$xe_add_p" = "yes"; then
    test -n "$runpath" && runpath="${runpath}:"
    runpath="${runpath}${xe_runpath_dir}"
    runpath_dirs="$runpath_dirs $xe_runpath_dir"
  fi'


dnl XE_ADD_RUNPATH_DIR(directory)
define([XE_ADD_RUNPATH_DIR],[{
xe_runpath_dir=$1
dnl PRINT_VAR(ld_switch_site ld_switch_x_site runpath xe_runpath_dir LD_RUN_PATH xe_ldflags)
  test "$xe_runpath_dir" != "/lib"     -a \
	"$xe_runpath_dir" != "/usr/lib" -a \
	-n "`ls ${xe_runpath_dir}/*.s[[ol]] 2>/dev/null`" && \
  eval "$xe_add_unique_runpath_dir"
}])dnl

dnl XE_COMPUTE_RUNPATH()
define([XE_COMPUTE_RUNPATH],[
if test "$add_runtime_path" = "yes" -a -n "$dash_r"; then
  dnl Remove runtime paths from current ld switches
  ld_switch_site=`echo   '' $ld_switch_site   | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
  ld_switch_x_site=`echo '' $ld_switch_x_site | sed -e 's:^ ::' -e "s/$dash_r[[^ ]]*//g"`
  dnl PRINT_VAR(ld_switch_site ld_switch_x_site)

  dnl Fix up Runtime path
  dnl If LD_RUN_PATH is set in environment, use that.
  dnl In this case, assume user has set the right value.
  runpath="" runpath_dirs=""
  if test -n "$LD_RUN_PATH"; then
    runpath="$LD_RUN_PATH"
  elif test "$GCC" = "yes"; then
    dnl Compute runpath from gcc's -v output
    ld_switch_run_save="$ld_switch_run"; ld_switch_run=""
    echo "int main(int argc, char *argv[[]]) {return 0;}" > conftest.c
    xe_runpath_link='${CC-cc} -o conftest -v $CFLAGS '"$xe_ldflags"' conftest.$ac_ext 2>&1 1>/dev/null'
    for arg in `eval "$xe_runpath_link" | grep ' -L'`; do
      case "$arg" in P,* | -L* | -R* )
        for dir in `echo '' "$arg" | sed -e 's:^ ::' -e 's/^..//' -e 'y/:/ /'`; do
          XE_ADD_RUNPATH_DIR("$dir")
        done ;;
      esac
    done
    ld_switch_run="$ld_switch_run_save"
    rm -f conftest*
  else
    dnl Add all directories with .so files to runpath
    for arg in $ld_switch_site $ld_switch_x_site; do
      case "$arg" in -L*) XE_ADD_RUNPATH_DIR(`echo '' "$arg" | sed -e 's:^ ::' -e 's/^-L//'`);; esac
    done
    dnl Sometimes /opt/SUNWdt/lib is the only installed Motif available
    if test "$opsys $need_motif" = "sol2 yes"; then
      xe_runpath_dir="/opt/SUNWdt/lib";
      eval "$xe_add_unique_runpath_dir";
    fi
  fi dnl Compute $runpath

  if test -n "$runpath"; then
    ld_switch_run="${dash_r}${runpath}"
    test "$extra_verbose" = "yes" && echo "Setting runpath to $runpath"
  fi
fi
])dnl
XE_COMPUTE_RUNPATH()

dnl -----------------------------------
dnl Do some misc autoconf-special tests
dnl -----------------------------------

dnl Do the opsystem or machine files prohibit the use of the GNU malloc?
dnl Assume not, until told otherwise.
GNU_MALLOC=yes
if test "$system_malloc" = "yes" ; then
  GNU_MALLOC=no
  GNU_MALLOC_reason="
  (The GNU allocators don't work with this system configuration.)"
elif test "$use_system_malloc" = "yes" ; then
  GNU_MALLOC=no
  GNU_MALLOC_reason="
  (User chose not to use GNU allocators.)"
fi

dnl Some other nice autoconf tests.  If you add a test here which
dnl should make an entry in src/config.h, do not forget to add an
dnl #undef clause to src/config.h.in for autoconf to modify.

AC_PROG_RANLIB
AC_PROG_INSTALL
AC_PROG_YACC

dnl checks for header files
AC_CHECK_HEADERS(mach/mach.h sys/stropts.h sys/timeb.h sys/time.h unistd.h)
AC_CHECK_HEADERS(utime.h locale.h libgen.h fcntl.h ulimit.h)
AC_CHECK_HEADERS(linux/version.h kstat.h sys/pstat.h inttypes.h limits.h)
AC_HEADER_SYS_WAIT
AC_HEADER_STDC
AC_HEADER_TIME
AC_DECL_SYS_SIGLIST

dnl Some systems have utime.h but do not declare the struct anyplace.
AC_MSG_CHECKING(for struct utimbuf)
AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
#include <sys/time.h>
#include <time.h>
#else
#ifdef HAVE_SYS_TIME_H
#include <sys/time.h>
#else
#include <time.h>
#endif
#endif
#ifdef HAVE_UTIME_H
#include <utime.h>
#endif], [static struct utimbuf x; x.actime = x.modtime;],
  [AC_MSG_RESULT(yes)
   AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
  AC_MSG_RESULT(no))

dnl checks for typedefs
AC_TYPE_SIGNAL
AC_TYPE_SIZE_T
AC_TYPE_PID_T
AC_TYPE_UID_T
AC_TYPE_MODE_T
AC_TYPE_OFF_T

AC_MSG_CHECKING(for struct timeval)
AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
#include <sys/time.h>
#include <time.h>
#else
#ifdef HAVE_SYS_TIME_H
#include <sys/time.h>
#else
#include <time.h>
#endif
#endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
  [AC_MSG_RESULT(yes)
  HAVE_TIMEVAL=yes
  AC_DEFINE(HAVE_TIMEVAL)],
  [AC_MSG_RESULT(no)
   HAVE_TIMEVAL=no])

dnl checks for structure members
AC_STRUCT_TM
AC_STRUCT_TIMEZONE

dnl checks for compiler characteristics
AC_C_CONST

dnl check for Make feature
AC_PROG_MAKE_SET

dnl check byte order
AC_C_BIGENDIAN

dnl define SIZEOF_TYPE
AC_CHECK_SIZEOF(short)
if test "$ac_cv_sizeof_short" = 0; then
  echo ""
  echo "*** PANIC *** Configure tests are not working - compiler is broken."
  echo "*** PANIC *** Please examine config.log for compilation errors."
  exit 1
fi
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(long long)
AC_CHECK_SIZEOF(void *)

dnl check for long file names
AC_SYS_LONG_FILE_NAMES

dnl -lm is required by LISP_FLOAT_TYPE, among other things
AC_CHECK_LIB(m, sqrt)

dnl -lPW might be needed on some systems
dnl But they break more other systems.
dnl AC_CHECK_LIB(PW, main)

dnl Floating operation support is now unconditional
AC_DEFINE(LISP_FLOAT_TYPE)

dnl Determine type of mail locking from configure args and s&m headers
AC_CHECKING(type of mail spool file locking)
test -z "$mail_locking" -a "$mail_use_flock" = "yes" && mail_locking=flock
test -z "$mail_locking" -a "$mail_use_lockf" = "yes" && mail_locking=lockf
if   test "$mail_locking" = "lockf"; then AC_DEFINE(REAL_MAIL_USE_LOCKF)
elif test "$mail_locking" = "flock"; then AC_DEFINE(REAL_MAIL_USE_FLOCK)
else mail_locking="dot-locking"
fi

dnl Used by getloadavg() - does not require root priveleges
AC_CHECK_LIB(kstat, kstat_open)

dnl Another way to get the load average
AC_CHECK_LIB(kvm, kvm_read)

AC_CHECK_LIB(pthreads, cma_open)
if test "$ac_cv_lib_pthreads_cma_open" = "yes"; then
   case "$opsys" in decosf*) c_switch_site="$c_switch_site -threads";; esac
fi

AC_MSG_CHECKING(whether the -xildoff compiler flag is required)
if   ${CC-cc} '-###' -xildon  no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ; then
  if ${CC-cc} '-###' -xildoff no_such_file.c 2>&1 | grep '^[^ ]*/ild ' > /dev/null ;
    then AC_MSG_RESULT(no);
    else AC_MSG_RESULT(yes); XE_APPEND(-xildoff, ld_switch_site)
  fi
  else AC_MSG_RESULT(no)
fi

dnl Link with "-z ignore" on Solaris if supported
if test "$opsys" = "sol2" && test "$OS_RELEASE" -ge 56; then
  AC_MSG_CHECKING(for \"-z ignore\" linker flag)
  case "`ld -h 2>&1`" in
    *-z\ ignore\|record* ) AC_MSG_RESULT(yes)
      XE_PREPEND(-z ignore, ld_switch_site) ;;
    *) AC_MSG_RESULT(no) ;;
  esac
fi

dnl ----------------------
dnl Choose a window system
dnl ----------------------

AC_CHECKING("for specified window system")

dnl $OPENWINHOME implies --x-includes and --x-libraries
dnl Not (yet) handled by autoconf2
if test "$x_includes $x_libraries" = "NONE NONE"; then
  if test -n "$OPENWINHOME" \
   -a "$OPENWINHOME" != "/usr/openwin" \
   -a -d "$OPENWINHOME"; then
    test -d "$OPENWINHOME/lib"           && x_libraries="$OPENWINHOME/lib"
    test -d "$OPENWINHOME/include"       && x_includes="$OPENWINHOME/include"
    test -d "$OPENWINHOME/share/include" && x_includes="$OPENWINHOME/share/include"
  fi
fi

dnl --x-includes or --x-libraries implies --with-x11.
test "$x_includes $x_libraries" != "NONE NONE" && \
 window_system=x11 with_x11=yes

if test "$with_x11" != "no"; then
  AC_PATH_XTRA # Autoconf claims to find X library and include dirs for us.
  if test "$no_x" = "yes"
  then with_x11=no  window_system=none HAVE_X_WINDOWS=no
  else with_x11=yes window_system=x11  HAVE_X_WINDOWS=yes
  fi
fi

case "$with_x11" in
  yes ) window_system=x11  HAVE_X_WINDOWS=yes ;;
  no  ) window_system=none HAVE_X_WINDOWS=no  ;;
esac

if test "$with_x11" = "yes"; then
  AC_DEFINE(HAVE_X_WINDOWS)
  XE_APPEND(lwlib, MAKE_SUBDIR)
  XE_APPEND(lwlib, SRC_SUBDIR_DEPS)

  dnl Try to find Motif/CDE/Tooltalk dirs
  dnl These take precedence over other X libs/includes, so PRE-pend
  for lib_dir in "/usr/dt/lib" "/usr/lib/Motif1.2" "/usr/lib/Motif1.1"; do
    inc_dir=`echo $lib_dir | sed -e 's/lib/include/'`
    if test -d "$lib_dir" -a -d "$inc_dir"; then
      case "$x_libraries" in *"$lib_dir"* ) ;; *)
        x_libraries="$lib_dir $x_libraries"
        XE_PREPEND(-L${lib_dir}, X_LIBS) ;;
      esac
      case "$x_includes" in "$inc_dir"* ) ;; *)
        x_includes="$inc_dir $x_includes"
        XE_PREPEND(-I${inc_dir}, X_CFLAGS) ;;
      esac
      break; dnl only need ONE Motif implementation!
      fi
  done

  dnl Contrib X libs/includes do NOT take precedence, so AP-pend
  for rel in "X11R6" "X11R5" "X11R4"; do
    lib_dir="/usr/contrib/$rel/lib" inc_dir="/usr/contrib/$rel/include"
    if test -d "$lib_dir" -a -d "$inc_dir"; then
      case "$x_libraries" in *"$lib_dir"* ) ;; *)
        x_libraries="$x_libraries $lib_dir"
	XE_APPEND(-L${lib_dir}, X_LIBS)
      esac
      case "$x_includes" in "$inc_dir"* ) ;; *)
        x_includes="$x_includes $inc_dir"
        XE_APPEND(-I${inc_dir}, X_CFLAGS)
      esac
      break; dnl Only need ONE X11 implementation !
    fi
  done

  ld_switch_x_site="$X_LIBS"

  XE_COMPUTE_RUNPATH()

  if test "$extra_verbose" = "yes"; then
    echo; echo "X11 compilation variables:"
    PRINT_VAR(x_libraries x_includes X_CFLAGS X_LIBS X_PRE_LIBS X_EXTRA_LIBS)
    echo
  fi

  dnl Autodetect defines extracted from X config by xmkmf, e.g. NARROWPROTO
  AC_CHECKING(for X defines extracted by xmkmf)
  rm -fr conftestdir
  if mkdir conftestdir; then
    cd conftestdir
    cat > Imakefile <<'EOF'
xetest:
	@echo ${PROTO_DEFINES} ${STD_DEFINES}
EOF
    if (xmkmf) >/dev/null 2>/dev/null && test -f Makefile; then
      # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
      xmkmf_defines=`${MAKE-make} xetest 2>/dev/null | grep -v make`
    fi
    cd ..
    rm -fr conftestdir
    for word in $xmkmf_defines; do
      case "$word" in
	-D*=* ) ;;
	-D* ) word=`echo '' $word | sed -e 's:^ *-D::'`
	      AC_DEFINE_UNQUOTED($word) ;;
      esac
    done
  fi

  dnl make sure we can find Intrinsic.h
  AC_CHECK_HEADER(X11/Intrinsic.h, ,
   [AC_MSG_ERROR("Unable to find X11 header files.")])

  dnl -lXt and -lX11 are required
  dnl Some broken systems require the magic "-b i486-linuxaout" flag
  AC_CHECK_LIB(X11, XOpenDisplay, have_lib_x11=yes)
  if test "$have_lib_x11" != "yes"; then
    AC_CHECK_LIB(X11, XGetFontProperty,
      ld_switch_x_site="-b i486-linuxaout $ld_switch_x_site",
      [AC_MSG_ERROR("Unable to find X11 libraries.")],
      -b i486-linuxaout)
  fi
  libs_x="-lX11"
  test "$extra_verbose" = "yes" && echo "    Setting libs_x to \"-lX11\""

  dnl Autodetect -lXext
  AC_CHECK_LIB(Xext, XShapeSelectInput, XE_PREPEND(-lXext, libs_x))

  dnl Require -lXt
  AC_CHECK_LIB(Xt, XtOpenDisplay, XE_PREPEND(-lXt, libs_x),
    AC_MSG_ERROR("Unable to find X11 libraries."))

  AC_MSG_CHECKING(the version of X11 being used)
  AC_TRY_RUN([#include <X11/Intrinsic.h>
    main(int c, char* v[]) { return c>1 ? XlibSpecificationRelease : 0; }],
    [./conftest foobar; x11_release=$?],[x11_release=4],[x11_release=4])
  AC_MSG_RESULT(R${x11_release})
  AC_DEFINE_UNQUOTED(THIS_IS_X11R${x11_release})

  AC_CHECK_HEADERS(X11/Xlocale.h)

  dnl remove this - we should avoid checking for specific OS
  AC_MSG_CHECKING(for XFree86)
  if test -d "/usr/X386/include" -o \
          -f "/etc/XF86Config"    -o \
	  -f "/etc/X11/XF86Config" -o \
	  -f "/usr/X11R6/lib/X11/XF86Config"; then
    AC_MSG_RESULT(yes)
    AC_DEFINE(HAVE_XFREE386)
  else
    AC_MSG_RESULT(no)
  fi

  dnl autodetect -lXmu
  test -z "$with_xmu" && { AC_CHECK_LIB(Xmu, XmuReadBitmapDataFromFile,
                           with_xmu=yes, with_xmu=no) }
  if test "$with_xmu" = "no"
  then XE_ADD_OBJS(xmu.o)
  else XE_PREPEND(-lXmu, libs_x)
  fi

  dnl Autodetect -lXbsd
  dnl #### Someone, please add a better function than main
  AC_CHECK_LIB(Xbsd, main, XE_PREPEND(-lXbsd, libs_x))

  dnl Autodetect -lXaw
  AC_CHECK_LIB(Xaw, XawScrollbarSetThumb, have_xaw=yes, have_xaw=no)
  if test "$have_xaw" = "yes"; then
    AC_CHECK_HEADER(X11/Xaw/Reports.h, [
     XE_APPEND(pkg-src/tree-x, MAKE_SUBDIR)
     XE_APPEND(pkg-src/tree-x, INSTALL_ARCH_DEP_SUBDIR)])
  fi

fi dnl $with_x11 = yes

test -z "$window_system" && window_system="none"

if test "$window_system" = "none" ; then
  if test "$with_tty" = "no" ; then
    AC_MSG_ERROR([No window system support and no TTY support - Unable to proceed.])
  fi
  for feature in tooltalk cde offix \
                 menubars scrollbars toolbars dialogs xim xmu \
                 tiff png jpeg gif compface xpm
  do
    if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
       AC_MSG_WARN([--with-$feature ignored:  Not valid without X support])
    fi
    eval "with_${feature}=no"
  done
else
  test -z "$with_toolbars" && with_toolbars=yes
fi

dnl FSF 19.29 has some bitmapdir stuff here.
bitmapdir=

case "$window_system" in
  x11  ) HAVE_X_WINDOWS=yes; echo "  Using X11." ;;
  none ) HAVE_X_WINDOWS=no ; echo "  Using no window system." ;;
esac

case "$x_libraries" in *X11R4* )
  test "$opsys" = "hpux9"     && opsysfile="s/hpux9-x11r4.h"
  test "$opsys" = "hpux9-shr" && opsysfile="s/hpux9shxr4.h"
esac

dnl Autodetect Xauth
dnl -lXau is only used by gnuclient, so use a special variable for Xauth X libs
test -z "$with_xauth" && test "$window_system" = "none" && with_xauth=no
test -z "$with_xauth" && { AC_CHECK_HEADER(X11/Xauth.h,          ,with_xauth=no) }
test -z "$with_xauth" && { AC_CHECK_LIB(Xau, XauGetAuthByAddr,[:],with_xauth=no) }
test -z "$with_xauth" && with_xauth=yes
if test "$with_xauth" = "yes"; then
  AC_DEFINE(HAVE_XAUTH)
  XE_SPACE(libs_xauth, $X_EXTRA_LIBS -lXau $libs_x $X_PRE_LIBS)
fi
AC_SUBST(libs_xauth)

dnl Autodetect OffiX
test -z "$with_offix" && { AC_CHECK_HEADER(OffiX/DragAndDrop.h, , with_offix=no) }
test -z "$with_offix" && { AC_CHECK_LIB(Dnd, DndInitialize, [:] , with_offix=no) }
test -z "$with_offix" && with_offix=yes
if test "$with_offix" = "yes"; then
  AC_DEFINE(HAVE_OFFIX_DND)
  XE_PREPEND(-lDnd, libs_x)
fi

dnl Autodetect tooltalk
test "$with_cde" = "yes" && with_tooltalk=yes # CDE requires tooltalk
if test "$with_tooltalk" != "no" ; then
  dnl autodetect the location of tt_c.h
  dnl tt_c.h might be in Tt or desktop include directories
  for dir in "" "Tt/" "desktop/" ; do
    AC_CHECK_HEADER(${dir}tt_c.h, tt_c_h_path="${dir}tt_c.h" && break)
  done
  test -z "$tt_c_h_path" && with_tooltalk=no
fi
if test "$with_tooltalk" != "no" ; then
  for extra_libs in "" "-lI18N -lce" "-lcxx"; do
    AC_CHECK_LIB(tt, tt_message_create,
      with_tooltalk=yes tt_libs="-ltt $extra_libs"; break, [:],$extra_libs)
  done
fi
test -z "$with_tooltalk" && with_tooltalk=no
if test "$with_tooltalk" = "yes"; then
  AC_DEFINE(TOOLTALK)
  AC_DEFINE_UNQUOTED(TT_C_H_PATH, "$tt_c_h_path")
  XE_PREPEND($tt_libs, libs_x)
  XE_ADD_OBJS(tooltalk.o)
fi

dnl Autodetect CDE
test -z "$with_cde" && { AC_CHECK_HEADER(Dt/Dt.h,               , with_cde=no) }
test -z "$with_cde" && { AC_CHECK_LIB(DtSvc, DtDndDragStart, [:], with_cde=no) }
test -z "$with_cde" && with_cde=yes
if test "$with_cde" = "yes" ; then
  AC_DEFINE(HAVE_CDE)
  XE_PREPEND(-lDtSvc, libs_x)
  with_tooltalk=yes # CDE requires Tooltalk
  need_motif=yes    # CDE requires Motif
fi

dnl if Energize specified, make sure we can find its need libraries/headers
if test "$with_energize" = "yes" ; then
  AC_DEFINE(ENERGIZE)
  AC_CHECK_LIB(energize, main, [
     XE_PREPEND(-lenergize, LIBS)
     energize_version="3.X"
     AC_DEFINE(ENERGIZE_3)])
  if test -z "$energize_version"; then
    AC_CHECK_LIB(conn, main, [
      XE_PREPEND(-lconn, LIBS)
      energize_version="2.X"
      AC_DEFINE(ENERGIZE_2)],
     [AC_MSG_ERROR(Unable to find Energize library.)])
  fi
  AC_CHECK_HEADER(editorconn.h, ,
    [AC_MSG_ERROR(Unable to find Energize editorconn.h header file.)])

  test "$energize_version" = "2.X" && AC_DEFINE(ENERGIZE_2)
  test "$energize_version" = "3.X" && AC_DEFINE(ENERGIZE_3)
fi

dnl ------------------
dnl Graphics libraries
dnl ------------------

AC_CHECKING(for graphics libraries)
dnl Built-in GIF support defaults to yes
test -z "$with_gif" && with_gif=yes;
if test "$with_gif" = "yes"; then
  AC_DEFINE(HAVE_GIF)
  XE_ADD_OBJS(dgif_lib.o gif_err.o gifalloc.o)
fi

dnl Autodetect Xpm
AC_MSG_CHECKING(for Xpm - no older than 3.4f)
xe_check_libs=-lXpm
test -z "$with_xpm" && { AC_TRY_RUN([#include <X11/xpm.h>
int main(int c, char **v) {
return c == 1 ? 0 :
  XpmIncludeVersion != XpmLibraryVersion() ? 1 :
        XpmIncludeVersion < 30406 ? 2 :
		0 ;
}], [./conftest foobar; xpm_status=$?;
  if test "$xpm_status" = "0"; then with_xpm=yes; else with_xpm=no; fi;],
with_xpm=no, with_xpm=no)
}
xe_check_libs=
AC_MSG_RESULT($with_xpm)
if test "$xpm_status" = "1" -o "$xpm_status" = "2"; then
  test "$xpm_status" = "1" && problem="Xpm library version and header file version don't match!"
  test "$xpm_status" = "2" && problem="Xpm library version is too old!"
  echo "
*** WARNING *** $problem
                I'm not touching that with a 10-foot pole!
                If you really want to use the installed version of Xpm, rerun
                configure --with-xpm=yes, but don't blame me if XEmacs crashes!
"
fi
if test "$with_xpm" = "yes"; then
  AC_DEFINE(HAVE_XPM)
  XE_PREPEND(-lXpm, libs_x)
fi

dnl Autodetect XFACE
test -z "$with_xface" && { AC_CHECK_HEADER(compface.h,          ,with_xface=no) }
test -z "$with_xface" && { AC_CHECK_LIB(compface, UnGenFace,[:] ,with_xface=no) }
test -z "$with_xface" && with_xface=yes
if test "$with_xface" = "yes"; then
  AC_DEFINE(HAVE_XFACE)
  XE_PREPEND(-lcompface, libs_x)
fi

dnl autodetect JPEG
test -z "$with_jpeg" && { AC_CHECK_HEADER(jpeglib.h,                    ,with_jpeg=no) }
test -z "$with_jpeg" && { AC_CHECK_LIB(jpeg, jpeg_destroy_decompress,[:],with_jpeg=no) }
test -z "$with_jpeg" && with_jpeg=yes
if test "$with_jpeg" = "yes"; then
  AC_DEFINE(HAVE_JPEG)
  XE_PREPEND(-ljpeg, libs_x)
fi

dnl autodetect PNG
test -z "$with_png" && { AC_CHECK_HEADER(png.h, , with_png=no) }
test -z "$with_png" && { AC_CHECK_FUNC(pow,     , with_png=no) }
if test "$with_png" != "no"; then
  for extra_libs in "" "-lz" "-lgz"; do
    AC_CHECK_LIB(png, png_read_image,
      png_libs="-lpng $extra_libs" with_png=yes; break,[:],$extra_libs)
  done
fi
test -z "$with_png" && with_png=no
if test "$with_png" = "yes"; then
  AC_DEFINE(HAVE_PNG)
  XE_PREPEND($png_libs, libs_x)
fi

dnl autodetect TIFF (not yet implemented)
if test "$with_tiff" = "yes"; then
  AC_DEFINE(HAVE_TIFF)
  XE_PREPEND(-ltiff, libs_x)
fi

dnl autodetect Motif - but only add to libs_x later (if necessary)
  AC_CHECK_HEADER(Xm/Xm.h,
   [AC_CHECK_LIB(Xm, XmStringFree, have_motif=yes, have_motif=no)],
   have_motif=no)

dnl Finish ensuring that we have values for the various toolkit items.
dnl Not all toolkits support all widgets
dnl if Motif is available we use it for the dialog boxes.

case "$with_menubars" in "" | "yes" | "athena" )
  with_menubars="lucid" ;;
esac
case "$with_dialogs" in "" | "yes" | "lucid"  )
  if   test "$have_motif" = "yes"; then with_dialogs="motif"
  elif test "$have_xaw"   = "yes"; then with_dialogs="athena"
  else with_dialogs=no
  fi ;;
esac
case "$with_scrollbars" in "" | "yes" )
  with_scrollbars="lucid" ;;
esac

all_widgets="$with_menubars $with_scrollbars $with_dialogs $with_toolbars"

case "$all_widgets" in *athena* )
  AC_DEFINE(LWLIB_USES_ATHENA)
  AC_DEFINE(NEED_ATHENA)
  XE_APPEND(lwlib-Xaw.o, lwlib_objs)
  XE_PREPEND(-lXaw, libs_x) ;;
esac

case "$all_widgets" in *motif* )
  AC_DEFINE(LWLIB_USES_MOTIF)
  AC_DEFINE(NEED_MOTIF)
  XE_APPEND(lwlib-Xm.o, lwlib_objs)
  need_motif=yes ;;
esac

test "$with_menubars"   = "lucid" && XE_APPEND(xlwmenu.o, lwlib_objs)
test "$with_scrollbars" = "lucid" && XE_APPEND(xlwscrollbar.o, lwlib_objs)
case "$all_widgets" in *lucid* )
  AC_DEFINE(NEED_LUCID)
  XE_APPEND(lwlib-Xlw.o, lwlib_objs) ;;
esac

AC_SUBST(lwlib_objs)

case "$with_scrollbars" in athena* ) AC_DEFINE(LWLIB_SCROLLBARS_ATHENA);; esac
case "$with_dialogs"    in athena* ) AC_DEFINE(LWLIB_DIALOGS_ATHENA)   ;; esac
test "$with_scrollbars" = "athena3d" && AC_DEFINE(LWLIB_SCROLLBARS_ATHENA3D)
test "$with_dialogs"    = "athena3d" && AC_DEFINE(LWLIB_DIALOGS_ATHENA3D)

test "$with_menubars"   != "no"    && AC_DEFINE(HAVE_MENUBARS)
test "$with_scrollbars" != "no"    && AC_DEFINE(HAVE_SCROLLBARS)
test "$with_dialogs"    != "no"    && AC_DEFINE(HAVE_DIALOGS)
test "$with_toolbars"   != "no"    && AC_DEFINE(HAVE_TOOLBARS)

test "$with_menubars"   = "lucid"  && AC_DEFINE(LWLIB_MENUBARS_LUCID)
test "$with_scrollbars" = "lucid"  && AC_DEFINE(LWLIB_SCROLLBARS_LUCID)

test "$with_menubars"   = "motif"  && AC_DEFINE(LWLIB_MENUBARS_MOTIF)
test "$with_scrollbars" = "motif"  && AC_DEFINE(LWLIB_SCROLLBARS_MOTIF)
test "$with_dialogs"    = "motif"  && AC_DEFINE(LWLIB_DIALOGS_MOTIF)

test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar.o)
test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar.o)
test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog.o)
test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar.o)
test "$all_widgets" != "no no no no" && XE_ADD_OBJS(gui.o)

if test "$with_x11" = "yes"; then
  test "$with_menubars"   != "no"      && XE_ADD_OBJS(menubar-x.o)
  test "$with_scrollbars" != "no"      && XE_ADD_OBJS(scrollbar-x.o)
  test "$with_dialogs"    != "no"      && XE_ADD_OBJS(dialog-x.o)
  test "$with_toolbars"   != "no"      && XE_ADD_OBJS(toolbar-x.o)
  test "$all_widgets" != "no no no no" && XE_ADD_OBJS(gui-x.o)
fi

dnl ----------------------
dnl Mule-dependent options
dnl ----------------------

test -z "$with_mule" && with_mule=no

if test "$with_mule" = "yes" ; then
  AC_CHECKING(for Mule-related features)
  AC_DEFINE(MULE)
  XE_ADD_OBJS(mule.o mule-ccl.o mule-charset.o mule-coding.o)

  dnl Use -lintl to get internationalized strerror for Mule
  AC_CHECK_HEADERS(libintl.h)
  AC_CHECK_LIB(intl, strerror)

  AC_CHECKING(for Mule input methods)
  dnl Do we have the XmIm* routines?  And if so, do we want to use them?
  dnl XIM seems to be flaky except on Solaris...
  test -z "$with_xim" -a "$opsys" != "sol2" && with_xim=no
  case "$with_xim" in "" | "yes" )
    AC_CHECKING(for XIM)
    AC_CHECK_LIB(Xm, XmImMbLookupString, with_xim=motif, with_xim=xlib)
  esac
  if test "$with_xim" != "no" ; then
    AC_DEFINE(HAVE_XIM)
    if test "$with_xim" = "xlib"; then
      AC_DEFINE(XIM_XLIB)
      XE_ADD_OBJS(input-method-xlib.o)
    fi
    if test "$with_xim" = "motif"; then
      AC_DEFINE(XIM_MOTIF)
      need_motif=yes
      XE_ADD_OBJS(input-method-motif.o)
    fi
  fi dnl with_xim

  dnl Autodetect WNN
  test "$with_wnn6" = "yes" && with_wnn=yes # wnn6 implies wnn support
  test -z "$with_wnn" && { AC_CHECK_HEADER(wnn/jllib.h, ,with_wnn=no) }
  dnl Detour to find crypt
  if test "$with_wnn" != "no"; then
    AC_CHECK_FUNCS(crypt)
    test "$ac_cv_func_crypt" != "yes" && { AC_CHECK_LIB(crypt, crypt) }
  fi
  dnl Back to our regularly scheduled wnn hunting
  test -z "$with_wnn" && { AC_CHECK_LIB(wnn,jl_dic_list_e,[:],with_wnn=no) }
  test -z "$with_wnn" && with_wnn=yes
  if test "$with_wnn" = "yes"; then
    AC_DEFINE(HAVE_WNN)
    XE_PREPEND(-lwnn, libs_x)
    XE_ADD_OBJS(mule-wnnfns.o)
    AC_CHECK_LIB(wnn, jl_fi_dic_list, with_wnn6=yes)
    test "$with_wnn6" = "yes" && AC_DEFINE(WNN6)
  fi

  dnl Autodetect canna
  test -z "$with_canna" && { AC_CHECK_HEADER(canna/RK.h,         , with_canna=no) }
  test -z "$with_canna" && { AC_CHECK_LIB(RKC, RkBgnBun,       [:],with_canna=no) }
  test -z "$with_canna" && { AC_CHECK_LIB(canna,jrKanjiControl,[:],with_canna=no) }
  test -z "$with_canna" && with_canna=yes
  if test "$with_canna" = "yes"; then
    AC_DEFINE(HAVE_CANNA)
    XE_PREPEND(-lcanna -lRKC, libs_x)
    XE_ADD_OBJS(mule-canna.o)
  fi

else dnl "$with_mule" = "no"
  for feature in xim canna wnn; do
    if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
      AC_MSG_WARN("--with-${feature} ignored:  Not valid without Mule support")
    fi
    eval "with_${feature}=no"
  done
fi dnl with_mule


dnl At this point, we know whether we need the motif lib or not.
if test "$need_motif" = "yes" ; then
  XE_PREPEND(-lXm, libs_x)
  XE_COMPUTE_RUNPATH()
fi

AC_CHECK_FUNCS(acosh asinh atanh cbrt closedir dup2 eaccess fmod fpathconf frexp ftime gethostname getpagesize gettimeofday getcwd getwd logb lrand48 matherr mkdir mktime perror poll random rename res_init rint rmdir select setitimer setpgid setlocale setsid sigblock sighold sigprocmask strcasecmp strerror tzset ulimit usleep utimes waitpid)

dnl realpath is buggy on linux, decosf and aix4

dnl The realpath() in linux libc (4.6.27) sometimes fails with ELOOP.
dnl For example, call realpath on a file thirty-five or so directories deep
dnl and you get ELOOP even if no symlinks at all are involved.
case "$opsys" in
  linux* | decosf4-0* | aix4* ) XE_ADD_OBJS(realpath.o) ;;
  * )
    AC_CHECK_FUNCS(realpath)
    test "$ac_cv_func_realpath" != "yes" && XE_ADD_OBJS(realpath.o) ;;
esac

dnl If netdb.h does not declare h_errno, we must declare it by hand.
AC_MSG_CHECKING(whether netdb declares h_errno)
AC_TRY_LINK([#include <netdb.h>],
  [return h_errno;],
  [AC_MSG_RESULT(yes)
   AC_DEFINE(HAVE_H_ERRNO)],
  [AC_MSG_RESULT(no)])

AC_MSG_CHECKING(for sigsetjmp)
AC_TRY_COMPILE([#include <setjmp.h>],
	[sigjmp_buf bar; sigsetjmp (bar, 0);],
  [AC_MSG_RESULT(yes)
   AC_DEFINE(HAVE_SIGSETJMP)],
  [AC_MSG_RESULT(no)])

AC_MSG_CHECKING(whether localtime caches TZ)
AC_CACHE_VAL(emacs_cv_localtime_cache,
[if test "$ac_cv_func_tzset" = "yes"; then
AC_TRY_RUN([#include <time.h>
#if STDC_HEADERS
# include <stdlib.h>
#endif
extern char **environ;
unset_TZ ()
{
  char **from, **to;
  for (to = from = environ; (*to = *from); from++)
    if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
      to++;
}
char TZ_GMT0[] = "TZ=GMT0";
char TZ_PST8[] = "TZ=PST8";
main()
{
  time_t now = time ((time_t *) 0);
  int hour_GMT0, hour_unset;
  if (putenv (TZ_GMT0) != 0)
    exit (1);
  hour_GMT0 = localtime (&now)->tm_hour;
  unset_TZ ();
  hour_unset = localtime (&now)->tm_hour;
  if (putenv (TZ_PST8) != 0)
    exit (1);
  if (localtime (&now)->tm_hour == hour_GMT0)
    exit (1);
  unset_TZ ();
  if (localtime (&now)->tm_hour != hour_unset)
    exit (1);
  exit (0);
}], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
[# If we have tzset, assume the worst when cross-compiling.
emacs_cv_localtime_cache=yes])
else
	# If we lack tzset, report that localtime does not cache TZ,
	# since we can't invalidate the cache if we don't have tzset.
	emacs_cv_localtime_cache=no
fi],[:])dnl
AC_MSG_RESULT($emacs_cv_localtime_cache)
if test $emacs_cv_localtime_cache = yes; then
  AC_DEFINE(LOCALTIME_CACHE)
fi

if test "$HAVE_TIMEVAL" = "yes"; then
AC_MSG_CHECKING(whether gettimeofday cannot accept two arguments)
AC_TRY_LINK([
#ifdef TIME_WITH_SYS_TIME
#include <sys/time.h>
#include <time.h>
#else
#ifdef HAVE_SYS_TIME_H
#include <sys/time.h>
#else
#include <time.h>
#endif
#endif
  ],
  [
  struct timeval time;
  struct timezone dummy;
  gettimeofday (&time, &dummy);
],
  [AC_MSG_RESULT(no)],
  [AC_MSG_RESULT(yes)
   AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
fi


AC_C_INLINE
if test "$ac_cv_c_inline" != "no"; then
  AC_DEFINE(HAVE_INLINE)
  test "$GCC" = "yes" && XE_ADD_OBJS(inline.o)
fi

dnl HP-UX has a working alloca in libPW.
case "$opsys" in hpux* )
 AC_CHECK_FUNC(alloca, [:], [AC_CHECK_LIB(PW, alloca)])
esac

AC_FUNC_ALLOCA
test -n "$ALLOCA" && XE_ADD_OBJS($ALLOCA)

dnl Check whether vfork exists and works correctly. (This does more
dnl than just check for its existence.) If so, it defines HAVE_VFORK_H.
dnl If not, it defines vfork to be fork.
AC_FUNC_VFORK

dnl Check whether strcoll exists and works correctly. (This does more
dnl than just check for its existence.) If so, it defines HAVE_STRCOLL.
AC_FUNC_STRCOLL

dnl If `getpgrp' takes no argument (the POSIX.1 version), define
dnl `GETPGRP_VOID'.  Otherwise, it is the BSD version, which takes a
dnl process ID as an argument.
AC_CHECK_FUNCS(getpgrp)
AC_FUNC_GETPGRP

dnl We used to call AC_FUNC_MMAP here
dnl Instead we now use following, suggested by Neal Becker
AC_MSG_CHECKING(for working mmap)
case "$opsys" in ultrix* ) have_mmap=no ;; *)
AC_TRY_RUN([#include <stdio.h>
#include <unistd.h>
#include <fcntl.h>
#include <sys/mman.h>

#ifndef MAP_VARIABLE
#define MAP_VARIABLE 0
#endif

#ifndef MAP_FAILED
#define MAP_FAILED -1
#endif

int main (int argc, char *argv[])
{
  int fd = -1;
  caddr_t p;
#ifndef MAP_ANONYMOUS
  fd = open ("/dev/zero", O_RDWR);
  if (fd < 0)
    return 1;
#define MAP_ANONYMOUS 0
#endif
  if (mmap(0, 1024, PROT_READ | PROT_WRITE,
	   MAP_PRIVATE | MAP_VARIABLE | MAP_ANONYMOUS,
	   fd, 0) != (void *) MAP_FAILED)
    return 0;
  perror ("conftest: mmap failed");
  return 1;
}], have_mmap=yes, have_mmap=no) ;;
esac
AC_MSG_RESULT($have_mmap)
test "$have_mmap" = "yes" && AC_DEFINE(HAVE_MMAP)

dnl rel_alloc requires either GNU malloc or system malloc with mmap
dnl We only turn rel_alloc on by default if mmap is available.
test "$GNU_MALLOC" != "yes"   -a "$have_mmap" != "yes" && rel_alloc=no
test "$rel_alloc" = "default" -a "$have_mmap"  = "yes" && rel_alloc=yes
test "$rel_alloc" = "yes" && AC_DEFINE(REL_ALLOC)

dnl Check for terminal I/O variants
dnl TERMIOS systems may have termio.h, but not vice-versa, I think.
AC_CHECK_HEADER(termios.h, 
  AC_DEFINE(HAVE_TERMIOS)
  AC_DEFINE(SIGNALS_VIA_CHARACTERS)
  AC_DEFINE(NO_TERMIO),
  [AC_CHECK_HEADER(termio.h, [AC_DEFINE(HAVE_TERMIO)])])


dnl Check for Internet sockets.
AC_CHECK_FUNC(socket,
 [AC_CHECK_HEADER(netinet/in.h,
   [AC_CHECK_HEADER(arpa/inet.h, [
  AC_DEFINE(HAVE_SOCKETS)
      AC_MSG_CHECKING("for sun_len member in struct sockaddr_un")
      AC_TRY_LINK([
#include <sys/types.h>
#include <sys/socket.h>
#include <sys/un.h>
      ],
      [static struct sockaddr_un x; x.sun_len = 1;],
      [AC_MSG_RESULT(yes); AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)],
      [AC_MSG_RESULT(no)])])])])

dnl Check for SYS V IPC. (Inferior to sockets.)
AC_CHECK_FUNC(msgget,
  [AC_CHECK_HEADER(sys/ipc.h,
    [AC_CHECK_HEADER(sys/msg.h,
      [AC_DEFINE(HAVE_SYSVIPC)])])])

dnl Check for directory variants
AC_CHECK_HEADER(dirent.h, [AC_DEFINE(SYSV_SYSTEM_DIR)],
  [AC_CHECK_HEADER(sys/dir.h, , [AC_DEFINE(NONSYSTEM_DIR_LIBRARY)])])

dnl Check for nlist.h
AC_CHECK_HEADER(nlist.h, AC_DEFINE(NLIST_STRUCT), )

dnl AIX export list
for f in "/usr/lpp/X11/bin/smt.exp" "/usr/bin/X11/smt.exp" ; do
  if test -r $f; then AC_DEFINE_UNQUOTED(AIX_SMT_EXP, "-bI:$f") break; fi
done

dnl Check for sound of various sorts.

dnl Autodetect native sound
AC_CHECKING("for sound support")
case "$with_sound" in
  native | both ) with_native_sound=yes;;
  nas    | no   ) with_native_sound=no;;
esac
test -z "$with_native_sound" -a -n "$native_sound_lib" && with_native_sound=yes

if test "$with_native_sound" != "no"; then
  dnl Maybe sound is already on include path...
  if test -n "$native_sound_lib"; then
    AC_CHECK_HEADER(multimedia/audio_device.h,
      [sound_found=yes sound_cflags=""
      XE_ADD_OBJS(sunplay.o)])
  fi

  dnl Autodetect Sun native sound from SUNWaudmo package
  if test -z "$sound_found" -a -d "/usr/demo/SOUND"; then
    sound_found=yes
    XE_ADD_OBJS(sunplay.o)
    if test -d "/usr/demo/SOUND/include"
      then sound_cflags="-I/usr/demo/SOUND/include"
      else sound_cflags="-I/usr/demo/SOUND"
    fi
    if test -z "$native_sound_lib" ; then
      if test -r "/usr/demo/SOUND/lib/libaudio.a"
        then native_sound_lib="/usr/demo/SOUND/lib/libaudio.a"
        else native_sound_lib="/usr/demo/SOUND/libaudio.a"
      fi
    fi
  fi

  dnl Check for SGI and HP native sound libs
  if test -z "$sound_found"; then
    case "$canonical" in
    *-sgi-* )
      if test -z "$native_sound_lib"; then
        AC_CHECK_LIB(audio, ALopenport, native_sound_lib="-laudio")
      fi
      if test -n "$native_sound_lib"; then
        sound_found=yes sound_cflags=""
        XE_ADD_OBJS(sgiplay.o)
      fi ;;
    hppa*-hp-hpux* )
      if test -z "$native_sound_lib"; then
	AC_CHECK_LIB(Alib, AOpenAudio, native_sound_lib="-lAlib")
      fi
      if test -n "$native_sound_lib"; then
        sound_found=yes
        XE_ADD_OBJS(hpplay.o)
        if test "$GCC" = "yes" # Kludge city
          then sound_cflags="-Dconst= -Dvolatile= -I/usr/audio/examples"
          else sound_cflags="+e -I/usr/audio/examples"
        fi
      fi ;;
    esac
  fi

  dnl Check for Linux/BSD native sound
  if test -z "$sound_found"; then
    for dir in "machine" "sys" "linux"; do
      AC_CHECK_HEADER(${dir}/soundcard.h,
        sound_found=yes
        XE_ADD_OBJS(linuxplay.o)
        [AC_DEFINE_UNQUOTED(SOUNDCARD_H_PATH, "${dir}/soundcard.h")]
        break)
    done
  fi

  test "$sound_found" = "yes" && with_native_sound=yes
fi

if test -z "$with_sound"; then
  if test "$with_native_sound" = "yes" -o -n "$native_sound_lib"; then
    with_sound=native
  fi
fi

if test "$with_native_sound" = "yes"; then
  AC_DEFINE(HAVE_NATIVE_SOUND)
  test -n "$native_sound_lib" && XE_PREPEND($native_sound_lib, LIBS)
fi

case "$with_sound" in both | nas )
  AC_DEFINE(HAVE_NAS_SOUND)
  XE_ADD_OBJS(nas.o)
  XE_PREPEND(-laudio, LIBS)
  dnl If the nas library does not contain the error jump point,
  dnl then we force safer behaviour.
  AC_EGREP_HEADER(AuXtErrorJump,audio/Xtutil.h,,[AC_DEFINE(NAS_NO_ERROR_JUMP)])
esac

dnl ---------------------
dnl TTY-dependent options
dnl ---------------------

test -z "$with_tty" && with_tty=yes

if test "$with_tty" = "yes"  ; then
  AC_CHECKING(for TTY-related features)
  AC_DEFINE(HAVE_TTY)
  XE_ADD_OBJS(console-tty.o device-tty.o event-tty.o frame-tty.o objects-tty.o redisplay-tty.o cm.o)

  dnl Autodetect ncurses.
  if test -z "$with_ncurses"; then
    AC_CHECK_LIB(ncurses, tgetent, with_ncurses=yes, with_ncurses=no)
  fi
  if test "$with_ncurses" = "yes"; then
    AC_DEFINE(HAVE_NCURSES)
    AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
    AC_CHECK_HEADER(ncurses/term.h, term_h_path=ncurses/term.h)
    XE_ADD_OBJS(terminfo.o)
    XE_PREPEND(-lncurses, LIBS)

    if test "$ac_cv_header_ncurses_curses_h" != "yes" ; then
      dnl Try again, and check for the bogus ncurses/ include bug.
      dnl (i.e. ncurses/curses.h bogusly includes <unctrl.h> instead of
      dnl <ncurses/unctrl.h>)
      save_c_switch_site="$c_switch_site"
      c_switch_site="$c_switch_site -I/usr/include/ncurses"
      AC_CHECK_HEADER(ncurses/curses.h, curses_h_path=ncurses/curses.h)
      if test "$ac_cv_header_ncurses_curses_h" = "yes"
        then AC_MSG_WARN("Your system has the bogus ncurses include bug.")
        else c_switch_site="$save_c_switch_site"
      fi
    fi
  else dnl "$with_ncurses" = "no"
    dnl Autodetect terminfo/-lcurses/-ltermlib/-ltermcap
    if test "$have_terminfo" = "yes"; then
      XE_ADD_OBJS(terminfo.o)
      if test -n "$libs_termcap"; then
	XE_PREPEND($libs_termcap, LIBS)
      else
	for lib in curses termlib termcap; do
	  AC_CHECK_LIB($lib, tgetent, XE_PREPEND(-l${lib}, LIBS); break)
	done
      fi
    else dnl "$have_terminfo" = "no" && "with_ncurses" = "no"
      XE_ADD_OBJS(tparam.o)
      dnl The HP-UX curses library seems to have a badly broken version of select(2)
      dnl that makes "poll: interrupted system call" messages to appear and
      dnl Emacs suprocesses to hang (e.g. TeX compilation w/ AUCTeX) */
      case "$opsys" in *-hp-hpux* ) libs_termcap="-ltermcap" ;; esac
      if test -n "$libs_termcap"; then
	XE_PREPEND($libs_termcap, LIBS)
      else
	AC_CHECK_LIB(curses, tgetent, XE_PREPEND(-lcurses, LIBS),
	  AC_CHECK_LIB(termcap, tgetent, XE_PREPEND(-ltermcap, LIBS),
            XE_ADD_OBJS(termcap.o)))
      fi
    fi
  fi
  AC_DEFINE_UNQUOTED(CURSES_H_PATH, "${curses_h_path-curses.h}")
  AC_DEFINE_UNQUOTED(TERM_H_PATH, "${term_h_path-term.h}")

  dnl Autodetect gpm
  test -z "$with_gpm" && { AC_CHECK_HEADER(gpm.h, , with_gpm=no) }
  test -z "$with_gpm" && { AC_CHECK_LIB(gpm, Gpm_Open, with_gpm=yes, with_gpm=no) }
  if test "$with_gpm" = "yes"; then
    AC_DEFINE(HAVE_GPM)
    XE_ADD_OBJS(gpmevent.o)
    XE_PREPEND(-lgpm, LIBS)
  fi

else dnl "$with_tty" = "no"
  for feature in ncurses gpm; do
    if eval "test -n \"\$with_${feature}\" -a \"\$with_${feature}\" != no" ; then
      AC_MSG_WARN("--with-${feature} ignored:  Not valid without TTY support")
    fi
    eval "with_${feature}=no"
  done
fi dnl with_tty

dnl Do we need event-unixoid.o ?
test "$with_x11" = "yes" -o "$with_tty" = "yes" && XE_ADD_OBJS(event-unixoid.o)

dnl Database support
dnl <mdiers@logware.de>
dnl We do not necessarily have to have libdb/lib(g)dbm for DB/(G)DBM support.
dnl On FreeBSD, both DB and DBM are part of libc.
dnl Note that unless support for DB/(G)DBM is explicitly disabled, we always
dnl want to check for libdb/lib(g)dbm. Also note that libc will not be
dnl checked if we have the libraries.
dnl If support for DB/(G)DBM is requested, but we neither have libdb/lib(g)dbm,
dnl nor does libc implement it, we are a bit lost :)

AC_CHECKING(for database support)

if test "$with_database_gnudbm" != "no"; then
  AC_CHECK_LIB(gdbm, dbm_open, with_database_gnudbm=yes have_libgdbm=yes)
  if test "$with_database_gnudbm" != "yes"; then
    AC_CHECK_FUNC(dbm_open, with_database_gnudbm=yes)
      fi
  if test "$with_database_gnudbm" = "yes"; then
    AC_DEFINE(HAVE_DBM)
    test "$have_libgdbm" = "yes" && XE_PREPEND(-lgdbm, LIBS)
    with_database_dbm=no
  else with_database_gnudbm=no
  fi
fi

if test "$with_database_dbm" != "no"; then
  AC_CHECK_FUNC(dbm_open, with_database_dbm=yes need_libdbm=no)
  if test "$need_libdbm" != "no"; then
    AC_CHECK_LIB(dbm, dbm_open, with_database_dbm=yes need_libdbm=yes)
  fi
  if test "$with_database_dbm" = "yes"; then
    AC_DEFINE(HAVE_DBM)
    test "$need_libdbm" = "yes" && XE_PREPEND(-ldbm, LIBS)
  else with_database_dbm=no
  fi
fi

if test "$with_database_berkdb" != "no"; then
  AC_CHECK_FUNC(dbopen, with_database_berkdb=yes need_libdb=no)
  if test "$need_libdb" != "no"; then
    AC_CHECK_LIB(db, dbopen, with_database_berkdb=yes need_libdb=yes)
    fi
  if test "$with_database_berkdb" = "yes"; then
    for path in "db/db.h" "db.h"; do
AC_TRY_COMPILE([#ifdef HAVE_INTTYPES_H
#define __BIT_TYPES_DEFINED__
#include <inttypes.h>
typedef uint8_t  u_int8_t;
typedef uint16_t u_int16_t;
typedef uint32_t u_int32_t;
#ifdef WE_DONT_NEED_QUADS
typedef uint64_t u_int64_t;
#endif
#endif
#include <$path>
],[], db_h_path="$path"; break)
    done
    test -z "$db_h_path" && with_database_berkdb=no
  fi
  if test "$with_database_berkdb" = "yes"; then
    AC_DEFINE_UNQUOTED(DB_H_PATH, "$db_h_path")
    AC_DEFINE(HAVE_BERKELEY_DB)
    test "$need_libdb" = "yes" && XE_PREPEND(-ldb, LIBS)
  else with_database_berkdb=no
  fi
fi

if test "$with_database_gnudbm" = "yes" -o \
        "$with_database_dbm"    = "yes" -o \
        "$with_database_berkdb" = "yes"; then
  AC_DEFINE(HAVE_DATABASE)
  XE_ADD_OBJS(database.o)
fi

dnl Socks support
if test "$with_socks" = "yes"; then
  AC_CHECK_LIB(socks, SOCKSinit)
  test -n "$ac_cv_lib_socks_SOCKSinit" && AC_DEFINE(HAVE_SOCKS)
fi

dnl Usage tracking (undocumented and likely unused option)
if test "$usage_tracking" = "yes"; then
  AC_DEFINE(USAGE_TRACKING)
  XE_PREPEND(-Bstatic -lut -Bdynamic, LIBS)
fi

dnl --------------------------------
dnl Compute SUBST-itutable variables
dnl --------------------------------

dnl We ignore (C|LD)_SWITCH_X_(MACHINE|SYSTEM)
dnl Use XE_SPACE instead of plain assignment statements to remove extraneous blanks
XE_SPACE(CFLAGS, $CFLAGS)
XE_SPACE(extra_objs, $extra_objs)
XE_SPACE(c_switch_general, -DHAVE_CONFIG_H $c_switch_site $c_switch_machine $c_switch_system)
XE_SPACE(c_switch_window_system, $c_switch_x_site $X_CFLAGS)
XE_SPACE(c_switch_all, $c_switch_general $c_switch_window_system)
XE_SPACE(ld_switch_general, $ld_switch_site $ld_switch_machine $ld_switch_system $ld_switch_run)
XE_SPACE(ld_switch_window_system, $ld_switch_x_site)
XE_SPACE(ld_switch_all, $ld_switch_general $ld_switch_window_system)
XE_SPACE(ld_libs_general, $LIBS $libs_machine $libs_system $libs_standard)
XE_SPACE(ld_libs_window_system, $X_EXTRA_LIBS $libs_x $X_PRE_LIBS)
XE_SPACE(ld_libs_all, $ld_libs_window_system $ld_libs_general)

dnl Compute lists of Makefiles and subdirs
AC_SUBST(SRC_SUBDIR_DEPS)
XE_APPEND(src, MAKE_SUBDIR)
internal_makefile_list="Makefile"
SUBDIR_MAKEFILES=''
test -d lock || mkdir lock
for dir in $MAKE_SUBDIR; do
  case "$dir" in */* ) dnl Implement mkdir -p
    ( for d in `echo $dir | sed 's:/: :g'` ; do
        test -d "$d" || mkdir "$d"; cd "$d"
      done ) ;;
   * ) test -d "$dir" || mkdir "$dir" ;;
  esac
  XE_SPACE(SUBDIR_MAKEFILES, $SUBDIR_MAKEFILES $dir/Makefile)
  XE_SPACE(internal_makefile_list, $internal_makefile_list $dir/Makefile.in)
done
AC_SUBST(INSTALL_ARCH_DEP_SUBDIR)
AC_SUBST(MAKE_SUBDIR)
AC_SUBST(SUBDIR_MAKEFILES)

dnl Make s&m symlinks in the src directory, for config.h
for dir in src/s src/m; do
  if test ! -d "$dir" ; then
    echo Making symbolic link to "$srcdir/$dir"
    ${LN_S} "$srcdir/$dir" "$dir"
  fi
done

if test "$extra_verbose" = "yes"; then
  echo ""
  PRINT_VAR(extra_objs
   c_switch_general  c_switch_window_system  c_switch_all
  ld_switch_general ld_switch_window_system ld_switch_all
    ld_libs_general   ld_libs_window_system   ld_libs_all)
  echo ""
fi

dnl Create some auxiliary files
if test -f $srcdir/src/gdbinit -a ! -f src/gdbinit ; then
  echo "creating src/gdbinit"; echo ""
  echo "source $srcdir/src/gdbinit" > src/gdbinit
fi

dnl Create top level .sbinit for Sun compilers
if test "$__sunpro_c" = "yes"; then
  echo "creating .sbinit"; echo ""
  ( echo "# For use with Sun WorkShop's Source browser."
    echo "# See sbquery(1) and sbinit(4) for more information"
    for dir in $MAKE_SUBDIR; do echo "import $dir"; done
  ) > .sbinit
fi

dnl There are no more compile tests; remove the core they created.
rm -f core

dnl -------------------------------------
dnl Substitute into Makefile and config.h
dnl -------------------------------------

dnl what sort of things to edit into Makefile and config.h.
dnl configuration here uncanonicalized to avoid exceeding size limits.

AC_SUBST(version)
AC_SUBST(configuration)
AC_SUBST(canonical)
AC_SUBST(srcdir)
AC_SUBST(prefix)
AC_SUBST(exec_prefix)
AC_SUBST(bindir)
AC_SUBST(datadir)
AC_SUBST(pkgdir)
AC_SUBST(statedir)
AC_SUBST(libdir)
AC_SUBST(mandir)
AC_SUBST(infodir)
AC_SUBST(infodir_user_defined)
AC_SUBST(lispdir)
AC_SUBST(lispdir_user_defined)
AC_SUBST(sitelispdir)
AC_SUBST(etcdir)
AC_SUBST(etcdir_user_defined)
AC_SUBST(lockdir)
AC_SUBST(lockdir_user_defined)
AC_SUBST(archlibdir)
AC_SUBST(archlibdir_user_defined)
AC_SUBST(docdir)
AC_SUBST(bitmapdir)
AC_SUBST(extra_objs)

dnl The following flags combine all the information from:
dnl - command line options (user always gets priority)
dnl - user environment variables
dnl - determined by configure
dnl - the s&m header files (deprecated)
AC_SUBST(machfile)
AC_SUBST(opsysfile)
AC_SUBST(c_switch_general)
AC_SUBST(c_switch_window_system)
AC_SUBST(c_switch_all)
AC_SUBST(ld_switch_general)
AC_SUBST(ld_switch_window_system)
AC_SUBST(ld_switch_all)
AC_SUBST(ld_libs_general)
AC_SUBST(ld_libs_window_system)
AC_SUBST(ld_libs_all)
AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)
RECURSIVE_MAKE="\$(MAKE) \$(MFLAGS) CC='\$(CC)' CFLAGS='\$(CFLAGS)' LDFLAGS='\$(LDFLAGS)' CPPFLAGS='\$(CPPFLAGS)'"
AC_SUBST(RECURSIVE_MAKE)

AC_SUBST(native_sound_lib)
AC_SUBST(sound_cflags)
AC_SUBST(RANLIB)
AC_SUBST(dynodump_arch)


dnl change blanks to colons in package path, and make available to config.h
if test -n "$package_path"; then
  package_path=`echo $package_path | sed 'y/ /:/'`
  AC_DEFINE_UNQUOTED(PACKAGE_PATH, "$package_path")
fi

AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "$canonical")
AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
AC_DEFINE_UNQUOTED(config_machfile,  "$machfile")
AC_DEFINE_UNQUOTED(config_opsysfile, "$opsysfile")

dnl Following are deprecated

null_string=""
AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE,     $null_string)
AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, $null_string)
AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,      $null_string)
AC_DEFINE_UNQUOTED(LD_SWITCH_SITE,       $null_string)
AC_DEFINE_UNQUOTED(C_SWITCH_SITE,        $null_string)

dnl Note: as a general rule, *only* define things here that are not
dnl autodetected.  For things that are autodetected, define them
dnl at the point where the autodetection occurs or would occur,
dnl so that the user gets immediate feedback on the results of the
dnl autodetection.

test -n "$puresize" && AC_DEFINE_UNQUOTED(RAW_PURESIZE, $puresize)

if   test "$GNU_MALLOC"        = "yes"; then AC_DEFINE(GNU_MALLOC)
elif test "$use_system_malloc" = "yes"; then AC_DEFINE(USE_SYSTEM_MALLOC)
fi
test "$with_i18n3"         = "yes" && AC_DEFINE(I18N3)
test "$GCC"                = "yes" && AC_DEFINE(USE_GCC)
test "$with_term"          = "yes" && AC_DEFINE(HAVE_TERM)
test "$external_widget"    = "yes" && AC_DEFINE(EXTERNAL_WIDGET)
test "$with_gnu_make"      = "yes" && AC_DEFINE(USE_GNU_MAKE)
test "$no_doc_file"        = "yes" && AC_DEFINE(NO_DOC_FILE)
test "$const_is_losing"    = "yes" && AC_DEFINE(CONST_IS_LOSING)
test "$with_quantify"      = "yes" && AC_DEFINE(QUANTIFY)
test "$with_pop"           = "yes" && AC_DEFINE(MAIL_USE_POP)
test "$with_kerberos"      = "yes" && AC_DEFINE(KERBEROS)
test "$with_hesiod"        = "yes" && AC_DEFINE(HESIOD)
test "$use_union_type" != yes && AC_DEFINE(NO_UNION_TYPE)

dnl -------------------------------
dnl Report on what we decided to do
dnl -------------------------------

(
dnl /etc/osversion is on SONY NEWS-OS
if test -f /etc/osversion; then dnl SONY NEWS-OS
  echo "osversion: `cat /etc/osversion`"
else
  echo "uname -a: `uname -a`"
fi
echo ""
echo "$0 $quoted_arguments"
) >> Installation

dnl Start stdout redirection to '| tee -a Installation'
(
echo "

Configured for \`$canonical'.

  Where should the build process find the source code?    $srcdir
  What installation prefix should install use?		  $prefix
  What operating system and machine description files should XEmacs use?
        \`$opsysfile' and \`$machfile'
  What compiler should XEmacs be built with?              $CC $CFLAGS
  Should XEmacs use the GNU version of malloc?            ${GNU_MALLOC}${GNU_MALLOC_reason}
  Should XEmacs use the relocating allocator for buffers? $rel_alloc
  What window system should XEmacs use?                   ${window_system}"
if test "$with_x11" = "yes"; then
  echo "  Where do we find X Windows header files?                $x_includes"
  echo "  Where do we find X Windows libraries?                   $x_libraries"
fi
if test -n "$site_includes"; then
  echo "  Additional header files:                                $site_includes"
fi
if test -n "$site_libraries"; then
  echo "  Additional libraries:                                   $site_libraries"
fi
if test -n "$runpath"; then
  echo "  Runtime library search path:                            $runpath"
fi
test "$with_dnet"  = yes && echo "  Compiling in support for DNET."
test "$with_socks" = yes && echo "  Compiling in support for SOCKS."
test "$with_term"  = yes && echo "  Compiling in support for TERM."
test "$with_xauth" = yes && echo "  Compiling in support for XAUTH."
if test "$with_xmu" != yes -a "$with_x11" = yes; then
  echo "  No Xmu; substituting equivalent routines."
fi

test "$with_gif"   = yes && echo "  Compiling in support for GIF image conversion."
if test "$with_xpm" = yes; then
  echo "  Compiling in support for XPM images."
elif test "$with_x11" = yes; then
  echo "  --------------------------------------------------------------------"
  echo "  WARNING: Compiling without XPM support."
  echo "  WARNING: You should strongly considering installing XPM."
  echo "  WARNING: Otherwise toolbars and other graphics will look suboptimal."
  echo "  --------------------------------------------------------------------"
fi
test "$with_xface" = yes && echo "  Compiling in support for X-Face message headers."
test "$with_jpeg"  = yes && echo "  Compiling in support for JPEG image conversion."
test "$with_png"   = yes && echo "  Compiling in support for PNG image conversion."
test "$with_tiff"  = yes && echo "  Compiling in support for TIFF image conversion (not implemented)."

case "$with_sound" in
  nas    ) echo "  Compiling in network sound (NAS) support." ;;
  native ) echo "  Compiling in native sound support." ;;
  both   ) echo "  Compiling in both network and native sound support." ;;
esac
test "$old_nas" = yes && echo "        nas library lacks error trapping, will play synchronously"

test "$with_database_berkdb" = yes && echo "  Compiling in support for Berkeley DB."
test "$with_database_dbm"    = yes && echo "  Compiling in support for DBM."
test "$with_database_gnudbm" = yes && echo "  Compiling in support for GNU DBM."

test "$with_ncurses"  = yes && echo "  Compiling in support for ncurses."
test "$with_gpm"      = yes && echo "  Compiling in support for GPM (General Purpose Mouse)."

test "$with_mule"     = yes && echo "  Compiling in Mule (multi-lingual) support."
test "$with_xim"      != no && echo "  Compiling in XIM (X11R5+ I18N input method) support."
test "$with_xim" = motif    && echo "    Using Motif to provide XIM support."
test "$with_xim" = xlib     && echo "    Using raw Xlib to provide XIM support."
test "$with_canna"    = yes && echo "  Compiling in support for Canna on Mule."
if test "$with_wnn" = yes; then
  echo "  Compiling in support for the WNN input method on Mule."
  test "$with_wnn6" = yes && echo "    Using WNN version 6."
fi
test "$with_i18n3"    = yes && echo "  Compiling in I18N support, level 3 (doesn't currently work)."

test "$with_cde"      = yes && echo "  Compiling in support for CDE."
test "$with_tooltalk" = yes && echo "  Compiling in support for ToolTalk."
test "$with_offix"    = yes && echo "  Compiling in support for OffiX."
test "$with_workshop" = yes && echo "  Compiling in support for Sun WorkShop."
test "$with_energize" = yes && echo "  Compiling in support for Lucid Energize (doesn't currently work)."
case  "$with_menubars" in
  lucid ) echo "  Using Lucid menubars." ;;
  motif ) echo "  Using Motif menubars."
          echo "  *WARNING*  The Motif menubar implementation is currently buggy."
          echo "             We recommend using the Lucid menubar instead."
          echo "             Re-run configure with --with-menubars='lucid'." ;;
esac
case "$with_scrollbars" in
  lucid    ) echo "  Using Lucid scrollbars."     ;;
  motif    ) echo "  Using Motif scrollbars."     ;;
  athena   ) echo "  Using Athena scrollbars."    ;;
  athena3d ) echo "  Using Athena-3d scrollbars." ;;
esac
case "$with_dialogs" in
  motif    ) echo "  Using Motif dialog boxes."     ;;
  athena   ) echo "  Using Athena dialog boxes."    ;;
  athena3d ) echo "  Using Athena-3d dialog boxes." ;;
esac
echo "  movemail will use \"$mail_locking\" for locking mail spool files."
test "$with_pop"	= yes && echo "  Using POP for mail access"
test "$with_kerberos"	= yes && echo "  Using Kerberos for POP authentication"
test "$with_hesiod"	= yes && echo "  Using Hesiod to get POP server host"

test "$use_union_type"     = yes && echo "  Using the union type for Lisp_Objects."
test "$debug"              = yes && echo "  Compiling in extra code for debugging."
test "$memory_usage_stats" = yes && echo "  Compiling in code for checking XEmacs memory usage."
test "$usage_tracking"     = yes && echo "  Compiling with usage tracking active (Sun internal)."
if test "$error_check_extents $error_check_typecheck $error_check_bufpos $error_check_gc $error_check_malloc" \
  != "no no no no no"; then
  echo "  WARNING: ---------------------------------------------------------"
  echo "  WARNING: Compiling in support for runtime error checking."
  echo "  WARNING: XEmacs will run noticeably more slowly as a result."
  echo "  WARNING: Error checking is on by default for XEmacs beta releases."
  echo "  WARNING: ---------------------------------------------------------"
fi
echo ""
) | tee -a Installation
echo "The above configure report is appended to \"Installation\" file."
echo ""

dnl -----------------------------------
dnl Now generate config.h and Makefiles
dnl -----------------------------------

dnl This has to be called in order for this variable to get into config.status
AC_SUBST(internal_makefile_list)
# Remove any trailing slashes in these variables.
test -n "$prefix" &&
  prefix=`echo '' "$prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`
test -n "$exec_prefix" &&
  exec_prefix=`echo '' "$exec_prefix" | sed -e 's:^ ::' -e 's,\([[^/]]\)/*$,\1,'`

dnl Build Makefile.in's from Makefile.in.in's
dnl except ./Makefile from $srcdir/Makefile.in

AC_OUTPUT($internal_makefile_list,[
for dir in $MAKE_SUBDIR; do
  echo creating $dir/Makefile
  (
changequote(<<, >>)dnl
    cd $dir
    rm -f junk.c
    < Makefile.in \
      sed -e '/^# Generated/d' \
          -e 's%/\*\*/#.*%%' \
          -e 's/^ *# */#/' \
          -e '/^##/d' \
          -e '/^#/ {
p
d
}'        -e '/./ {
s/\([\"]\)/\\\1/g
s/^/"/
s/$/"/
}'  > junk.c;
    $CPP -I. -I${top_srcdir}/src $CPPFLAGS junk.c > junk.cpp;
    < junk.cpp				\
      sed -e 's/^#.*//'			\
	-e 's/^[ TAB][ TAB]*$//'	\
	-e 's/^ /TAB/'			\
	| sed -n -e '/^..*$/p'		\
	| sed '/^"/ {
s/\\\([\"]\)/\1/g
s/^"//
s/"$//
}'	> Makefile.new
    chmod 444 Makefile.new
    mv -f Makefile.new Makefile
    rm -f junk.c junk.cpp
changequote([, ])dnl
)
done

dnl Create a file of config variables for use by the lisp code
sed < config.status > lib-src/config.values \
-e 's/^s%@\(.*\)@%\(.*\)%g$/\1 "\2"/p' \
-e '/{ac_dA}.*{ac_dB}.*{ac_dC}.*{ac_dD}$/!d' \
-e 's/\${ac_dA}\(.*\)\${ac_dB}.*\${ac_dC}\(.*\)\${ac_dD}/\1 \2/' \
-e 's/^\([[^ ]]*\) $/\1 ""/' \
-e 's/ 1$/ t/'

],
[CPP="$CPP"
 CPPFLAGS="$CPPFLAGS"
 top_srcdir="$srcdir"
 MAKE_SUBDIR="$MAKE_SUBDIR"
])
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.