pkgbuilds / ttf-latex-tlwg / PKGBUILD

# Maintainer: Smith Dhumbumroong <zodmaner@gmail.com>

pkgname=ttf-latex-tlwg
pkgver=0.5.0
pkgrel=1
pkgdesc="A collection of Thai scalable and LaTeX fonts available in free licenses"
arch=('any')
url="http://linux.thai.net/projects/fonts-tlwg"
license=('GPL' 'custom')
depends=('xorg-fonts-encodings' 'xorg-fonts-alias' 'xorg-font-utils' 
         'fontconfig' 'texlive-bin')
makedepends=('fontforge')
provides=('thai-ttf' 'ttf-thai')
conflicts=('ttf-thai' 'ttf-thai-latex')
install=ttf-latex-tlwg.install
source=(ftp://linux.thai.net/pub/ThaiLinux/software/fonts-tlwg/fonts-tlwg-$pkgver.tar.gz
        'LICENSE')
md5sums=('e407df4a9652aa1555e3dd5894d6ddd8'
         'cc4f2ce6fbb72abdca36384a7dead27f')

build() {
  cd "$srcdir/fonts-tlwg-$pkgver"
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --with-ttfdir=/usr/share/fonts/TTF \
    --with-texmfdir=/usr/share/texmf-dist \
    --docdir=/usr/share/doc/thailatex \
    --enable-latex
  make
}

check() {
  cd "$srcdir/fonts-tlwg-$pkgver"
  make -k check
}

package() {
  cd "$srcdir/fonts-tlwg-$pkgver"
  make DESTDIR="$pkgdir/" install
  install -D -m644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim:set ts=2 sw=2 et:
Tip: Filter by directory path e.g. /media app.js to search for public/media/app.js.
Tip: Use camelCasing e.g. ProjME to search for ProjectModifiedEvent.java.
Tip: Filter by extension type e.g. /repo .js to search for all .js files in the /repo directory.
Tip: Separate your search with spaces e.g. /ssh pom.xml to search for src/ssh/pom.xml.
Tip: Use ↑ and ↓ arrow keys to navigate and return to view the file.
Tip: You can also navigate files with Ctrl+j (next) and Ctrl+k (previous) and view the file with Ctrl+o.
Tip: You can also navigate files with Alt+j (next) and Alt+k (previous) and view the file with Alt+o.