#!c
// <predefinedChannel> definition and listen example for Aeros Cocks >=6.0
integer AEROS_PUBLIC_ADDON_CH = -727002;

default {
  state_entry() {
    llListen(AEROS_PUBLIC_ADDON_CH, "", NULL_KEY, "");
  }
  listen(integer channel, string name, key id, string message) {
    if (channel!=AEROS_PUBLIC_ADDON_CH) return;
    if (llGetOwnerKey(id)!=llGetOwner()) return;
    // ...
  }
}

>a0|a!|<attachmentPoint>|<localPos>|<localRot>|<hideDistance>|<currentMode>|<currentStage>|<currentVerticalAngle>|<currentHorizontalAngle>

>a0|d!|<batchIndex>|<primIndex>|<primsCount>|<meshName>|<alpha>|<pos>|<rot>|<size>|<widthAxisName>|<widthMultiplyer>|<overallSizeMultiplier>

>a0|o!|<hideDistance>

>a0|t!|<factorsCommaSeparatedList>

#!c
// <predefinedChannel> definition and listen example for Aeros Cocks >=6.0
integer AEROS_PUBLIC_ADDON_CH = -727002;

// This assumes your prim consists of 2 prims, one of them will be snapped
// to the attachment point, and the other will try to follow one of the cock prims
integer check() {
  return (llGetAttached()>0 && llGetNumberOfPrims()>1);
}

default {
  state_entry() {
    if (!check()) state invalid;
    llListen(AEROS_PUBLIC_ADDON_CH, "", NULL_KEY, "");
    llOwnerSay("Attached and running");
  }

  on_rez(integer start_param) {
    if (!check()) state invalid;
  }

  changed(integer change) {
    if (change & CHANGED_LINK) {
      if (!check()) state invalid;
    }
  }

  listen(integer channel, string name, key id, string message) {
    if (channel!=AEROS_PUBLIC_ADDON_CH) return;
    if (llGetOwnerKey(id)!=llGetOwner()) return;
    // High possibility it is Aeros Addon API message :D
    list parts = llParseStringKeepNulls(message, ["|"], []);
    if (llList2String(parts,0)!=">a0") return; // Filter just in case
    if (llList2String(parts,1)=="a!") {  // "Anchor" message (https://bitbucket.org/aeros-in-sl/aeros-addons-api/wiki/Home#markdown-header-anchor)
      // >a0|a!|<attachmentPoint>|<localPos>|<localRot>|<hideDistance>|<currentMode>|<currentStage>|<currentVerticalAngle>|<currentHorizontalAngle>
      //               #2            #3         #4     
      integer attachmentPoint = llList2Integer(parts,2); // "<attachmentPoint>"

      // So your addon can now "snap" its root to this - if attached to the same attachment point
      if (llGetAttached() == attachmentPoint) { // This also checks if we are rezzed on the ground or not... Yeah! If rezzed we snap it anyway! Hope it works or it flies away!
        // Okay we are good to go.
        vector pos = (vector)llList2String(parts,3);
        rotation rot = (rotation)llList2String(parts,4);
        // Let's snap our guy.
        llSetLinkPrimitiveParamsFast(LINK_ROOT, [PRIM_POSITION, pos, PRIM_ROTATION, rot]); // It's better to test this
        // ######### TEST THIS OUT ######### May be something else should be used like PRIM_POS_LOCAL and PRIM_ROT_LOCAL
        // Once your root is snapped, you can be sure that the data message will affect your prims in relation to the same exact point in body space.
      } else {
        // Inform a user to reattach the addon somehow?
        llOwnerSay("The prim seems not to be attached to the same point as the cock");
      }

    } else if (llList2String(parts,1)=="d!") {  // "Data" message (https://bitbucket.org/aeros-in-sl/aeros-addons-api/wiki/Home#markdown-header-data)
      // >a0|d!|<batchIndex>|<primIndex>|<primsCount>|<meshName>|<alpha>|<pos>|<rot>|<size>|<widthAxisName>|<widthMultiplyer>|<overallSizeMultiplier>
      //                          #3                      #5               #7    #8    #9
      // Here we receive exact prim positions. As we want only "knob" its primIndex is....0 !!!!
      if (llList2Integer(parts,3)==0 /*knob*/) {
        // Okay good
        vector pos = (vector)llList2String(parts,7);
        rotation rot = (rotation)llList2String(parts,8);        
        vector size = (vector)llList2String(parts,9);
        // This should be enough to start playing with this data.
        // Start moving your linked prim according to this. Let's say it's link #2 (so it's a 2 prims set at least)
        float factor = 0.5; // It could be anything depending on how big your prim is in releation to the knob mesh size (which also has a bounding box so its size is bigger than it is)
        llSetLinkPrimitiveParamsFast(2 /*Link number*/, [PRIM_POS_LOCAL, pos, PRIM_ROT_LOCAL, rot, PRIM_SIZE, size * factor]);
        // I'm pretty sure we use "LOCAL" here. It's a pain above with the root prim as attachment
        // The real math will become more complex in time as you realize you need adjustments to the position and rotation and size.
        // But this is a fun part!
      }

    }
  }
}

state invalid {
  state_entry() {
    llOwnerSay("Not attached or invalid amount of prims in the linkset. Should be at least 2");
    llSetTimerEvent(5);
  }

  on_rez(integer start_param) {
    if (check()) llResetScript();
  }

  timer() {
    if (check()) llResetScript();
  }

}