Source

js-elisp / ocaml / contrib / ocp-indent / src / approx_lexer.mll

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
(**************************************************************************)
(*                                                                        *)
(*    TypeRex OCaml Studio                                                *)
(*      Thomas Gazagnaire, Fabrice Le Fessant                             *)
(*                                                                        *)
(*    OCaml                                                               *)
(*      Xavier Leroy, projet Cristal, INRIA Rocquencourt                  *)
(*                                                                        *)
(*  Copyright 2011-2012 OCamlPro                                          *)
(*  Copyright 1996-2011 INRIA.                                            *)
(*  All rights reserved.  This file is distributed under the terms of     *)
(*  the GNU Public License version 3.0.                                   *)
(*                                                                        *)
(*  TypeRex is distributed in the hope that it will be useful,            *)
(*  but WITHOUT ANY WARRANTY; without even the implied warranty of        *)
(*  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the         *)
(*  GNU General Public License for more details.                          *)
(*                                                                        *)
(**************************************************************************)

(* ADMIN: fabrice *)

(***********************************************************************)
(*                                                                     *)
(*                           Objective Caml                            *)
(*                                                                     *)
(*            Xavier Leroy, projet Cristal, INRIA Rocquencourt         *)
(*                                                                     *)
(*  Copyright 1996 Institut National de Recherche en Informatique et   *)
(*  en Automatique.  All rights reserved.  This file is distributed    *)
(*  under the terms of the Q Public License version 1.0.               *)
(*                                                                     *)
(***********************************************************************)

{

open Lexing

open Approx_common
include Approx_tokens

let list_last l = List.hd (List.rev l)

let comment_stack = ref []
let lines_starts = ref []

let init () =
  comment_stack := [];
  lines_starts := []

let comments () =
  List.rev !comment_stack

(* The table of keywords *)

let keywords = [
  "and", AND;
  "as", AS;
  "assert", ASSERT;
  "begin", BEGIN;
  "class", CLASS;
  "constraint", CONSTRAINT;
  "do", DO;
  "done", DONE;
  "downto", DOWNTO;
  "else", ELSE;
  "end", END;
  "exception", EXCEPTION;
  "external", EXTERNAL;
  "false", FALSE;
  "for", FOR;
  "fun", FUN;
  "function", FUNCTION;
  "functor", FUNCTOR;
  "if", IF;
  "in", IN;
  "include", INCLUDE;
  "inherit", INHERIT;
  "initializer", INITIALIZER;
  "lazy", LAZY;
  "let", LET;
  "match", MATCH;
  "method", METHOD;
  "module", MODULE;
  "mutable", MUTABLE;
  "new", NEW;
  "object", OBJECT;
  "of", OF;
  "open", OPEN;
  "or", OR;
  "private", PRIVATE;
  "rec", REC;
  "sig", SIG;
  "struct", STRUCT;
  "then", THEN;
  "to", TO;
  "true", TRUE;
  "try", TRY;
  "type", TYPE;
  "val", VAL;
  "virtual", VIRTUAL;
  "when", WHEN;
  "while", WHILE;
  "with", WITH;

  "mod", INFIXOP3("mod");
  "land", INFIXOP3("land");
  "lor", INFIXOP3("lor");
  "lxor", INFIXOP3("lxor");
  "lsl", INFIXOP4("lsl");
  "lsr", INFIXOP4("lsr");
  "asr", INFIXOP4("asr");
]

(* extensions *)
let syntax_extensions = [
  "lwt", [
    "for_lwt", FOR;
    "lwt", LET;
    "match_lwt", MATCH;
    "try_lwt", TRY;
    "while_lwt", WHILE;
    "finally", BAR;  (* -- no equivalence for this one, this is a hack ! *)
  ];
  "mll", [
    "rule", LET;
    "parse", FUNCTION;
  ];
  "stream", [
    "parser", FUNCTION;
  ];
]

let keyword_table =
  let t = Hashtbl.create 149 in
  List.iter (fun (x,y) -> Hashtbl.add t x y) keywords;
  t

let available_extensions () = List.map fst syntax_extensions
let enable_extension name =
  List.iter
    (fun (x,y) -> Hashtbl.add keyword_table x y)
    (List.assoc name syntax_extensions)
let disable_extensions () =
  Hashtbl.clear keyword_table;
  List.iter (fun (x,y) -> Hashtbl.add keyword_table x y) keywords

(* To buffer string literals *)

let initial_string_buffer = String.create 256
let string_buff = ref initial_string_buffer
let string_index = ref 0

let reset_string_buffer () =
  string_buff := initial_string_buffer;
  string_index := 0

let store_string_char c =
  if !string_index >= String.length (!string_buff) then begin
    let new_buff = String.create (String.length (!string_buff) * 2) in
    String.blit (!string_buff) 0 new_buff 0 (String.length (!string_buff));
    string_buff := new_buff
  end;
  String.unsafe_set (!string_buff) (!string_index) c;
  incr string_index

let get_stored_string () =
  let s = String.sub (!string_buff) 0 (!string_index) in
  string_buff := initial_string_buffer;
  s

(* To store the position of the beginning of a string and comment *)
let string_start_loc = ref (-1);;
let quotation_start_loc = ref (-1);;
let comment_start_loc = ref [];;
let in_comment () = !comment_start_loc <> [];;

(* To translate escape sequences *)

let char_for_backslash = function
  | 'n' -> '\010'
  | 'r' -> '\013'
  | 'b' -> '\008'
  | 't' -> '\009'
  | c   -> c

let can_overflow f lexbuf =
  let s = Lexing.lexeme lexbuf in
  try InRange (f s) with Failure _ -> Overflow s

let char_for_decimal_code i s =
  let c = 100 * (Char.code(s.[i]) - 48) +
      10 * (Char.code(s.[i+1]) - 48) +
      (Char.code(s.[i+2]) - 48) in
  if (c < 0 || c > 255) then
    failwith "Bad escaped decimal char"
  else Char.chr c

let char_for_hexadecimal_code lexbuf i =
  let d1 = Char.code (Lexing.lexeme_char lexbuf i) in
  let val1 = if d1 >= 97 then d1 - 87
    else if d1 >= 65 then d1 - 55
    else d1 - 48
  in
  let d2 = Char.code (Lexing.lexeme_char lexbuf (i+1)) in
  let val2 = if d2 >= 97 then d2 - 87
    else if d2 >= 65 then d2 - 55
    else d2 - 48
  in
  Char.chr (val1 * 16 + val2)

(* To convert integer literals, allowing max_int + 1 (PR#4210) *)

let cvt_int_literal s =
  - int_of_string ("-" ^ s)
let cvt_int32_literal s =
  Int32.neg (Int32.of_string ("-" ^ String.sub s 0 (String.length s - 1)))
let cvt_int64_literal s =
  Int64.neg (Int64.of_string ("-" ^ String.sub s 0 (String.length s - 1)))
let cvt_nativeint_literal s =
  Nativeint.neg (Nativeint.of_string ("-" ^ String.sub s 0 (String.length s - 1)))

(* Remove underscores from float literals *)

let remove_underscores s =
  let l = String.length s in
  let rec remove src dst =
    if src >= l then
      if dst >= l then s else String.sub s 0 dst
    else
      match s.[src] with
        '_' -> remove (src + 1) dst
      |  c  -> s.[dst] <- c; remove (src + 1) (dst + 1)
  in remove 0 0

(* Update the current location with file name and line number. *)

let update_loc lexbuf file line absolute chars =
  let pos = lexbuf.lex_curr_p in
  let new_file = match file with
    | None -> pos.pos_fname
    | Some s -> s
  in
  lexbuf.lex_curr_p <- {
    pos with
    pos_fname = new_file;
    pos_lnum = if absolute then line else pos.pos_lnum + line;
    pos_bol = pos.pos_cnum - chars;
  };
  lines_starts := (lexbuf.lex_curr_p.pos_lnum, lexbuf.lex_curr_p.pos_bol) :: !lines_starts;

;;
}

let newline = ('\010' | '\013' | "\013\010")
let blank = [' ' '\009' '\012']
let lowercase = ['a'-'z' '\223'-'\246' '\248'-'\255' '_' '\'']
let uppercase = ['A'-'Z' '\192'-'\214' '\216'-'\222' '`']
let identchar =
  ['A'-'Z' 'a'-'z' '_' '\192'-'\214' '\216'-'\246' '\248'-'\255' '\'' '0'-'9']
let symbolchar =
  ['!' '$' '%' '&' '*' '+' '-' '.' '/' ':' '<' '=' '>' '?' '@' '^' '|' '~']
let decimal_literal =
  (['0'-'9'] ['0'-'9' '_']*)
let hex_literal =
  ('0' ['x' 'X'] ['0'-'9' 'A'-'F' 'a'-'f']['0'-'9' 'A'-'F' 'a'-'f' '_']*)
let oct_literal =
  ('0' ['o' 'O'] ['0'-'7'] ['0'-'7' '_']*)
let bin_literal =
  ('0' ['b' 'B'] ['0'-'1'] ['0'-'1' '_']*)
let int_literal =
  (decimal_literal | hex_literal | oct_literal | bin_literal)
let float_literal =
  ['0'-'9'] ['0'-'9' '_']*
    ('.' ['0'-'9' '_']* )?
      (['e' 'E'] ['+' '-']? ['0'-'9'] ['0'-'9' '_']*)?


rule token = parse
  | newline
      { update_loc lexbuf None 1 false 0;
        token lexbuf
      }
  | blank +
      { token lexbuf }
  | "_"
    { UNDERSCORE }
  | "~"
    { TILDE }
  | "~" lowercase identchar * ':'
      { let s = Lexing.lexeme lexbuf in
        let name = String.sub s 1 (String.length s - 2) in
        (*
           if Hashtbl.mem keyword_table name then
           raise (Error(Keyword_as_label name, Location.curr lexbuf));
        *)
        LABEL name }
  | "?"  { QUESTION }
  | "??" { QUESTIONQUESTION }
  | "?" lowercase identchar * ':'
      { let s = Lexing.lexeme lexbuf in
        let name = String.sub s 1 (String.length s - 2) in
        (*
           if Hashtbl.mem keyword_table name then
           raise (Error(Keyword_as_label name, Location.curr lexbuf));
        *)
        OPTLABEL name }
  | lowercase identchar *
    { let s = Lexing.lexeme lexbuf in
      try
        Hashtbl.find keyword_table s
      with Not_found ->
          LIDENT s }
  | uppercase identchar *
    { UIDENT(Lexing.lexeme lexbuf) }      (* No capitalized keywords *)
  | int_literal
    { INT (can_overflow cvt_int_literal lexbuf) }
  | float_literal
    { FLOAT (remove_underscores(Lexing.lexeme lexbuf)) }
  | int_literal "l"
    { INT32 (can_overflow cvt_int32_literal lexbuf) }
  | int_literal "L"
    { INT64 (can_overflow cvt_int64_literal lexbuf) }
  | int_literal "n"
    { NATIVEINT (can_overflow cvt_nativeint_literal lexbuf) }
  | "\""
    { reset_string_buffer();
      let string_start = lexbuf.lex_start_p in
      string_start_loc := Lexing.lexeme_start lexbuf;
      let token = string lexbuf in
      lexbuf.lex_start_p <- string_start;
      token }
  | "'" newline "'"
    { update_loc lexbuf None 1 false 1;
      CHAR (InRange (Lexing.lexeme_char lexbuf 1)) }
  | "'" [^ '\\' '\'' '\010' '\013'] "'"
    { CHAR( InRange (Lexing.lexeme_char lexbuf 1)) }
  | "'\\" ['\\' '\'' '"' 'n' 't' 'b' 'r' ' '] "'"
    { CHAR( InRange (char_for_backslash (Lexing.lexeme_char lexbuf 2))) }
  | "'\\" ['0'-'9'] ['0'-'9'] ['0'-'9'] "'"
    { CHAR(can_overflow (char_for_decimal_code 2) lexbuf) }
  | "'\\" 'x' ['0'-'9' 'a'-'f' 'A'-'F'] ['0'-'9' 'a'-'f' 'A'-'F'] "'"
    { CHAR( InRange (char_for_hexadecimal_code lexbuf 3)) }
  | "'\\" _
    { let l = Lexing.lexeme lexbuf in
      CHAR ( Overflow l )
    }
  | "(*"
    {
      let comment_start = lexbuf.lex_start_p in
      comment_start_loc := [Lexing.lexeme_start lexbuf];
      let token= comment lexbuf in
      lexbuf.lex_start_p <- comment_start;
      token
    }
  | "*)"
    {
      (*      let loc = Location.curr lexbuf in *)
      (*        Location.prerr_warning loc Warnings.Comment_not_end; *)
      lexbuf.Lexing.lex_curr_pos <- lexbuf.Lexing.lex_curr_pos - 1;
      let curpos = lexbuf.lex_curr_p in
      lexbuf.lex_curr_p <- { curpos with pos_cnum = curpos.pos_cnum - 1 };
      STAR
    }
  | "<:" identchar * "<"
      {
        let start = lexbuf.lex_start_p in
        quotation_start_loc := Lexing.lexeme_start lexbuf;
        let token = quotation lexbuf in
        lexbuf.lex_start_p <- start;
        token
      }
  | "#" [' ' '\t']* (['0'-'9']+ as _num) [' ' '\t']*
    ("\"" ([^ '\010' '\013' '"' ] * as _name) "\"")?
      [^ '\010' '\013'] * newline
      { update_loc lexbuf None 1 false 0;
        LINE_DIRECTIVE
      }
  | "#"  { SHARP }
  | "&"  { AMPERSAND }
  | "&&" { AMPERAMPER }
  | "`"  { BACKQUOTE }
  | "'"  { QUOTE }
  | "("  { LPAREN }
  | ")"  { RPAREN }
  | "*"  { STAR }
  | ","  { COMMA }
  | "->" { MINUSGREATER }
  | "."  { DOT }
  | ".." { DOTDOT }
  | ":"  { COLON }
  | "::" { COLONCOLON }
  | ":=" { COLONEQUAL }
  | ":>" { COLONGREATER }
  | ";"  { SEMI }
  | ";;" { SEMISEMI }
  | "<"  { LESS }
  | "<-" { LESSMINUS }
  | "="  { EQUAL }
  | "["  { LBRACKET }
  | "[|" { LBRACKETBAR }
  | "[<" { LBRACKETLESS }
  | "[>" { LBRACKETGREATER }
  | "]"  { RBRACKET }
  | "{"  { LBRACE }
  | "{<" { LBRACELESS }
  | "|"  { BAR }
  | "||" { BARBAR }
  | "|]" { BARRBRACKET }
  | ">"  { GREATER }
  | ">]" { GREATERRBRACKET }
  | "}"  { RBRACE }
  | ">}" { GREATERRBRACE }
  | "!"  { BANG }

  | "!=" { INFIXOP0 "!=" }
  | "+"  { PLUS }
  | "+." { PLUSDOT }
  | "-"  { MINUS }
  | "-." { MINUSDOT }

  | "!" symbolchar +
    { PREFIXOP(Lexing.lexeme lexbuf) }
  | ['~' '?'] symbolchar +
    { PREFIXOP(Lexing.lexeme lexbuf) }
  | ['=' '<' '>' '|' '&' '$'] symbolchar *
    { INFIXOP0(Lexing.lexeme lexbuf) }
  | ['@' '^'] symbolchar *
    { INFIXOP1(Lexing.lexeme lexbuf) }
  | ['+' '-'] symbolchar *
    { INFIXOP2(Lexing.lexeme lexbuf) }
  | "**" symbolchar *
    { INFIXOP4(Lexing.lexeme lexbuf) }
  | ['*' '/' '%'] symbolchar *
    { INFIXOP3(Lexing.lexeme lexbuf) }

  | eof { EOF }
  | _
    { ILLEGAL_CHAR (Lexing.lexeme_char lexbuf 0)      }

and quotation = parse
    ">>" { QUOTATION }
  | newline
      { update_loc lexbuf None 1 false 0;
        quotation lexbuf
      }
  | eof { EOF_IN_QUOTATION !quotation_start_loc }
  | _ { quotation lexbuf }

and comment = parse
  | "(*"
      { comment_start_loc := (Lexing.lexeme_start lexbuf) :: !comment_start_loc;
        comment lexbuf;
      }
  | "*)"
      { match !comment_start_loc with
        | [] -> assert false
        | [x] ->
            comment_start_loc := [];
            comment_stack := (x, Lexing.lexeme_end lexbuf) :: !comment_stack;
            COMMENT (x, Lexing.lexeme_end lexbuf)
        | _ :: l -> comment_start_loc := l;
            comment lexbuf;
      }
  | "\""
    { reset_string_buffer();
      string_start_loc := Lexing.lexeme_start lexbuf;
      let s = string lexbuf in
      reset_string_buffer ();
      match s with
      | EOF_IN_STRING _ ->
          let pos = list_last !comment_start_loc in
          comment_start_loc := [];
          EOF_IN_COMMENT pos
      | STRING _ -> comment lexbuf
      | _ -> assert false
    }
  | "''"
    { comment lexbuf }
  | "'" newline "'"
    { update_loc lexbuf None 1 false 1;
      comment lexbuf
    }
  | "'" [^ '\\' '\'' '\010' '\013' ] "'"
    { comment lexbuf }
  | "'\\" ['\\' '"' '\'' 'n' 't' 'b' 'r' ' '] "'"
    { comment lexbuf }
  | "'\\" ['0'-'9'] ['0'-'9'] ['0'-'9'] "'"
    { comment lexbuf }
  | "'\\" 'x' ['0'-'9' 'a'-'f' 'A'-'F'] ['0'-'9' 'a'-'f' 'A'-'F'] "'"
    { comment lexbuf }
  | eof
    {
      let pos = list_last !comment_start_loc in
      comment_start_loc := [];
      EOF_IN_COMMENT pos
    }
  | newline
    { update_loc lexbuf None 1 false 0;
      comment lexbuf
    }
  | _
    { comment lexbuf }

and string = parse
    '"'
      { STRING (get_stored_string ()) }
  | '\\' newline ([' ' '\t'] * as space)
      { update_loc lexbuf None 1 false (String.length space);
        string lexbuf
      }
  | '\\' ['\\' '\'' '"' 'n' 't' 'b' 'r' ' ']
    { store_string_char(char_for_backslash(Lexing.lexeme_char lexbuf 1));
      string lexbuf }
  | '\\' ['0'-'9'] ['0'-'9'] ['0'-'9']
    { (match can_overflow (char_for_decimal_code 1) lexbuf with
      | Overflow _ ->
          let s = Lexing.lexeme lexbuf in
          for i = 0 to String.length s - 1 do store_string_char s.[i] done
      | InRange c -> store_string_char c);
      string lexbuf }
  | '\\' 'x' ['0'-'9' 'a'-'f' 'A'-'F'] ['0'-'9' 'a'-'f' 'A'-'F']
    { store_string_char(char_for_hexadecimal_code lexbuf 2);
      string lexbuf }
  | '\\' _
    { if in_comment ()
      then string lexbuf
      else begin
        (*  Should be an error, but we are very lax.
            raise (Error (Illegal_escape (Lexing.lexeme lexbuf),
              Location.curr lexbuf))
        *)
        store_string_char (Lexing.lexeme_char lexbuf 0);
        store_string_char (Lexing.lexeme_char lexbuf 1);
        string lexbuf
      end
    }
  | newline
    {
      update_loc lexbuf None 1 false 0;
      let s = Lexing.lexeme lexbuf in
      for i = 0 to String.length s - 1 do
        store_string_char s.[i];
      done;
      string lexbuf
    }
  | eof
    { EOF_IN_STRING !string_start_loc }
  | _
    { store_string_char(Lexing.lexeme_char lexbuf 0);
      string lexbuf }

{

let rec token_locs lexbuf =
  match token lexbuf with
    COMMENT _ -> token_locs lexbuf
  | EOF_IN_COMMENT _ ->
      EOF, ( lexbuf.lex_start_p, lexbuf.lex_start_p)
  | EOF_IN_STRING _ ->
      EOF, ( lexbuf.lex_start_p, lexbuf.lex_start_p)
  | token ->
      token, ( lexbuf.lex_start_p, lexbuf.lex_curr_p)

let rec token_pos lexbuf =
  match token lexbuf with
    COMMENT _ -> token_pos lexbuf
  | EOF_IN_COMMENT _ ->
      EOF, ( lexbuf.lex_start_p.pos_cnum, lexbuf.lex_start_p.pos_cnum)
  | EOF_IN_STRING _ ->
      EOF, ( lexbuf.lex_start_p.pos_cnum, lexbuf.lex_start_p.pos_cnum)
  | token ->
      token, ( lexbuf.lex_start_p.pos_cnum, lexbuf.lex_curr_p.pos_cnum)


let token_locs_and_comments lexbuf =
  let token = token lexbuf in
  token,  ( lexbuf.lex_start_p, lexbuf.lex_curr_p)

let get_token = token

let token_with_comments = get_token

let rec token lexbuf =
  match get_token lexbuf with
    COMMENT _ -> token lexbuf
  | EOF_IN_COMMENT _
  | EOF_IN_STRING _ -> EOF
  | tok -> tok

let tokens_of_file filename =
  let ic = open_in filename in
  try
    init ();
    let lexbuf = Lexing.from_channel ic in
    let rec iter tokens =
      let token = token_pos lexbuf in
      match token with
        (EOF, _) -> List.rev tokens
      | _ -> iter (token :: tokens)
    in
    let tokens = iter [] in
    close_in ic;
    tokens
  with e -> close_in ic; raise e

let tokens_with_loc_of_string s =
  init ();
  let lexbuf = Lexing.from_string s in
  let rec iter tokens =
    let token = token_pos lexbuf in
    match token with
      (EOF, _) -> List.rev tokens
    | _ -> iter (token :: tokens)
  in
  let tokens = iter [] in
  tokens

let tokens_of_string s =
  init ();
  let lexbuf = Lexing.from_string s in
  let rec iter tokens =
    let token = token lexbuf in
    match token with
      (EOF) -> List.rev tokens
    | _ -> iter (token :: tokens)
  in
  let tokens = iter [] in
  tokens

let lines () = List.rev ( !lines_starts )

}